x11-plugins/bfm: Mark as C17-only

Problem is in header included from gkrellm. Can't be fixed without
fixing that dependency first.

Closes: https://bugs.gentoo.org/960292
Signed-off-by: NHOrus <jy6x2b32pie9@yahoo.com>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/293
Merges: https://codeberg.org/gentoo/gentoo/pulls/293
Signed-off-by: Sam James <sam@gentoo.org>

x11-plugins/bfm/bfm-0.6.4-r5.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs flag-o-matic
+
+DESCRIPTION="Dockapp and gkrellm plug-in combining timecop's bubblemon and wmfishtime"
+HOMEPAGE="https://github.com/JNRowe/bfm"
+SRC_URI="https://github.com/JNRowe/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="gkrellm"
+
+RDEPEND="
+	gkrellm? ( >=app-admin/gkrellm-2[X] )
+	x11-libs/gtk+:2
+	x11-libs/libX11
+	x11-libs/libXext
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-makefile.patch
+)
+
+src_configure() {
+	append-cflags -std=gnu17 #960292
+	default
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" GENTOO_LDFLAGS="${LDFLAGS}"
+	use gkrellm && emake gkrellm CC="$(tc-getCC)"
+}
+
+src_install() {
+	dobin bubblefishymon
+
+	doman doc/*.1
+	dodoc ChangeLog* README* doc/*.sample
+
+	if use gkrellm; then
+		insinto /usr/$(get_libdir)/gkrellm2/plugins
+		doins gkrellm-bfm.so
+	fi
+}