kde-apps/dolphin: 21.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/dolphin/Manifest

@@ -1 +1,2 @@
 DIST dolphin-20.12.3.tar.xz 5134660 BLAKE2B 3ad3e7c16d0c4203e189bdf035028777115971091bc3c45a3e88231f9715c9439f44c67b2bf2d9d4680a07d222c0c14858028d54499fbe8cf006e3eae63a9193 SHA512 fb57121875fb6b3db9b3071590ea2b6fe7db1d22238af758591835946ac297d7a1734646385a2f6b7ade41de7dcfdf8f6b5e7dccf335a3cf558259d017e44a11
+DIST dolphin-21.04.0.tar.xz 5160064 BLAKE2B 4443e68ca72e3849a082644c4f14e1bab57581261be3da20bd1a2f646277270d617d78afab1f0c26244886de77a1d3aa701cdda66dce33f69e3e84c389353dd2 SHA512 6675d39146f69395c51d264459b6ba29210d131fed068de8006be1ba324c604ce004ccc4e5d68cc8ac6c0dfa5a63a7b2fac25c04227e6abc802dfe5a37e96c35

kde-apps/dolphin/dolphin-21.04.0.ebuild

@@ -0,0 +1,96 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.80.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org optfeature
+
+DESCRIPTION="Plasma filemanager focusing on usability"
+HOMEPAGE="https://apps.kde.org/en/dolphin https://userbase.kde.org/Dolphin"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="activities semantic-desktop telemetry"
+
+DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kinit-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5=
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=media-libs/phonon-4.11.0
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+	semantic-desktop? (
+		>=kde-apps/baloo-widgets-${PVCUT}:5
+		>=kde-frameworks/baloo-${KFMIN}:5
+		>=kde-frameworks/kfilemetadata-${KFMIN}:5
+	)
+	telemetry? ( dev-libs/kuserfeedback:5 )
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/kio-extras-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package semantic-desktop KF5BalooWidgets)
+		$(cmake_use_find_package semantic-desktop KF5FileMetaData)
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# servicemenuinstaller requires ruby, no thanks
+		# dolphinmainwindowtest, kitemlistcontrollertest, kfileitemlistviewtest, kfileitemmodeltest hang forever
+		# placesitemmodeltest requires DBus
+		-E "(servicemenuinstaller|dolphinmainwindowtest|kfileitemlistviewtest|kfileitemmodeltest|kitemlistcontrollertest|placesitemmodeltest)"
+	)
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "compress/extract and other actions" kde-apps/ark:${SLOT}
+		optfeature "crypto actions" kde-apps/kleopatra:${SLOT}
+		optfeature "video file thumbnails" kde-apps/ffmpegthumbs:${SLOT}
+		optfeature "graphics file thumbnails" kde-apps/thumbnailers:${SLOT}
+		optfeature "'Share' context menu actions" kde-frameworks/purpose:${SLOT}
+	fi
+	ecm_pkg_postinst
+}