net-wireless/gnome-bluetooth: add 47.2

Also support python 3.14 and build sendto module (before it was provided
by :2 slot but, since it was dropped, we don't have conflicts with it
anymore).

Closes: https://bugs.gentoo.org/974190
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

net-wireless/gnome-bluetooth/Manifest

@@ -1,2 +1,3 @@
 DIST gnome-bluetooth-46.2.tar.xz 306076 BLAKE2B 5696ec06cde737d833f02edd89f265172a3b8c4e3486cbb09b3e2e046ead445e6a3aac23a92223dada9f8a6cadd7969755bed661b3a95161fb3874f545172f38 SHA512 e0745ae67e5c30000ace8161c114caecc1f3b8e99b824b961ed695ba78a088247d797ad3cb284fc7cf91dd7c37b94c5ce0bdc4c1118b9bf059039effeb79313a
 DIST gnome-bluetooth-47.1.tar.xz 297800 BLAKE2B f111a46cf56bc3614dac448297c2cd5fadbe0a3c3f75c2130542e9cbf88d3a6a167c6d59416ffede12945310e6720aedfc9181f3a71ca1e8bd4b61e14df9ab6b SHA512 474f8687e8d1c1a10ce5690a8e7c57e6afd29d55c9777820fad3b6d21ec07bab4ac31ab0ea9dd7d9a0e93a60b933913f5a54df69dc7d348d95098cc289c2e6b4
+DIST gnome-bluetooth-47.2.tar.xz 298012 BLAKE2B 7169e561e1c4b4d7dc0e02e247dec9f740d5837bd808211944cd4861424007f0b6f72b2738b93622f8cb1c7457992aace4fcbd330b2fe9d4dcbe7a06b83102c3 SHA512 bd86e314afa6979655e643c8d7566504b92ec0b29ad44d1a9bd12e67913b9dad44b3ed57ef67330abe368948ba0e14e59a8fd2bb2a542252a8b885f8c4aee413

net-wireless/gnome-bluetooth/gnome-bluetooth-47.2.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{11..14} )
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="Bluetooth graphical utilities integrated with GNOME"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-bluetooth"
+
+LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
+SLOT="3/13" # subslot = libgnome-bluetooth-3 soname version
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="gtk-doc +introspection test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.44:2
+	>=gui-libs/gtk-4.15.2:4[introspection?]
+	media-libs/gsound
+	>=gui-libs/libadwaita-1.6_beta:1
+	>=x11-libs/libnotify-0.7.0
+	virtual/libudev:=
+	>=sys-power/upower-0.99.14:=
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
+"
+RDEPEND="${DEPEND}
+	acct-group/plugdev
+	virtual/udev
+	>=net-wireless/bluez-5
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libxml2:2
+	>=dev-util/gdbus-codegen-2.80.5-r1
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.9 )
+	virtual/pkgconfig
+	test? (
+		$(python_gen_any_dep '
+			>=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	if use test; then
+		python_has_version ">=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/dbus-python[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	# Check for python is unconditional
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dsendto=true
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# Workaround test failures caused by flatpak being installed that adds to XDG_DATA_DIRS
+	gnome2_environment_reset
+	export XDG_DATA_DIRS="${EPREFIX}"/usr/share
+
+	meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}