dev-python/dns-lexicon: Bump to 3.13.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/dns-lexicon/Manifest

@@ -1 +1,2 @@
 DIST dns-lexicon-3.12.0.gh.tar.gz 6729773 BLAKE2B 1566b98db71027a8c49c7c90060a67b0efc8dc8afb8c977c0277d29c751f26cabc824a510194f09d02f19a40151bfdebe877ccd3e0bfcc8484f694ce128c0d95 SHA512 4ba799c6f7a01b8209f5274337258d0525efff366b297fff2fcff1d40c7ee58850fa8c3743bf9d29a1a082288e1f615cd94036a9cdc7be9f85e46f26fe3d7fbc
+DIST dns-lexicon-3.13.0.gh.tar.gz 6739417 BLAKE2B 86f879fb5b27c6d9b21788ce4a9d7573b9aca0eccc022f4ac81cbb0e683f089797156134720bcbd82b509253470b01ee3ead3161517a0108d16991b668e1b4f3 SHA512 582efefb93d9f122cf3f900ddc7cf615295855645f6d9621f14c11067e441eb67349adf40e5159b75e8c5703d1cfd874364d392ce2994feb89949d371b4b55be

dev-python/dns-lexicon/dns-lexicon-3.13.0.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Manipulate DNS records on various DNS providers in a standardized/agnostic way"
+HOMEPAGE="
+	https://github.com/AnalogJ/lexicon/
+	https://pypi.org/project/dns-lexicon/
+"
+SRC_URI="
+	https://github.com/AnalogJ/lexicon/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/lexicon-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/importlib-metadata-4[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/tldextract[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/boto3-1.25[${PYTHON_USEDEP}]
+		dev-python/dnspython[${PYTHON_USEDEP}]
+		dev-python/zeep[${PYTHON_USEDEP}]
+		dev-python/vcrpy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Requires the "localzone" module
+	lexicon/tests/providers/test_localzone.py
+	# Requires the "softlayer" module
+	lexicon/tests/providers/test_softlayer.py
+	# Requires the "transip" module
+	lexicon/tests/providers/test_transip.py
+	# Requires the "oci" module
+	lexicon/tests/providers/test_oci.py
+	# Uses tldextract which needs Internet access to download its database
+	lexicon/tests/providers/test_auto.py
+	# All recordings seem to be broken
+	lexicon/tests/providers/test_namecheap.py
+	# Broken by minor vcrpy / urllib3-2 incompatibility
+	# https://github.com/kevin1024/vcrpy/issues/714
+	lexicon/tests/providers/test_route53.py
+)
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		optfeature_header \
+			"Install the following packages to enable support for additional DNS providers:"
+		optfeature Gransy dev-python/zeep
+		optfeature Route53 dev-python/boto3
+		optfeature DDNS dev-python/dnspython
+	fi
+}