sys-apps/rng-tools: add 6.17

Signed-off-by: Sam James <sam@gentoo.org>

sys-apps/rng-tools/Manifest

@@ -1 +1,2 @@
 DIST rng-tools-6.16.tar.gz 67401 BLAKE2B ab1a84c9a298e71ea5cdc1e91004ac069199a0128ee9701b1b3e24b6c705c63a642ab3db260a2c6c910c185e8fc75d5775caa3b7c370f102c75fac496e9bca17 SHA512 f4155dca8a54f47227f49ccf5f8453ddd50bd91a37b3b1659b5ad02278ed119028cee42918dd48552c79e19f2e2477277a41afa8e422395b2778b17fab09484d
+DIST rng-tools-6.17.tar.gz 69979 BLAKE2B 4e5a654369ef21ffe19c50fc60bb0242d48ee91c9ea839cde18379aba01fc3648019c610526a51d75094578e25f94a4aa23566bb2dc723b2ff447b9800bfc03f SHA512 fe874e578c0d5916c271ed5a96b87ed8bb5ce4238cc158471d390ca32864959206b0657dd5910ebb0730a3987f3bf9656690759f5a910d1c4a5891a27678e60d

sys-apps/rng-tools/rng-tools-6.17.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools readme.gentoo-r1 systemd
+
+DESCRIPTION="Daemon to use hardware random number generators"
+HOMEPAGE="https://github.com/nhorman/rng-tools"
+SRC_URI="https://github.com/nhorman/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="jitterentropy nistbeacon pkcs11 qrypt rtlsdr selinux test"
+REQUIRED_USE="test? ( jitterentropy )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/openssl:=
+	sys-libs/libcap
+	jitterentropy? ( app-crypt/jitterentropy:= )
+	nistbeacon? (
+		dev-libs/jansson:=
+		dev-libs/libxml2:2=
+		net-misc/curl[ssl]
+	)
+	pkcs11? ( dev-libs/libp11:= )
+	qrypt? (
+		dev-libs/jansson:=
+		net-misc/curl[ssl]
+	)
+	rtlsdr? ( net-wireless/rtl-sdr )
+	elibc_musl? ( sys-libs/argp-standalone )
+"
+RDEPEND="
+	${DEPEND}
+	selinux? ( sec-policy/selinux-rngd )
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	sed -i "s/sleep 30/sleep 120/g" tests/rngtestjitter.sh || die
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable jitterentropy)
+		$(use_with nistbeacon)
+		$(use_with pkcs11)
+		$(use_with rtlsdr)
+		$(use_with qrypt)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	RNGD_JITTER_TIMEOUT=90 default
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}"/rngd-initd-6.11 rngd
+	newconfd "${FILESDIR}"/rngd-confd-6.11 rngd
+	systemd_dounit rngd.service
+
+	if use pkcs11; then
+		local DISABLE_AUTOFORMATTING=1
+		local DOC_CONTENTS="
+The PKCS11 entropy source may require extra packages (e.g. 'dev-libs/opensc')
+to support various smartcard readers. Make sure 'PKCS11_OPTIONS' in:
+	'${EPREFIX}/etc/conf.d/rngd'
+reflects the correct PKCS11 engine path to be used by rngd.
+"
+		readme.gentoo_create_doc
+	fi
+}
+
+pkg_postinst() {
+	use pkcs11 && readme.gentoo_print_elog
+}