dev-libs/tvmet: fix LICENSE, update EAPI 7 -> 9

Fix LICENSE.

dev-libs/tvmet uses LGPL-2.1 with an addendum that modifies the license
conditions. Therefore a user must explicitly accept both the LGPL-2.1
and the TVMET-ADDENDUM to use the software.

NB: due to point 5 in the addendum, this is essentially badgeware.

Revbump and EAPI 7 -> 9

Link: https://tvmet.sourceforge.net/license.html
Signed-off-by: Brett A C Sheffield <bacs@librecast.net>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/321
Merges: https://codeberg.org/gentoo/gentoo/pulls/321
Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/tvmet/tvmet-1.7.2-r3.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=9
+
+DESCRIPTION="Tiny Vector Matrix library using Expression Templates"
+HOMEPAGE="http://tvmet.sourceforge.net/"
+SRC_URI="https://downloads.sourceforge.net/${PN}/${P}.tar.bz2"
+
+SLOT="0"
+LICENSE="LGPL-2.1 TVMET-ADDENDUM"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="doc? ( app-text/doxygen )"
+DEPEND="test? ( dev-util/cppunit )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-respect-cxxflags.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's|^GENERATE_LATEX.*|GENERATE_LATEX = NO|' \
+		doc/Doxyfile.in || die "sed failed"
+
+	# Doc installation is broken with newer Doxygen and autoconf <=2.61
+	# and we can't rerun autoconf without requiring cppunit unconditionally
+	sed -i \
+		-e '/^SUBDIRS/ s|doc ||' \
+		Makefile.in || die "sed failed"
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable doc docs) \
+		$(use_enable test cppunit)
+}
+
+src_compile() {
+	default
+
+	if use doc ; then
+		cd doc || die
+		doxygen Doxyfile || die "doxygen failed"
+	fi
+}
+
+src_install() {
+	default
+
+	if use doc ; then
+		docinto html
+		dodoc -r doc/html/*
+	fi
+}