kde-plasma/kwin-x11: 6.6.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
2026-11-10 06:57:08 -08:00 · 2026-02-24 21:45:23 +01:00
parent 2ab9acd818
commit 4337c2cf22
2 changed files with 120 additions and 0 deletions
@@ -1,2 +1,3 @@
 DIST kwin-x11-6.5.5.tar.xz 6872376 BLAKE2B 0f18933ac62cf36629e78863329ebb9c968c97b1f545bf3b86aa90ea11db5592f06881403132a405c91b1a161af80db0aafee1c55617fae55031997cd8428778 SHA512 d0fdbd748f1c203a5cf99aa4f49efc3c0f607ab22c7c8758314fc59be4bdba1e8019bc5e66d5ad26ae0172133fd2c33347996fa69a8d4d6aef51c3190e29ca93
 DIST kwin-x11-6.6.0.tar.xz 6891900 BLAKE2B e6111eeb0c93c7823dd048e42066f45a9abd7e81a409c4d2a6aab47837f2176824acdfc16296ab8d94bda3c3be4c0e41ab4dd1b3f9a43c0c5e7b5cd1e17431d9 SHA512 9bca9f6d93d75d625e8d5ec7f7568d81b38002db4b1d15b3aa5f8807818d96843da5a6aa223294be7e55678fed06405f9d867540f04c524b94163abe739a364c
+DIST kwin-x11-6.6.1.tar.xz 6880792 BLAKE2B 3c789af7846d15297c762ba34451540cc82cc4b4e55108ba88b7e992808f61ae4e6f961e55c32d81ee35c837f8086e63a340fa3ff2de38bc0ff08aa433a12c1e SHA512 eab767509afe5f9b9e02e1cf502c8f8ad569cfb562fe1febe14d89bd6a57c798c0110c1336f058d4ee75b04258ea922c32f756c5cd8b681836f8bd664bfb6000
@@ -0,0 +1,119 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KFMIN=6.22.0
+QTMIN=6.10.1
+inherit ecm plasma.kde.org xdg
+
+DESCRIPTION="Flexible, composited X window manager"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="accessibility gles2-only lock +shortcuts systemd"
+
+RESTRICT="test"
+
+# qtbase slot op: GuiPrivate use in tabbox
+COMMON_DEPEND="
+	>=dev-libs/wayland-1.24.0
+	>=dev-qt/qt5compat-${QTMIN}:6[qml]
+	>=dev-qt/qtbase-${QTMIN}:6=[accessibility=,gles2-only=,gui,opengl,wayland,widgets,X]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=dev-qt/qtsensors-${QTMIN}:6
+	>=dev-qt/qtshadertools-${QTMIN}:6
+	>=dev-qt/qtsvg-${QTMIN}:6
+	>=dev-qt/qttools-${QTMIN}:6[widgets]
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kcolorscheme-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6[qml]
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kdeclarative-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6[wayland]
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kidletime-${KFMIN}:6=[wayland]
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kpackage-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ksvg-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6=[wayland,X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-plasma/breeze-${KDE_CATV}:6
+	>=kde-plasma/kdecoration-${KDE_CATV}:6
+	>=kde-plasma/knighttime-${KDE_CATV}:6
+	>=kde-plasma/plasma-activities-${KDE_CATV}:6=
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/lcms:2
+	media-libs/libcanberra
+	>=media-libs/libdisplay-info-0.2.0:=
+	media-libs/libepoxy
+	media-libs/libglvnd
+	>=media-libs/mesa-24.1.0_rc1[opengl,X]
+	virtual/libudev:=
+	x11-libs/libX11
+	x11-libs/libXi
+	>=x11-libs/libdrm-2.4.116
+	>=x11-libs/libxcb-1.10:=
+	>=x11-libs/libxkbcommon-1.5.0
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-keysyms
+	x11-libs/xcb-util-wm
+	accessibility? ( media-libs/libqaccessibilityclient:6 )
+	lock? ( >=kde-plasma/kscreenlocker-${KDE_CATV}:6 )
+	shortcuts? ( >=kde-plasma/kglobalacceld-${KDE_CATV}:6 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!kde-plasma/kdeplasma-addons:5
+	!<kde-plasma/kwin-6.3.80
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=kde-plasma/aurorae-${KDE_CATV}:6
+	>=kde-plasma/libplasma-${KDE_CATV}:6
+	sys-apps/hwdata
+	>=x11-base/xwayland-23.1.0
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/plasma-wayland-protocols-1.16.0
+	>=dev-libs/wayland-protocols-1.38
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+	x11-base/xorg-proto
+	x11-libs/xcb-util-image
+	test? ( >=kde-plasma/kwayland-${KDE_CATV}:6 )
+"
+BDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[wayland]
+	dev-util/wayland-scanner
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# TODO: try to get a build switch upstreamed
+	if ! use systemd; then
+		sed -e "s/^pkg_check_modules.*libsystemd/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# KWIN_BUILD_NOTIFICATIONS exists, but kdeclarative still hard-depends on it
+		$(cmake_use_find_package accessibility QAccessibilityClient6)
+		-DKWIN_BUILD_SCREENLOCKER=$(usex lock)
+		-DKWIN_BUILD_GLOBALSHORTCUTS=$(usex shortcuts)
+	)
+
+	ecm_src_configure
+}