mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-22 10:57:07 -08:00
mate-extra/mate-screensaver: Bump to 1.24.0
Package-Manager: Portage-2.3.82, Repoman-2.3.18 Signed-off-by: Adam Feldman <NP-Hardass@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST mate-screensaver-1.22.1.tar.xz 4942928 BLAKE2B e82b6482ed9ec655bb8bea2795b0e2559cbdfcb2be5f27a2264486a2013b8234cb02292b6ca547f8812e6dc0c74646f51af8a2f8d7baf2f28bf1b688508350d5 SHA512 7ffb94d88095ff5580862fe9c958a2e4af7a424d40dc5e0f3c1da49a258035179573721fc7052710624916678e953a6347a898b53ff872a49e022987b8c02904
|
||||
DIST mate-screensaver-1.22.2.tar.xz 4943380 BLAKE2B 20d28ee7496af9fd9ac23d4f083eaee716eb97e1c3a9b921fc6b3655cfe4c6dc6e482827eb7fad40fbfd5dfb705bcac57aff3bf60e232b84562e496a7a56c354 SHA512 6d28f7261556d59af0bdb8c59ac13fc042c9c5b4cce47e7f6d4148041eb7f05d5cb062f85f05dddb51d009e4aebac31c21fc1243c0e07813adc050fede134ef3
|
||||
DIST mate-screensaver-1.24.0.tar.xz 5075860 BLAKE2B f669cb9ce1c84cdd2dd84b1c88b668ad1910102ae5d9765117d313b6ece03e535b5fdaae600d8f3315346ac1109d1316e15c0dcac5bd4a637b682fa7b5d1e22b SHA512 8947b85ab8b006a1756649131a9184e4eb8f44c563f5a1b55840aa8280820713bca1ce46fece92b5ac44a73193bfe965e8ef0d17e8e403a751807ee72c674cc0
|
||||
|
||||
@@ -0,0 +1,121 @@
|
||||
# Copyright 1999-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
|
||||
inherit mate readme.gentoo-r1
|
||||
|
||||
if [[ ${PV} != 9999 ]]; then
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Replaces xscreensaver, integrating with the MATE desktop"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
IUSE="X debug consolekit elogind kernel_linux libnotify opengl pam systemd"
|
||||
REQUIRED_USE="?? ( elogind systemd )"
|
||||
|
||||
DOC_CONTENTS="
|
||||
Information for converting screensavers is located in
|
||||
/usr/share/doc/${PF}/xss-conversion.txt*
|
||||
"
|
||||
|
||||
COMMON_DEPEND="
|
||||
>=dev-libs/dbus-glib-0.71:0
|
||||
>=dev-libs/glib-2.50:2
|
||||
gnome-base/dconf
|
||||
>=mate-base/libmatekbd-1.17.0
|
||||
>=mate-base/mate-desktop-1.17.0
|
||||
>=mate-base/mate-menus-1.21.0
|
||||
>=sys-apps/dbus-0.30
|
||||
>=x11-libs/gdk-pixbuf-2.14:2
|
||||
>=x11-libs/libX11-1
|
||||
x11-libs/cairo
|
||||
>=x11-libs/gtk+-3.22:3
|
||||
x11-libs/libXext
|
||||
x11-libs/libXrandr
|
||||
x11-libs/libXScrnSaver
|
||||
x11-libs/libXxf86vm
|
||||
x11-libs/libxklavier
|
||||
x11-libs/pango
|
||||
consolekit? ( sys-auth/consolekit )
|
||||
libnotify? ( >=x11-libs/libnotify-0.7:0 )
|
||||
opengl? ( virtual/opengl )
|
||||
pam? ( gnome-base/gnome-keyring sys-libs/pam )
|
||||
!pam? ( kernel_linux? ( sys-apps/shadow ) )
|
||||
elogind? ( sys-auth/elogind )
|
||||
systemd? ( sys-apps/systemd:= )
|
||||
"
|
||||
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
>=mate-base/mate-session-manager-1.6
|
||||
virtual/libintl
|
||||
!!<gnome-extra/gnome-screensaver-3
|
||||
"
|
||||
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
dev-libs/libxml2
|
||||
>=sys-devel/gettext-0.19.8:*
|
||||
x11-base/xorg-proto
|
||||
virtual/pkgconfig:*
|
||||
"
|
||||
|
||||
src_configure() {
|
||||
local myconf=(
|
||||
--enable-locking
|
||||
--with-kbd-layout-indicator
|
||||
--with-xf86gamma-ext
|
||||
--with-xscreensaverdir=/usr/share/xscreensaver/config
|
||||
--with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
|
||||
$(use_with X x)
|
||||
$(use_with consolekit console-kit)
|
||||
$(use_with elogind)
|
||||
$(use_with libnotify)
|
||||
$(use_with opengl libgl)
|
||||
$(use_with systemd)
|
||||
$(use_enable debug)
|
||||
$(use_enable pam)
|
||||
)
|
||||
|
||||
mate_src_configure "${myconf[@]}"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
mate_src_install
|
||||
|
||||
# Install the conversion script in the documentation.
|
||||
dodoc "${S}"/data/migrate-xscreensaver-config.sh
|
||||
dodoc "${S}"/data/xscreensaver-config.xsl
|
||||
dodoc "${FILESDIR}"/xss-conversion.txt
|
||||
|
||||
# Non PAM users will need this suid to read the password hashes.
|
||||
# OpenPAM users will probably need this too when
|
||||
# https://bugzilla.gnome.org/show_bug.cgi?id=370847
|
||||
# is fixed.
|
||||
if ! use pam ; then
|
||||
fperms u+s /usr/libexec/mate-screensaver-dialog
|
||||
fi
|
||||
|
||||
readme.gentoo_create_doc
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
mate_pkg_postinst
|
||||
|
||||
if has_version "<x11-base/xorg-server-1.5.3-r4" ; then
|
||||
ewarn "You have a too old xorg-server installation. This will cause"
|
||||
ewarn "mate-screensaver to eat up your CPU. Please consider upgrading."
|
||||
echo
|
||||
fi
|
||||
|
||||
if has_version "<x11-misc/xscreensaver-4.22-r2" ; then
|
||||
ewarn "You have xscreensaver installed, you probably want to disable it."
|
||||
ewarn "To prevent a duplicate screensaver entry in the menu, you need to"
|
||||
ewarn "build xscreensaver with -gnome in the USE flags."
|
||||
ewarn "echo \"x11-misc/xscreensaver -gnome\" >> /etc/portage/package.use"
|
||||
echo
|
||||
fi
|
||||
|
||||
readme.gentoo_print_elog
|
||||
}
|
||||
Reference in New Issue
Block a user