dev-python/imageio: Bump to 2.19.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/imageio/Manifest

@@ -1 +1,2 @@
 DIST imageio-2.19.1.gh.tar.gz 388314 BLAKE2B 447c2a666d6337926964d977fe45ec30d7995f486b59e03e8a0a68491db2fbcbffbb73946d51080fde5d2627d70fde1f6260f98205ff447e54b7349abdc839fd SHA512 01df54a84c7522ff8ffbc0141fb0ee3416f7b0e04d131473e02c8e18adac384d8f6f2e3f3148229c1d16509465b4a4597e38707bfc8991c6288f4ea1758b4101
+DIST imageio-2.19.2.gh.tar.gz 388434 BLAKE2B 4f0ec3f2586cbce7c15ff0551b8b5389d9236333eecda0870880c6dbe93bb2de464e57af7bc20c0f63aec6d53040a5140195d09c4c8a3c50c391a42b7847cf49 SHA512 6711a3be92f840d821f6539636072654d000932a6a7688384ae6bc007af5de41c8f90ed9a29e6401fd13219f50082ba5b75a1b383f1ac9242d568f95859de9c4

dev-python/imageio/imageio-2.19.2.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for reading and writing image data"
+HOMEPAGE="
+	https://imageio.readthedocs.io/en/stable/
+	https://github.com/imageio/imageio/
+	https://pypi.org/project/imageio/
+"
+SRC_URI="
+	https://github.com/imageio/imageio/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+# over 50% of tests rely on Internet
+PROPERTIES="test_network"
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/numpy-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/pillow-8.3.2[${PYTHON_USEDEP}]
+	media-libs/freeimage
+"
+# requests for fsspec[github]
+BDEPEND="
+	test? (
+		dev-python/fsspec[${PYTHON_USEDEP}]
+		dev-python/imageio-ffmpeg[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/tifffile[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Fails because of system installed freeimage
+	tests/test_core.py::test_findlib2
+	# Tries to download ffmpeg binary ?!
+	tests/test_ffmpeg.py::test_get_exe_installed
+)