Merge updates from master

This commit is contained in:
Repository mirror & CI
2024-09-18 05:34:11 +00:00
2 changed files with 115 additions and 0 deletions
+2
View File
@@ -2,3 +2,5 @@ DIST lynx2.9.0.tar.bz2 2781819 BLAKE2B 4380d46f28254bda241daae81c2072cd987cdbb4f
DIST lynx2.9.0.tar.bz2.asc 729 BLAKE2B 3221a794194554bd7b6fa577e9455a034802de715e93a9b0046ec4d9e367f0bf3a92b5780a7026c2a4a10cab8076d63964fe02f09bafea4f8fab08b27e3c7f6a SHA512 f08e46bf960a54656045d0874a3dd9811511589147bfe764efce43f87eb62d4a3e448b31edad60a485fc51f57d27dc0b87aae9df2e4dce5fbd9dea2f776a8f5d
DIST lynx2.9.0dev.12.tar.bz2 2762036 BLAKE2B 93bf762271b0419be73b11066b68dcf65e59f4eb1a5c221f0482bc0cad5e88e1cc83eb24c4c40316c37183c37db1178985d4478a2659c9e1b8322e8b6a4c6ff0 SHA512 9dd85d335a0b2c4c28f362cbcbe6499662696286fcc78e827bfafe2787d4a7fcd3faec78a115df8c14ea6e4314a5ea272f5b6353cb13224ecaebb61ae271701b
DIST lynx2.9.0dev.12.tar.bz2.asc 729 BLAKE2B 0e24df945b714acafc17974a908ca0246e4e4f506416cdb4fedb50a0b081fb87ac2b5e272fc27bbb1eee0aeef69ebb99b75583184e434e017b0edae3d9bde4d8 SHA512 fecfcbbf41f83285019a93b59d3ee38263aa0b8fc03914d41af1f9f3f77e1e376c8c686754d3e1a777d6aa853b4f3cfdca5d2a4ffa2ab3fe6ae4952e61a22e16
DIST lynx2.9.2.tar.bz2 2783769 BLAKE2B 875ac952e956071b1dfeb61fb5848a8a6435931d3ca1fbeef00e95e14d8510641b0b81683c7e2097c13c6cd6431e8b4243c47c5f983829af1a63140673794c23 SHA512 bb9ed23a5f8664ca8bccd95cc55683849aa707f601e209d84e0acaed151b78cd772316f527881022ff120049c4fc586c05d579f9d616a2b108d9ddfaa5b2159d
DIST lynx2.9.2.tar.bz2.asc 729 BLAKE2B fe8c3dd2a851a20363ab7e9ec498889965b9bb0f7f41cee3a84e451c630f2ec20c6255edd7f49bdc919612a92173755e991b9b13d7fde0d46274a8a6b0fa786c SHA512 2ec01cfa0928806837fdb4d499467e97c1ea90b62789015a7cf7c3ea60ee0eb3422c3cf88bb40f758560a85dfa2301e930ce20096a4f00038662951a1a5254ab
+113
View File
@@ -0,0 +1,113 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/thomasdickey.asc
inherit verify-sig
case ${PV} in
*_pre*) MY_P="${PN}${PV/_pre/dev.}" ;;
*_rc*) MY_P="${PN}${PV/_rc/pre.}" ;;
*_p*|*) MY_P="${PN}${PV/_p/rel.}" ;;
esac
DESCRIPTION="An excellent console-based web browser with ssl support"
HOMEPAGE="https://lynx.invisible-island.net/"
SRC_URI="https://invisible-island.net/archives/lynx/tarballs/${MY_P}.tar.bz2"
SRC_URI+=" verify-sig? ( https://invisible-island.net/archives/lynx/tarballs/${MY_P}.tar.bz2.asc )"
S="${WORKDIR}/${MY_P}"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="brotli bzip2 cjk gnutls idn nls ssl"
RDEPEND="
sys-libs/ncurses:=[unicode(+)]
sys-libs/zlib
brotli? ( app-arch/brotli:= )
bzip2? ( app-arch/bzip2 )
idn? ( net-dns/libidn2:= )
nls? ( virtual/libintl )
ssl? (
!gnutls? (
dev-libs/openssl:=
)
gnutls? (
dev-libs/libgcrypt:=
>=net-libs/gnutls-2.6.4:=
)
)"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
nls? ( sys-devel/gettext )
verify-sig? ( >=sec-keys/openpgp-keys-thomasdickey-20240114 )
"
PATCHES=(
"${FILESDIR}/${PN}-2.9.0-mint.patch"
"${FILESDIR}/${PN}-2.9.0-parallel.patch"
)
QA_CONFIG_IMPL_DECL_SKIP=(
# Doesn't exist on Linux
arc4random_push
)
src_configure() {
local myconf=(
--enable-cgi-links
--enable-color-style
--enable-externs
--enable-file-upload
--enable-included-msgs
--enable-ipv6
--enable-nested-tables
--enable-nsl-fork
--enable-persistent-cookies
--enable-prettysrc
--enable-read-eta
--enable-scrollbar
--with-screen=ncursesw
--with-zlib
$(use_enable cjk)
$(use_enable idn idna)
$(use_enable nls)
$(use_with brotli)
$(use_with bzip2 bzlib)
)
if use ssl; then
myconf+=(
--with-$(usex gnutls gnutls ssl)="${EPREFIX}/usr"
)
fi
econf "${myconf[@]}"
# Compared to openssl gnutls-openssl API does not use
# default trust store: bug #604526.
sed -e \
"s|#define SSL_CERT_FILE NULL|#define SSL_CERT_FILE \"${EPREFIX}/etc/ssl/certs/ca-certificates.crt\"|" \
-i userdefs.h || die
}
src_compile() {
# generating translation files in parallel is currently broken
use nls && emake -C po -j1
emake
}
src_install() {
emake install DESTDIR="${D}"
sed -i "s|^HELPFILE.*$|HELPFILE:file://localhost/usr/share/doc/${PF}/lynx_help/lynx_help_main.html|" \
"${ED}"/etc/lynx.cfg || die "lynx.cfg not found"
sed -i '/^#CHARACTER_SET:/ c\CHARACTER_SET:utf-8' \
"${ED}"/etc/lynx.cfg || die "lynx.cfg not found"
dodoc CHANGES COPYHEADER PROBLEMS README
dodoc -r docs lynx_help
}