sci-libs/linux-gpib-modules: Version bump

Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>

sci-libs/linux-gpib-modules/Manifest

@@ -1 +1,2 @@
+DIST linux-gpib-4.2.0.tar.gz 1431440 BLAKE2B 7b6adf562963e0785f960c072f3f3d67cb91df9090205d8fecb0dc3170d3a1ac3719732919bae112e06b47387499ffe49a0144e72caa27ba39c85c8b98e56786 SHA512 1505c2c04f16bf7e92b9dd474f09edd242520a96f9e4d8eea88ebd44d0a82d653055155c1bfcde69da5355d609d400e3cb682da8aae83f59f1e565307a3fc4a7
 DIST linux-gpib-kernel-4.2.0_rc1.tar.gz 332525 BLAKE2B e84f9da9902d139474cf68e49922f7b402c6d11113eab8c009683c1b4304a505eb6aba86a60b019e4d3ad0ef1d003c743f14f60b61b3d7f31e8aeca99a4a16c1 SHA512 8bf1a2b04d6128c513c5d13549fb95e563e719e43ffb3b303fc5aa2376f57a69774c1afdb901281933f6b253068461ce59bd9564146a0c5a6483e1ccc47d259f

sci-libs/linux-gpib-modules/linux-gpib-modules-4.2.0.ebuild

@@ -0,0 +1,88 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit linux-info linux-mod autotools toolchain-funcs
+
+DESCRIPTION="Kernel modules for GPIB (IEEE 488.2) hardware"
+HOMEPAGE="https://linux-gpib.sourceforge.io/"
+SRC_URI="mirror://sourceforge/linux-gpib/linux-gpib-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="isa pcmcia debug"
+
+COMMONDEPEND=""
+RDEPEND="${COMMONDEPEND}
+	!<sci-libs/linux-gpib-4.2.0_rc1
+"
+DEPEND="${COMMONDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.2.0_rc1-reallydie.patch
+)
+
+S=${WORKDIR}/linux-gpib-kernel-${PV}
+
+pkg_setup () {
+	linux-mod_pkg_setup
+
+	if kernel_is -lt 2 6 8; then
+		die "Kernel versions older than 2.6.8 are not supported."
+	fi
+
+	# https://sourceforge.net/p/linux-gpib/bugs/43/
+	if use pcmcia && kernel_is -ge 2 6 38; then
+		die "pcmcia support is broken on kernels newer 2.6.38"
+	fi
+}
+
+src_unpack() {
+	default
+	unpack "${WORKDIR}/linux-gpib-${PV}/linux-gpib-kernel-${PV}.tar.gz"
+}
+
+src_prepare () {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	set_arch_to_kernel
+	econf \
+		$(use_enable isa) \
+		$(use_enable pcmcia) \
+		$(use_enable debug driver-debug) \
+		--with-linux-srcdir=${KV_DIR}
+}
+
+src_compile() {
+	set_arch_to_kernel
+	emake \
+		DESTDIR="${D}" \
+		INSTALL_MOD_PATH="${D}" \
+		docdir=/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	set_arch_to_kernel
+	emake \
+		DESTDIR="${D}" \
+		INSTALL_MOD_PATH="${D}" \
+		DEPMOD="/bin/true" \
+		docdir=/usr/share/doc/${PF}/html install
+
+	dodoc ChangeLog AUTHORS README* NEWS
+}
+
+pkg_preinst () {
+	linux-mod_pkg_preinst
+	enewgroup gpib
+}
+
+pkg_postinst () {
+	linux-mod_pkg_postinst
+}