mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 22:27:17 -08:00
sci-geosciences/qgis: 3.0.0 version bump
Bug: https://bugs.gentoo.org/635798 Package-Manager: Portage-2.3.24, Repoman-2.3.6
This commit is contained in:
@@ -1,5 +1,6 @@
|
||||
DIST qgis-2.18.12.tar.bz2 84936155 BLAKE2B 0d47094ae8dac3101888140b5773a8e7b52d2562517bb30983592043267adc28d878ad644162ad04d84440497c567d075225db3db5a215440dee7258a8faade3 SHA512 e34dd98d0d0aa5fdf1f980dbc1376c25a9a7ffaa59b1a2eba8423e7f44bc039b547f3f65368178a8c485fa34526dd9fece2e09d9372fed3b9a758f7286b690ea
|
||||
DIST qgis-2.18.14.tar.bz2 84935301 BLAKE2B 37468062894235608f6efd0b58311e019f57ec0b3e6db63d8fef92ae93ac95ed13fe51290ebd063d31f1ea2318a23d7bdabb0774b451a2305064162addb4da29 SHA512 da738ae25f1207441a52091af9a3e70fd17f95704a23e27f72ee4c7ba213fd9ccf2d6685d91c34f94c555ca2dce420d6a07840b1fa682d6b960abdf3ba177036
|
||||
DIST qgis-2.18.16.tar.bz2 84976777 BLAKE2B ad68ce63698266bc081db7be0529ef50f66ee9c048b2e2a743cfc24d1ddb161c86c71283c09740a22c45476f863516f8855c69a5ccf074e9676d1ed5a09563a1 SHA512 1fe060c1d392f304eea10a211815e14081299a865e34114625f3a5f2a1b365f571bb30878a21cbf25bc32285ffc689d37cb7dbcab129ce5f03ccd6fa0781876d
|
||||
DIST qgis-3.0.0.tar.bz2 94186303 BLAKE2B 2b2623c218a86af22ee13e1271e66244fc6191732db6bc694860015824525188308609c8758062910ba7065ca6790d4091beb15ff324d1a8410e65525cf785b0 SHA512 91201c5d48f9450734a6268f70cba830e363db15a979266af1a7f2ef73857ca11e89145d027f394d052d0536e54b4f62523b1ad49bbe698743fec882ceecfabe
|
||||
DIST qgis_sample_data-2.8.14.tar.gz 22119181 BLAKE2B 2d0565e91ec8119382bc9ab8e262dc04227fe8289146794891759ff5a32012245270614ba1119a6329fc45cf56852830c2079589309aa3467873f71f5c608eac SHA512 6b2653d5b57ffc2c2317639dac212429840984ac917ca3e452b39aabb99ea106d1a77c1c1dd967244ef16ede9deae751b170affdf08b72239eafed5b8977da3d
|
||||
DIST qgis_sample_data.tar.gz 13601736 BLAKE2B 92acadbd009b181e74516120b3a700c96c7c1a732240434439bbe51afa441dee6521dac7bf6629fb5d7489b63fd0e0a45b1871df099820e8cd594920fa1499b7 SHA512 5847d7b32e5f75e771adf6b959847024f55b2360c307bd80e5628595fc53f5aaca18adf6cb00fa027a7e7b326c7f72bab58df16674daf20b77c676e163d93f78
|
||||
|
||||
@@ -0,0 +1,211 @@
|
||||
# Copyright 1999-2018 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
|
||||
PYTHON_COMPAT=( python3_5 )
|
||||
PYTHON_REQ_USE="sqlite"
|
||||
QT_MIN_VER="5.9.1"
|
||||
|
||||
if [[ ${PV} != *9999 ]]; then
|
||||
SRC_URI="https://qgis.org/downloads/${P}.tar.bz2
|
||||
examples? ( https://qgis.org/downloads/data/qgis_sample_data.tar.gz -> qgis_sample_data-2.8.14.tar.gz )"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
else
|
||||
GIT_ECLASS="git-r3"
|
||||
EGIT_REPO_URI="https://github.com/${PN}/${PN^^}.git"
|
||||
fi
|
||||
inherit cmake-utils eutils ${GIT_ECLASS} gnome2-utils python-single-r1 qmake-utils xdg-utils
|
||||
unset GIT_ECLASS
|
||||
|
||||
DESCRIPTION="User friendly Geographic Information System"
|
||||
HOMEPAGE="https://www.qgis.org/"
|
||||
|
||||
LICENSE="GPL-2+ GPL-3+"
|
||||
SLOT="0"
|
||||
IUSE="designer examples georeferencer grass mapserver oracle polar postgres python webkit"
|
||||
|
||||
REQUIRED_USE="
|
||||
mapserver? ( python )
|
||||
python? ( ${PYTHON_REQUIRED_USE} )"
|
||||
|
||||
COMMON_DEPEND="
|
||||
app-crypt/qca:2[qt5(+),ssl]
|
||||
>=dev-db/spatialite-4.2.0
|
||||
dev-db/sqlite:3
|
||||
dev-libs/expat
|
||||
dev-libs/libzip:=
|
||||
dev-libs/qtkeychain[qt5(+)]
|
||||
>=dev-qt/qtconcurrent-${QT_MIN_VER}:5
|
||||
>=dev-qt/qtcore-${QT_MIN_VER}:5
|
||||
>=dev-qt/qtgui-${QT_MIN_VER}:5
|
||||
>=dev-qt/qtnetwork-${QT_MIN_VER}:5
|
||||
>=dev-qt/qtpositioning-${QT_MIN_VER}:5
|
||||
>=dev-qt/qtprintsupport-${QT_MIN_VER}:5
|
||||
>=dev-qt/qtsvg-${QT_MIN_VER}:5
|
||||
>=dev-qt/qtsql-${QT_MIN_VER}:5
|
||||
>=dev-qt/qtwidgets-${QT_MIN_VER}:5
|
||||
>=dev-qt/qtxml-${QT_MIN_VER}:5
|
||||
>=sci-libs/gdal-2.2.3:=[geos,python?,${PYTHON_USEDEP}]
|
||||
sci-libs/geos
|
||||
sci-libs/libspatialindex:=
|
||||
sci-libs/proj
|
||||
>=x11-libs/qscintilla-2.10.1:=[qt5(+)]
|
||||
>=x11-libs/qwt-6.1.2:6=[qt5(+),svg]
|
||||
designer? ( >=dev-qt/designer-${QT_MIN_VER}:5 )
|
||||
georeferencer? ( sci-libs/gsl:= )
|
||||
grass? ( >=sci-geosciences/grass-7.0.0:= )
|
||||
mapserver? ( dev-libs/fcgi )
|
||||
oracle? (
|
||||
dev-db/oracle-instantclient:=
|
||||
sci-libs/gdal:=[oracle]
|
||||
)
|
||||
polar? ( >=x11-libs/qwtpolar-1.1.1-r1[qt5(+)] )
|
||||
postgres? ( dev-db/postgresql:= )
|
||||
python? ( ${PYTHON_DEPS}
|
||||
dev-python/future[${PYTHON_USEDEP}]
|
||||
dev-python/httplib2[${PYTHON_USEDEP}]
|
||||
dev-python/jinja[${PYTHON_USEDEP}]
|
||||
dev-python/markupsafe[${PYTHON_USEDEP}]
|
||||
dev-python/owslib[${PYTHON_USEDEP}]
|
||||
dev-python/pygments[${PYTHON_USEDEP}]
|
||||
dev-python/PyQt5[sql,svg,webkit?,${PYTHON_USEDEP}]
|
||||
dev-python/python-dateutil[${PYTHON_USEDEP}]
|
||||
dev-python/pytz[${PYTHON_USEDEP}]
|
||||
dev-python/pyyaml[${PYTHON_USEDEP}]
|
||||
>=dev-python/qscintilla-python-2.10.1[qt5(+),${PYTHON_USEDEP}]
|
||||
dev-python/requests[${PYTHON_USEDEP}]
|
||||
dev-python/sip:=[${PYTHON_USEDEP}]
|
||||
dev-python/six[${PYTHON_USEDEP}]
|
||||
postgres? ( dev-python/psycopg:2[${PYTHON_USEDEP}] )
|
||||
)
|
||||
webkit? ( >=dev-qt/qtwebkit-${QT_MIN_VER}:5 )
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
>=dev-qt/linguist-tools-${QT_MIN_VER}:5
|
||||
>=dev-qt/qttest-${QT_MIN_VER}:5
|
||||
>=dev-qt/qtxmlpatterns-${QT_MIN_VER}:5
|
||||
sys-devel/bison
|
||||
sys-devel/flex
|
||||
"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
sci-geosciences/gpsbabel
|
||||
"
|
||||
|
||||
# Disabling test suite because upstream disallow running from install path
|
||||
RESTRICT="test"
|
||||
|
||||
PATCHES=(
|
||||
# git master
|
||||
"${FILESDIR}/${PN}-2.18.12-cmake-lib-suffix.patch"
|
||||
)
|
||||
|
||||
pkg_setup() {
|
||||
python-single-r1_pkg_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
cmake-utils_src_prepare
|
||||
|
||||
sed -e "s:\${QT_BINARY_DIR}:$(qt5_get_bindir):" \
|
||||
-i CMakeLists.txt || die "Failed to fix lrelease path"
|
||||
|
||||
sed -e "/QT_LRELEASE_EXECUTABLE/d" \
|
||||
-e "/QT_LUPDATE_EXECUTABLE/s/set/find_program/" \
|
||||
-e "s:lupdate-qt5:NAMES lupdate PATHS $(qt5_get_bindir) NO_DEFAULT_PATH:" \
|
||||
-i cmake/modules/ECMQt4To5Porting.cmake || die "Failed to fix ECMQt4To5Porting.cmake"
|
||||
|
||||
cd src/plugins || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DQGIS_MANUAL_SUBDIR=/share/man/
|
||||
-DBUILD_SHARED_LIBS=ON
|
||||
-DQGIS_LIB_SUBDIR=$(get_libdir)
|
||||
-DQGIS_PLUGIN_SUBDIR=$(get_libdir)/qgis
|
||||
-DQWT_INCLUDE_DIR=/usr/include/qwt6
|
||||
-DQWT_LIBRARY=/usr/$(get_libdir)/libqwt6-qt5.so
|
||||
-DPEDANTIC=OFF
|
||||
-DWITH_APIDOC=OFF
|
||||
-DWITH_QSPATIALITE=ON
|
||||
-DENABLE_TESTS=OFF
|
||||
-DWITH_CUSTOM_WIDGETS=$(usex designer)
|
||||
-DWITH_GEOREFERENCER=$(usex georeferencer)
|
||||
-DWITH_GRASS=$(usex grass)
|
||||
-DWITH_SERVER=$(usex mapserver)
|
||||
-DWITH_ORACLE=$(usex oracle)
|
||||
-DWITH_QWTPOLAR=$(usex polar)
|
||||
-DWITH_POSTGRESQL=$(usex postgres)
|
||||
-DWITH_BINDINGS=$(usex python)
|
||||
-DWITH_QTWEBKIT=$(usex webkit)
|
||||
)
|
||||
|
||||
if use grass; then
|
||||
mycmakeargs+=(
|
||||
-DWITH_GRASS7=ON
|
||||
-DGRASS_PREFIX7=/usr/$(get_libdir)/grass70
|
||||
)
|
||||
fi
|
||||
|
||||
use python && mycmakeargs+=( -DBINDINGS_GLOBAL_INSTALL=ON )
|
||||
|
||||
# bug 612956
|
||||
addpredict /dev/dri/renderD128
|
||||
|
||||
cmake-utils_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake-utils_src_install
|
||||
|
||||
domenu debian/qgis.desktop
|
||||
|
||||
local size type
|
||||
for size in 16 22 24 32 48 64 96 128 256; do
|
||||
newicon -s ${size} debian/icons/${PN}-icon${size}x${size}.png ${PN}.png
|
||||
newicon -c mimetypes -s ${size} debian/icons/${PN}-mime-icon${size}x${size}.png ${PN}-mime.png
|
||||
for type in qgs qml qlr qpt; do
|
||||
newicon -c mimetypes -s ${size} debian/icons/${PN}-${type}${size}x${size}.png ${PN}-${type}.png
|
||||
done
|
||||
done
|
||||
newicon -s scalable images/icons/qgis_icon.svg qgis.svg
|
||||
|
||||
insinto /usr/share/mime/packages
|
||||
doins debian/qgis.xml
|
||||
|
||||
if use examples; then
|
||||
docinto examples
|
||||
dodoc -r "${WORKDIR}"/qgis_sample_data/.
|
||||
docompress -x /usr/share/doc/${PF}/examples
|
||||
fi
|
||||
|
||||
python_optimize "${ED%/}"/usr/share/qgis/python
|
||||
|
||||
if use grass; then
|
||||
python_fix_shebang "${ED%/}"/usr/share/qgis/grass/scripts
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
if use postgres; then
|
||||
elog "If you don't intend to use an external PostGIS server"
|
||||
elog "you should install:"
|
||||
elog " dev-db/postgis"
|
||||
elif use python; then
|
||||
elog "Support of PostgreSQL is disabled."
|
||||
elog "But some installed python-plugins import the psycopg2 module."
|
||||
elog "If you do not need these plugins just disable them"
|
||||
elog "in the Plugins menu, else you need to set USE=\"postgres\""
|
||||
fi
|
||||
|
||||
gnome2_icon_cache_update
|
||||
xdg_mimeinfo_database_update
|
||||
xdg_desktop_database_update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
gnome2_icon_cache_update
|
||||
xdg_mimeinfo_database_update
|
||||
xdg_desktop_database_update
|
||||
}
|
||||
@@ -96,8 +96,6 @@ RDEPEND="${COMMON_DEPEND}
|
||||
RESTRICT="test"
|
||||
|
||||
PATCHES=(
|
||||
# Taken from redhat
|
||||
"${FILESDIR}/${PN}-2.18.12-sip.patch"
|
||||
# git master
|
||||
"${FILESDIR}/${PN}-2.18.12-cmake-lib-suffix.patch"
|
||||
)
|
||||
|
||||
Reference in New Issue
Block a user