dev-python/kombu: add 5.3.0_beta2

Signed-off-by: Anna Vyalkova <cyber+gentoo@sysrq.in>
Closes: https://github.com/gentoo/gentoo/pull/27880
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/kombu/Manifest

@@ -1 +1,2 @@
 DIST kombu-5.2.4.tar.gz 423450 BLAKE2B d0a180a4644876594eacea51706ca74fa4a95729ba965f69694da9694c2a91641ccf05aa1aec8a64f9d8c2260477d00bc2664d0a50143562b46524c98e4159b1 SHA512 695813bee71d627649e772b45b25494784a6a81bcad92331160705e34d8b2268fa90629983ebcfd04ec23208508d422f1834cc56895532911602d58ec0090a03
+DIST kombu-5.3.0b2.tar.gz 434341 BLAKE2B 6d5188f7682ccf2daa6ca4ed0fec7988cd4781954be0fdc847c18e47d5c425a657c3df0f5bda7999c764de293626e119a4645e92ff7bf23328f4fcb9d6f4cd4a SHA512 3000577cc3b2acfb378396640245f2bdf4c9e5e1d45252a27e4e168e22ff4070f480ad1fd70059b24cd710c452924bff1716f69bedcf020446f428f0967de832

dev-python/kombu/kombu-5.3.0_beta2.ebuild

@@ -0,0 +1,94 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+MY_PV="${PV//_beta/b}"
+MY_P="${PN}-${MY_PV}"
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+	https://github.com/celery/kombu/
+	https://pypi.org/project/kombu/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/py-amqp-5.1.1[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+		dev-python/Pyro4[${PYTHON_USEDEP}]
+		dev-python/pytest-freezegun[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-py-4.2.2[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_celery
+
+EPYTEST_IGNORE=(
+	# Unpackaged azure-servicebus
+	t/unit/transport/test_azureservicebus.py
+	# Unpackaged librabbitmq
+	t/unit/transport/test_librabbitmq.py
+	# Unpackaged python-consul
+	t/unit/transport/test_consul.py
+	# AttributeError: test_Etcd instance has no attribute 'patch'
+	t/unit/transport/test_etcd.py
+)
+
+python_test() {
+	local EPYTEST_DESELECT
+
+	# AttributeError: 'str' object has no attribute 'load'
+	[[ ${EPYTHON} == python3.10 ]] && \
+		EPYTEST_DESELECT+=( t/unit/utils/test_compat.py::test_entrypoints )
+
+	epytest
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Pyro 4 backend" dev-python/Pyro4
+	optfeature "Redis backend" dev-python/redis-py
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}