gui-wm/labwc: add 0.9.8

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

gui-wm/labwc/Manifest

@@ -1,2 +1,3 @@
 DIST labwc-0.20.0.tar.gz 548211 BLAKE2B 09a7d5bc1b775d370cfc294a76a679aac441f3bf5518bd5e271c398ecf64ca506e2096a625f467e34252668310852113d07d84e6d1caaf76f800271ea6f8094a SHA512 47958a3b386d2db344ac069edc56c533ac795f73048db1246172bfe22d26f51082a4dd9bdd40b5d7eeb52bb034d588b1b870e81c70b4ca9529502a9dc62da403
 DIST labwc-0.9.7.tar.gz 548483 BLAKE2B b8b4bdd295aeb9a051961dedfbd5cbeff611a5700914e0e5c6bbafd2523b3db9fde2d98bef4300fa3c03d44e4d219aeacba3bbe0ac07d8e7090d2028df68536b SHA512 299b6b46961450d60355b45d8e5565d64800abc58e2ef95d6c8f27b9665ff45712108611d4272450761c962d3943de2b73c9de55a2d1189a061eb24985ccfbe6
+DIST labwc-0.9.8.tar.gz 548854 BLAKE2B 2bb16b7fbf3817e45327773c38d7692a56bcd74e6a2cf0b5cee6d4b1e280c50e9ea7b739238bd1bd606d7e292d465f1f3293ff253c0d00d0a207e21cfed729bc SHA512 19d4c19ec4f208e24c2559a0803b32b1593c5babfde4469e10314e50b93cfe718c35a8ebb915383e0005fc15a82bf0b9a6035af88537a36215a750fdbff6305e

gui-wm/labwc/labwc-0.9.8.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+DESCRIPTION="Openbox alternative for wayland"
+HOMEPAGE="https://github.com/labwc/labwc https://labwc.github.io/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/labwc/labwc"
+else
+	SRC_URI="https://github.com/labwc/labwc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="X icons nls svg test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/wayland-1.19
+	dev-libs/glib:2
+	dev-libs/libinput:=
+	dev-libs/libxml2:=
+	gui-libs/wlroots:0.19[X?,libinput]
+	media-libs/libpng:=
+	x11-libs/cairo[X?]
+	x11-libs/libdrm:=
+	x11-libs/libxkbcommon[X?]
+	x11-libs/pango[X?]
+	x11-libs/pixman
+	X? (
+		x11-base/xwayland
+		x11-libs/libxcb:0=
+		x11-libs/xcb-util-wm
+	)
+	icons? ( gui-libs/libsfdo )
+	nls? ( sys-devel/gettext )
+	svg? ( gnome-base/librsvg:2 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-text/scdoc
+	>=dev-libs/wayland-protocols-1.35
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( dev-util/cmocka )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=enabled
+		$(meson_feature X xwayland)
+		$(meson_feature nls)
+		$(meson_feature svg)
+		$(meson_feature icons icon)
+		$(meson_feature test)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	mv "${ED}"/usr/share/doc/${PN} "${ED}"/usr/share/doc/${PF} || die
+}