gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 12:58:16 -07:00
Code Issues Projects Releases Wiki Activity

kde-apps/okular: 25.08.3 version bump

Browse Source 
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2025-11-06 16:34:07 +01:00
parent 8b258745d9
commit 41634bfa4f
2 changed files with 100 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
kde-apps/okular/Manifest
View File

@@ -1 +1,2 @@
DIST okular-25.08.2.tar.xz 8202524 BLAKE2B ef35de30048f02a7471c041dafae44fb6361395c55146cb506e230484e21b1f25b58ee4c645bed1baf104a4e6ded7c32a276f93453fcb100b7d66e5b04387c79 SHA512 e7a4be24e446a18dbe83607f12c348a35bc28e0147eaf49d3386ff028f36dbfdd10c93d9f49af96ec7bd95e880f61db4fadf6dbb731743216c4654ebc556bdd1
DIST okular-25.08.3.tar.xz 8203744 BLAKE2B 63216355d83433260585c8a90191444db09305c9faa7b883b136417d9c9bdcb3d267b73e305523862e4a876b3b6604711daccd81223b7bfa3435a827f475b778 SHA512 370aa227ddfc1c08de86a60f0ceeca0fd64bbd57a24f14f6c594b1f2e3c784dc861280ee187451282c8d596995bcd8c9dd5ec78a86f027d2cd2ce0e2097aeb51

99
kde-apps/okular/okular-25.08.3.ebuild Normal file
View File

@@ -0,0 +1,99 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="forceoptional"
PVCUT=$(ver_cut 1-3)
KFMIN=6.16.0
QTMIN=6.9.1
inherit ecm gear.kde.org xdg
DESCRIPTION="Universal document viewer based on KDE Frameworks"
HOMEPAGE="https://okular.kde.org https://apps.kde.org/okular/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="crypt djvu epub markdown mobi +pdf phonon +postscript qml share speech +tiff"
# slot op: Uses Qt6::CorePrivate
DEPEND="
>=dev-qt/qtbase-${QTMIN}:6=[dbus,gui,widgets,X,xml]
>=dev-qt/qtdeclarative-${QTMIN}:6
>=dev-qt/qtsvg-${QTMIN}:6
>=kde-apps/libkexiv2-${PVCUT}:6
>=kde-frameworks/karchive-${KFMIN}:6
>=kde-frameworks/kbookmarks-${KFMIN}:6
>=kde-frameworks/kcolorscheme-${KFMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kitemviews-${KFMIN}:6
>=kde-frameworks/kparts-${KFMIN}:6
>=kde-frameworks/kpty-${KFMIN}:6
>=kde-frameworks/ktextwidgets-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/threadweaver-${KFMIN}:6
media-libs/freetype
virtual/zlib:=
crypt? ( >=kde-frameworks/kwallet-${KFMIN}:6 )
djvu? ( app-text/djvu )
epub? ( app-text/ebook-tools )
markdown? ( >=app-text/discount-2.2.7-r1:= )
mobi? ( >=kde-apps/kdegraphics-mobipocket-${PVCUT}:6 )
pdf? ( >=app-text/poppler-24.10.0[nss,qt6] )
phonon? ( >=media-libs/phonon-4.12.0[qt6(+)] )
postscript? ( app-text/libspectre )
share? ( >=kde-frameworks/purpose-${KFMIN}:6 )
speech? ( >=dev-qt/qtspeech-${QTMIN}:6 )
tiff? ( media-libs/tiff:= )
"
RDEPEND="${DEPEND}
>=kde-frameworks/kimageformats-${KFMIN}:6
qml? ( >=kde-frameworks/kirigami-${KFMIN}:6 )
"
PATCHES=(
"${FILESDIR}/${PN}-20.08.2-hide-mobile-app.patch" # downstream; avoid same-name entry
"${FILESDIR}/${PN}-23.08.5-implicit-vasprintf.patch" # bug 922345; pending upstream
"${FILESDIR}/${PN}-25.08.1-obsolete-activities.patch" # bug 824546; in git master
)
src_configure() {
local mycmakeargs=(
-DFORCE_NOT_REQUIRED_DEPENDENCIES="KF6DocTools;KF6Wallet;DjVuLibre;EPub;Discount;QMobipocket6;Poppler;LibSpectre;KF6Purpose;Qt6TextToSpeech;TIFF;"
-DOKULAR_UI=$(usex qml "both" "desktop")
$(cmake_use_find_package crypt KF6Wallet)
$(cmake_use_find_package djvu DjVuLibre)
$(cmake_use_find_package epub EPub)
$(cmake_use_find_package markdown Discount)
$(cmake_use_find_package mobi QMobipocket6)
$(cmake_use_find_package pdf Poppler)
$(cmake_use_find_package phonon Phonon4Qt6)
$(cmake_use_find_package postscript LibSpectre)
$(cmake_use_find_package share KF6Purpose)
$(cmake_use_find_package speech Qt6TextToSpeech)
$(cmake_use_find_package tiff TIFF)
)
ecm_src_configure
}
src_test() {
# mainshelltest hangs, bug #603116
# parttest hangs, bug #641728, annotationtoolbartest fails, KDE-Bug #429640
# signunsignedfieldtest fails, whatever. bug #852749
local myctestargs=(
-E "(mainshelltest|parttest|annotationtoolbartest|signunsignedfieldtest)"
)
ecm_src_test
}