net-misc/gnome-remote-desktop: Version bump to 47.3

Signed-off-by: Lukas Schmelting <lschmelting@posteo.com>
Part-of: https://github.com/gentoo/gentoo/pull/42537
Signed-off-by: Sam James <sam@gentoo.org>

net-misc/gnome-remote-desktop/Manifest

@@ -1,2 +1,3 @@
 DIST gnome-remote-desktop-46.3.tar.xz 273304 BLAKE2B dd959c0fabf183afd0be39da84f344589d5f5a6defaa298141bba4aeb3a39b253c962095efe35e425c106ae7126ddf2b3c8bba79b43054e26d0e0ff61c8e5ce5 SHA512 4e12ef3156eae8a1770646dd10235f0950ca34bd60bd8358958fe98696c2eb3af9ed9a2ad37239de9b4f25e0991bb7248a1d0f89e4b67c34430d5980064d4319
 DIST gnome-remote-desktop-47.1.tar.xz 283864 BLAKE2B 17c70fe8b5642d9abb77e1fee12328ea9c2f1ada146f39b374432441de44c37f190dfaf2d420403d676478b466e89fa43b47d25ad080e1f7d69e4afa8c0dd01d SHA512 072d4064d23976eaf76a3293c313a6e121a33ab5ab5aa9557e6065579b72cfeae3e070db705c9d1d07dbb9fd5633ab5014aa1d4f022bc0b9a15ee2120589b75c
+DIST gnome-remote-desktop-47.3.tar.xz 287080 BLAKE2B 8bcaf7fa28a2c2ba8082d7c8515fad90db7a339458854da0c0c7ff605f10d0c6f8e1eb0caad6732aff4d2caa9c59fd2dae03dad5481198b92a10c95012ca0f62 SHA512 6a2da7fd3c09d47594eee53146fcc9c467844ce4d0282b4fb88f265016e3fd11f7ee5629cc70164427c024ad91b07021d5a5b9f771e983accc6019c17a0c5f7f

net-misc/gnome-remote-desktop/gnome-remote-desktop-47.3.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd tmpfiles xdg
+
+DESCRIPTION="Remote desktop server which allows you to connect to your machine remotely"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="doc +rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	x11-libs/libdrm
+	>=media-libs/libepoxy-1.4
+	>=dev-libs/glib-2.75:2
+	>=dev-libs/libei-1.2.0
+	x11-libs/libnotify
+	app-crypt/libsecret
+	>=media-video/pipewire-0.3.49:=
+	app-crypt/tpm2-tss:=
+	rdp? (
+		>=media-libs/nv-codec-headers-11.1.5.0
+		>=net-misc/freerdp-3.1.0:=[server]
+		>=sys-fs/fuse-3.9.1:3=
+		>=sys-auth/polkit-122
+		>=x11-libs/libxkbcommon-1.0.0
+		media-libs/fdk-aac:=
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	acct-user/gnome-remote-desktop
+	acct-group/gnome-remote-desktop
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	dev-libs/glib
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+	doc? (
+		app-text/asciidoc
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc man)
+		$(meson_use rdp)
+		$(meson_use vnc)
+		$(meson_use systemd)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+		-Dtests=false  # Tests run xvfb-run directly
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	tmpfiles_process "${PN}-tmpfiles.conf"
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}