gui-libs/libdecor: new package, add 0.2.2, 9999

Closes: https://bugs.gentoo.org/927186
Signed-off-by: Gonçalo Negrier Duarte <gonegrier.duarte@gmail.com>
Signed-off-by: James Le Cuirot <chewi@gentoo.org>

gui-libs/libdecor/Manifest

@@ -0,0 +1 @@
+DIST libdecor-0.2.2.tar.bz2 45375 BLAKE2B 86e78ce5017b0babc627b5f9ce75b7e2cca38929e3c382828e0453329efed707e2c010fb51522b7b5077a616d54cf2f9af70d5b3d68d2b2aa1d6d36b7a834b8d SHA512 f9761a8c59dc85dd92c871f73192ab05eb56ea34e85a38b5a7222822173f9fd71b5bfb5cffe2782e8c0a6275100e32b6761143cb1469dbcc6988d046a09f1b9a

gui-libs/libdecor/libdecor-0.2.2.ebuild

@@ -0,0 +1,54 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="A client-side decorations library for Wayland clients"
+HOMEPAGE="https://gitlab.freedesktop.org/libdecor/libdecor"
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/libdecor/libdecor.git"
+	inherit git-r3
+else
+	SRC_URI="https://gitlab.freedesktop.org/libdecor/libdecor/-/archive/${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64"
+fi
+LICENSE="MIT"
+SLOT="0"
+IUSE="+dbus +gtk examples"
+
+RDEPEND="
+	>=dev-libs/wayland-1.18
+	x11-libs/pango
+	x11-libs/cairo
+	dbus? ( sys-apps/dbus )
+	gtk? ( x11-libs/gtk+:3 )
+	examples? (
+		media-libs/libglvnd
+		x11-libs/libxkbcommon
+	)
+"
+
+DEPEND="
+	${RDEPEND}
+	>=dev-libs/wayland-protocols-1.15
+"
+
+BDEPEND="
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		# Avoid auto-magic, built-in feature of meson
+		-Dauto_features=disabled
+		$(meson_feature gtk)
+		$(meson_feature dbus)
+		$(meson_use examples demo)
+		-Dinstall_demo=true
+	)
+
+	meson_src_configure
+}

gui-libs/libdecor/libdecor-9999.ebuild

@@ -0,0 +1,54 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="A client-side decorations library for Wayland clients"
+HOMEPAGE="https://gitlab.freedesktop.org/libdecor/libdecor"
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/libdecor/libdecor.git"
+	inherit git-r3
+else
+	SRC_URI="https://gitlab.freedesktop.org/libdecor/libdecor/-/archive/${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64"
+fi
+LICENSE="MIT"
+SLOT="0"
+IUSE="+dbus +gtk examples"
+
+RDEPEND="
+	>=dev-libs/wayland-1.18
+	x11-libs/pango
+	x11-libs/cairo
+	dbus? ( sys-apps/dbus )
+	gtk? ( x11-libs/gtk+:3 )
+	examples? (
+		media-libs/libglvnd
+		x11-libs/libxkbcommon
+	)
+"
+
+DEPEND="
+	${RDEPEND}
+	>=dev-libs/wayland-protocols-1.15
+"
+
+BDEPEND="
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		# Avoid auto-magic, built-in feature of meson
+		-Dauto_features=disabled
+		$(meson_feature gtk)
+		$(meson_feature dbus)
+		$(meson_use examples demo)
+		-Dinstall_demo=true
+	)
+
+	meson_src_configure
+}

gui-libs/libdecor/metadata.xml

@@ -0,0 +1,24 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<use>
+		<flag name="dbus">Enable dbus to query current cursor theme</flag>
+		<flag name="gtk">Build GTK plugin</flag>
+		<flag name="examples">Build and install examples</flag>
+	</use>
+	<maintainer type="person">
+		<email>chewi@gentoo.org</email>
+		<name>James Le Cuirot</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Gentoo Proxy Maintainers</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>gonegrier.duarte@gmail.com</email>
+		<name>Gonçalo Negrier Duarte</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="freedesktop-gitlab">libdecor/libdecor</remote-id>
+	</upstream>
+</pkgmetadata>