sys-cluster/libqb: version bump

closes #720910 #775605

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Alexys Jacob <ultrabug@gentoo.org>

sys-cluster/libqb/Manifest

@@ -1 +1,2 @@
 DIST libqb-2.0.1.tar.xz 480516 BLAKE2B 402ca20f16a232497c9a363c557556bbdcfffff5d0f075898bf4008bb51b30771f284c29b64421be1dae8215e153b8978ac06c9bd10f3e5e23632b597549d2c7 SHA512 6d989d30b381253c7d7c4ff1e6400ad3445b92184906c859f10d6352dd604a309d7e2d9c8298d8b8d59a0e884e2d821608a39f043db7e96db2118a867ef57672
+DIST libqb-2.0.4.tar.xz 504444 BLAKE2B a363a06bcfc34557e634b9be4f625db5b1aba15be89c5d2c7f897ae7c23f229410ce7d697daf6d27364c0cc4c58c13d61db775f8ffe2822673821c2726b7bef0 SHA512 a726b9c1828cbef741ba9c50b9588cbd421637a8fac0d8f4381e2bf6d349cb228935e86f4e8cf409656ef789f4f5c0d096914d7a13637ee1f1e607894349d330

sys-cluster/libqb/libqb-2.0.4.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Library providing high performance logging, tracing, ipc, and poll"
+HOMEPAGE="https://github.com/ClusterLabs/libqb"
+SRC_URI="https://github.com/ClusterLabs/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/100"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="debug doc examples systemd test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/libxml2"
+DEPEND="${RDEPEND}"
+BDEPEND="app-arch/xz-utils
+	test? ( dev-libs/check )
+	doc? (
+		app-doc/doxygen[dot]
+	)"
+
+DOCS=( ChangeLog README.markdown )
+
+PATCHES=()
+
+src_prepare() {
+	default
+
+	# Skip installation of text documents without value
+	sed -e '/dist_doc_DATA/d' -i Makefile.am || die
+
+	# Do not append version suffix "-yank"
+	sed 's|1-yank|1|' -i configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--with-socket-dir=/run \
+		$(use_enable systemd systemd-journal) \
+		$(use_enable debug)
+}
+
+src_compile() {
+	default
+	use doc && emake doxygen
+}
+
+src_install() {
+	emake install DESTDIR="${D}"
+
+	if use examples ; then
+		docinto examples
+		dodoc examples/*.c
+	fi
+
+	use doc && HTML_DOCS=("docs/html/.")
+	einstalldocs
+
+	find "${D}" -name '*.la' -delete || die
+}