mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
net-irc/kvirc: Version bump (5.0_pre20171001143427).
This commit is contained in:
Arfrever Frehtes Taifersar Arahesis
committed by
Mike Gilbert
Mike Gilbert
parent
f11de7a5d4
commit
40ee3bcdf8
@@ -1 +1,2 @@
|
||||
DIST kvirc-5.0_pre20170801214745.tar.gz 6024368 SHA256 ed47c63930be5a9f1f3dd8804fa68d6b22e4119bdbbfd2328450b7842b765beb SHA512 a662faf3cdb593b7576aca4957ea225240b5732cd2544952b8bfe3b46c6e9671a0357f2de778a15119b6ba0201fe3356ca2c7e8e81487e40651e139a55ed485c WHIRLPOOL 1090caf0ce9624aed0853c62643bff14054df15c0eeabe0242164bba697d5001e63c7ea77492a79799f88414f4a39bbeada676e8c1479d56e61d79bce519ae23
|
||||
DIST kvirc-5.0_pre20171001143427.tar.gz 6035319 SHA256 fdb00940319840cae266a8ca16f2814a937220ae37b8c354405393a80fd0d370 SHA512 ccf9b032737ce24cc98c23f3e1363b7ad874452837805b9a240dfd0d5e067da556dcd6003398f3cb2826f144656540592189e7f88d68608d6fbb2e8294535640 WHIRLPOOL 1bf28d9714d03d53a5e7f5881ef25e0ebfdda37bdc498c74291a867e9e03ed3cd97db649833c1dcbf8ac31af1cc8527a8a9471388f9936d5558e62ca2ab374cf
|
||||
|
||||
148
net-irc/kvirc/kvirc-5.0_pre20171001143427.ebuild
Normal file
148
net-irc/kvirc/kvirc-5.0_pre20171001143427.ebuild
Normal file
@@ -0,0 +1,148 @@
|
||||
# Copyright 1999-2017 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="5"
|
||||
PYTHON_COMPAT=(python2_7)
|
||||
|
||||
inherit cmake-utils flag-o-matic gnome2-utils multilib python-single-r1 xdg-utils
|
||||
|
||||
if [[ "${PV}" == "9999" ]]; then
|
||||
inherit git-r3
|
||||
|
||||
EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
|
||||
KVIRC_GIT_REVISION=""
|
||||
KVIRC_GIT_SOURCES_DATE=""
|
||||
else
|
||||
inherit vcs-snapshot
|
||||
|
||||
KVIRC_GIT_REVISION="150eeeab99ce7f340bf17e337b7ef1357ba375ad"
|
||||
KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
|
||||
KVIRC_GIT_SOURCES_DATE="${KVIRC_GIT_SOURCES_DATE:0:4}-${KVIRC_GIT_SOURCES_DATE:4:2}-${KVIRC_GIT_SOURCES_DATE:6:2}"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Advanced IRC Client"
|
||||
HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
|
||||
if [[ "${PV}" == "9999" ]]; then
|
||||
SRC_URI=""
|
||||
else
|
||||
SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
|
||||
fi
|
||||
|
||||
LICENSE="kvirc"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
|
||||
IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
|
||||
REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
|
||||
|
||||
RDEPEND="dev-qt/qtcore:5
|
||||
dev-qt/qtgui:5
|
||||
dev-qt/qtmultimedia:5
|
||||
dev-qt/qtnetwork:5
|
||||
dev-qt/qtprintsupport:5
|
||||
dev-qt/qtsql:5
|
||||
dev-qt/qtwidgets:5
|
||||
dev-qt/qtx11extras:5
|
||||
dev-qt/qtxml:5
|
||||
sys-libs/zlib:0=
|
||||
x11-libs/libX11
|
||||
x11-libs/libXScrnSaver
|
||||
audiofile? ( media-libs/audiofile )
|
||||
dbus? ( dev-qt/qtdbus:5 )
|
||||
dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
|
||||
kde? (
|
||||
kde-frameworks/kcoreaddons:5
|
||||
kde-frameworks/ki18n:5
|
||||
kde-frameworks/knotifications:5
|
||||
kde-frameworks/kservice:5
|
||||
kde-frameworks/kwindowsystem:5
|
||||
kde-frameworks/kxmlgui:5
|
||||
)
|
||||
perl? ( dev-lang/perl:0= )
|
||||
phonon? ( media-libs/phonon[qt5(+)] )
|
||||
python? ( ${PYTHON_DEPS} )
|
||||
spell? ( app-text/enchant:0= )
|
||||
ssl? ( dev-libs/openssl:0= )
|
||||
theora? (
|
||||
media-libs/libogg
|
||||
media-libs/libtheora
|
||||
media-libs/libvorbis
|
||||
)
|
||||
webkit? ( dev-qt/qtwebkit:5 )"
|
||||
DEPEND="${RDEPEND}
|
||||
virtual/pkgconfig
|
||||
doc? ( app-doc/doxygen )
|
||||
kde? ( kde-frameworks/extra-cmake-modules:5 )
|
||||
nls? ( sys-devel/gettext )"
|
||||
RDEPEND="${RDEPEND}
|
||||
gsm? ( media-sound/gsm )"
|
||||
|
||||
DOCS=(ChangeLog doc/FAQ)
|
||||
|
||||
pkg_setup() {
|
||||
if use python; then
|
||||
python-single-r1_pkg_setup
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
cmake-utils_src_prepare
|
||||
|
||||
if [[ "${PV}" == "9999" ]]; then
|
||||
KVIRC_GIT_REVISION="$(git show -s --format=%H)"
|
||||
KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
|
||||
fi
|
||||
einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
|
||||
sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
append-flags -fno-strict-aliasing
|
||||
|
||||
local libdir="$(get_libdir)"
|
||||
local mycmakeargs=(
|
||||
-DLIB_SUFFIX=${libdir#lib}
|
||||
-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
|
||||
-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
|
||||
-DWANT_ENV_FLAGS=yes
|
||||
-DWANT_VERBOSE=yes
|
||||
|
||||
-DWANT_CRYPT=yes
|
||||
-DWANT_DCC_VOICE=yes
|
||||
-DWANT_IPC=yes
|
||||
-DWANT_IPV6=yes
|
||||
-DWANT_TRANSPARENCY=yes
|
||||
|
||||
-DWANT_AUDIOFILE=$(usex audiofile)
|
||||
-DWANT_DCC_VIDEO=$(usex dcc_video)
|
||||
-DWANT_DEBUG=$(usex debug)
|
||||
-DWANT_DOXYGEN=$(usex doc)
|
||||
-DWANT_GETTEXT=$(usex nls)
|
||||
-DWANT_GSM=$(usex gsm)
|
||||
-DWANT_KDE=$(usex kde)
|
||||
-DWANT_MEMORY_PROFILE=$(usex profile)
|
||||
-DWANT_OGG_THEORA=$(usex theora)
|
||||
-DWANT_OPENSSL=$(usex ssl)
|
||||
-DWANT_OSS=$(usex oss)
|
||||
-DWANT_PERL=$(usex perl)
|
||||
-DWANT_PHONON=$(usex phonon)
|
||||
-DWANT_PYTHON=$(usex python)
|
||||
-DWANT_QTDBUS=$(usex dbus)
|
||||
-DWANT_QTWEBKIT=$(usex webkit)
|
||||
-DWANT_SPELLCHECKER=$(usex spell)
|
||||
|
||||
# COMPILE_SVG_SUPPORT not used in source code.
|
||||
-DWANT_QTSVG=no
|
||||
)
|
||||
|
||||
cmake-utils_src_configure
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
gnome2_icon_cache_update
|
||||
xdg_desktop_database_update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
gnome2_icon_cache_update
|
||||
xdg_desktop_database_update
|
||||
}
|
||||
Reference in New Issue
Block a user