gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-11-10 06:57:08 -08:00
Code Issues Projects Releases Wiki Activity

net-misc/freerdp: add 3.31.1

Browse Source 
Signed-off-by: Mike Gilbert <floppym@gentoo.org>
This commit is contained in:
Mike Gilbert
2026-09-02 15:45:34 -04:00
parent 24f54f88c9
commit 3fcf02b8da
4 changed files with 197 additions and 3 deletions
Download Patch File Download Diff File Expand all files Collapse all files
net-misc/freerdp/Manifest
+2
View File
@@ -4,3 +4,5 @@ DIST freerdp-3.30.0.tar.gz 11070523 BLAKE2B 654816d8fede28e5a302f4288481411ae6dc
DIST freerdp-3.30.0.tar.gz.asc 228 BLAKE2B 4ffb2710ca3a24df878a77c350b875c44515a1696a212a99596f3dbb79433ed3a2f066f4aa3187653a579db4a37d0d0b342aac372db0a3803ba8bf0c52fc3673 SHA512 df68f5ff8d0c895202c579b4b14f1dcc0555b6459ba0c73ad82224d8b2f031a88ff35c50a92c9426cc13c64ede138179eaa256a6785a77b78aefb7e55f7c1c24
DIST freerdp-3.31.0.tar.gz 11106371 BLAKE2B 62b2a227e05a6e96f031888de95281a37db9d0b82a52117a2b88570f0a0e0308469194e5c93542d56bb335ce6091641f2139359ce65daa5394e5e93b72183676 SHA512 3543a32b0204dcdc64deb6d4a410e223dce5c4195de8bc5c5931f569cf184a54441ddf315ca509e6500f79735693372c8f7dd108d94dd187df0da3f935a2c28d
DIST freerdp-3.31.0.tar.gz.asc 228 BLAKE2B 91e961f6987090cb85f9189415620dc8eed578afa5599e698579b0e075a858c3ade2952935e746d3811fc661180facfa53f70a156e1d3156c76e43452634fe1d SHA512 0e001b1ff461fe9eca67e80f0487d9d069c9a188412667a6bf5e3e21a0d5189126fe7b4ae0ee173ba8935ce915d5d1c2d49adc03b5b09bf8ae4863a09de73f98
DIST freerdp-3.31.1.tar.gz 11111567 BLAKE2B 97d47a4daab1341b558212da34c580543fc9c62d5e4fa6ea71b230a8b79b8c5aa2d960aa49294b48f19fcf27f0a6d81cae9c75d3987477c8ff964a1ec71d723b SHA512 708fa170d70c01cbd5b16b2bc0359092114e0158c3a76c38862b58b19bc2757a467656cf0f326cd9e81c366f2a9c1ff11073a099ee81304006556dac0d8b5a7e
DIST freerdp-3.31.1.tar.gz.asc 228 BLAKE2B 6b009b8969c06a2123469eadf02a85a18567a541b745b7a7a82324dd3c27faa99f53c05846933ee24001686f4bc297d32d48a9f4d7f82045161d94bf7586f0f5 SHA512 5c9bfc3cb28cc900cce93f9b9f94e41e3e7ed1ee1b87c68d46bed260ddc294bab3035676a2361e8943c5d6be8791c237f89032e04dc772e16d0bc6117d13ded9
net-misc/freerdp/freerdp-3.31.1.ebuild
+192
View File
@@ -0,0 +1,192 @@
# Copyright 2011-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic
if [[ ${PV} == *9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
case ${PV} in
2.*) EGIT_BRANCH="stable-2.0";;
esac
else
inherit verify-sig
MY_P=${P/_/-}
S="${WORKDIR}/${MY_P}"
SRC_URI="https://pub.freerdp.com/releases/${MY_P}.tar.gz
verify-sig? ( https://pub.freerdp.com/releases/${MY_P}.tar.gz.asc )"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
BDEPEND="verify-sig? ( sec-keys/openpgp-keys-akallabeth )"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/akallabeth.asc"
fi
DESCRIPTION="Free implementation of the Remote Desktop Protocol"
HOMEPAGE="https://www.freerdp.com/"
LICENSE="Apache-2.0"
SLOT="3"
IUSE="aad alsa camera cpu_flags_arm_neon +client cups debug +ffmpeg +fuse gstreamer +icu jpeg kerberos openh264 pulseaudio sdl server smartcard systemd test usb valgrind wayland winpr-tools X xinerama xv"
RESTRICT="!test? ( test )"
BDEPEND+="
virtual/pkgconfig
app-text/docbook-xsl-stylesheets
dev-libs/libxslt
"
COMMON_DEPEND="
dev-libs/openssl:0=
virtual/zlib:=
aad? ( dev-libs/cJSON )
alsa? ( media-libs/alsa-lib )
cups? ( net-print/cups )
usb? (
virtual/libudev:0=
sys-apps/util-linux:0=
dev-libs/dbus-glib:0=
virtual/libusb:1=
)
X? (
x11-libs/libXcursor
x11-libs/libXext
x11-libs/libXi
x11-libs/libXrender
xinerama? ( x11-libs/libXinerama )
xv? ( x11-libs/libXv )
)
ffmpeg? ( media-video/ffmpeg:0= )
!ffmpeg? (
x11-libs/cairo:0=
)
fuse? ( sys-fs/fuse:3= )
gstreamer? (
media-libs/gstreamer:1.0
media-libs/gst-plugins-base:1.0
X? ( x11-libs/libXrandr )
)
icu? ( dev-libs/icu:0= )
jpeg? ( media-libs/libjpeg-turbo:0= )
kerberos? ( virtual/krb5 )
openh264? ( media-libs/openh264:0= )
pulseaudio? ( media-libs/libpulse )
server? (
X? (
x11-libs/libXcursor
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXrandr
x11-libs/libXtst
xinerama? ( x11-libs/libXinerama )
)
)
smartcard? ( sys-apps/pcsc-lite )
systemd? ( sys-apps/systemd:0= )
client? (
camera? ( media-libs/libv4l )
sdl? (
media-libs/libsdl3
media-libs/sdl3-ttf
)
wayland? (
dev-libs/wayland
x11-libs/libxkbcommon
)
)
X? (
x11-libs/libX11
x11-libs/libxkbfile
)
"
DEPEND="${COMMON_DEPEND}
test? (
ffmpeg? ( media-video/ffmpeg:0[x264(-)] )
)
valgrind? ( dev-debug/valgrind )
"
RDEPEND="${COMMON_DEPEND}
!net-misc/freerdp:0
client? ( !net-misc/freerdp:2[client] )
server? ( !net-misc/freerdp:2[server] )
smartcard? ( app-crypt/p11-kit )
"
option() {
usex "$1" ON OFF
}
option_client() {
if use client; then
option "$1"
else
echo OFF
fi
}
src_configure() {
use debug || append-cppflags -DNDEBUG
local mycmakeargs=(
-Wno-dev
-DBUILD_TESTING=$(option test)
# https://bugs.gentoo.org/927037
-DCMAKE_INTERPROCEDURAL_OPTIMIZATION=OFF
-DCHANNEL_URBDRC=$(option usb)
-DCHANNEL_RDPECAM_CLIENT=$(option_client camera)
-DWITH_AAD=$(option aad)
-DWITH_ALSA=$(option alsa)
-DWITH_CCACHE=OFF
-DWITH_CLIENT=$(option client)
-DWITH_CLIENT_SDL2=OFF
-DWITH_CLIENT_SDL3=$(option_client sdl)
-DWITH_SAMPLE=OFF
-DWITH_CUPS=$(option cups)
-DWITH_DEBUG_ALL=$(option debug)
-DWITH_VERBOSE_WINPR_ASSERT=$(option debug)
-DWITH_MANPAGES=ON
-DWITH_FFMPEG=$(option ffmpeg)
-DWITH_FREERDP_DEPRECATED_COMMANDLINE=ON
-DWITH_SWSCALE=$(option ffmpeg)
-DWITH_CAIRO=$(option !ffmpeg)
-DWITH_DSP_FFMPEG=$(option ffmpeg)
-DWITH_FUSE=$(option fuse)
-DWITH_GSTREAMER_1_0=$(option gstreamer)
-DWITH_JPEG=$(option jpeg)
-DWITH_KRB5=$(option kerberos)
-DWITH_NEON=$(option cpu_flags_arm_neon)
-DWITH_OPENH264=$(option openh264)
-DWITH_OSS=OFF
-DWITH_PCSC=$(option smartcard)
-DWITH_PKCS11=$(option smartcard)
-DWITH_PULSE=$(option pulseaudio)
-DWITH_SERVER=$(option server)
-DWITH_LIBSYSTEMD=$(option systemd)
-DWITH_UNICODE_BUILTIN=$(option !icu)
-DWITH_VALGRIND_MEMCHECK=$(option valgrind)
-DWITH_X11=$(option X)
-DWITH_XINERAMA=$(option xinerama)
-DWITH_XV=$(option xv)
-DWITH_WAYLAND=$(option_client wayland)
-DWITH_WEBVIEW=OFF
-DWITH_WINPR_TOOLS=$(option winpr-tools)
)
cmake_src_configure
}
src_test() {
# TestBacktrace: bug 930636
# TestSynchCritical, TestSynchMultipleThreads: bug 951301
local CMAKE_SKIP_TESTS=( TestBacktrace TestSynchCritical TestSynchMultipleThreads )
if has network-sandbox ${FEATURES}; then
CMAKE_SKIP_TESTS+=( TestConnect )
fi
cmake_src_test
}
src_install() {
cmake_src_install
mv "${ED}"/usr/share/man/man7/wlog{,3}.7 || die
}
net-misc/freerdp/freerdp-9999.ebuild
+2 -3
View File
@@ -27,7 +27,7 @@ HOMEPAGE="https://www.freerdp.com/"
LICENSE="Apache-2.0"
SLOT="3"
IUSE="aad alsa camera cpu_flags_arm_neon +client cups debug +ffmpeg +fuse gstreamer +icu jpeg kerberos openh264 pulseaudio sdl server smartcard systemd test usb valgrind wayland X xinerama xv"
IUSE="aad alsa camera cpu_flags_arm_neon +client cups debug +ffmpeg +fuse gstreamer +icu jpeg kerberos openh264 pulseaudio sdl server smartcard systemd test usb valgrind wayland winpr-tools X xinerama xv"
RESTRICT="!test? ( test )"
BDEPEND+="
@@ -171,8 +171,7 @@ src_configure() {
-DWITH_XV=$(option xv)
-DWITH_WAYLAND=$(option_client wayland)
-DWITH_WEBVIEW=OFF
# https://bugs.gentoo.org/981523
#-DWITH_WINPR_TOOLS=$(option server)
-DWITH_WINPR_TOOLS=$(option winpr-tools)
)
cmake_src_configure
}
net-misc/freerdp/metadata.xml
+1
View File
@@ -12,6 +12,7 @@
<flag name="fuse">Clipboard with FUSE file copy support</flag>
<flag name="openh264">Enable H.264 support using <pkg>media-libs/openh264</pkg></flag>
<flag name="server">Build server binaries</flag>
<flag name="winpr-tools">Build WinPR helper binaries</flag>
</use>
<upstream>
<remote-id type="github">FreeRDP/FreeRDP</remote-id>