net-p2p/qbittorrent: 4.5.4 version bump.

Signed-off-by: Piotr Karbowski <slashbeast@gentoo.org>
This commit is contained in:
Piotr Karbowski
2023-06-21 21:46:55 +02:00
parent 25c5c3339d
commit 3f2385653d
2 changed files with 105 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST qbittorrent-4.5.2.tar.gz 8890525 BLAKE2B 48585b703ce6edf862ea3c8cfad6cab2edcb65a138c6e8d232322b4f4fd682c87447ff11d29c04c26b5623e730ab9a1ce0496456b3ba6122f97913bd92b86790 SHA512 e900a1c5f0f70163463557aec3de0d31394fac56cfed91ea53ee5cf852cce4b2998bf79be60fc547c1c34a1658378f3ed9dbfb30aae5a772b85d819c7e7ce458
DIST qbittorrent-4.5.4.tar.gz 8791236 BLAKE2B 70b3194d6c4819655998406e0a13d22f3a5068e724048010daebd83d8b8db9e17daee943ca8dabaacd92a0fbc5249257de6d175b35287c748dc2d15395bd71fc SHA512 2e7988922137c9fade99e90236cc0c5b8b30f09021472f8ffc9048a7a2d989925eed7bfab4d79c93ca7d0f21acfde2e7feee5e6c43b557bf2c6f472fd52fbcea
@@ -0,0 +1,104 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake multibuild systemd xdg
DESCRIPTION="BitTorrent client in C++ and Qt"
HOMEPAGE="https://www.qbittorrent.org"
if [[ ${PV} == *9999 ]]; then
EGIT_REPO_URI="https://github.com/qbittorrent/qBittorrent.git"
inherit git-r3
else
SRC_URI="https://github.com/qbittorrent/qBittorrent/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
S="${WORKDIR}"/qBittorrent-release-${PV}
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="+dbus +gui webui"
REQUIRED_USE="dbus? ( gui )
|| ( gui webui )"
RDEPEND="
>=dev-libs/openssl-1.1.1:=
dev-qt/qtcore:5
dev-qt/qtnetwork:5[ssl]
dev-qt/qtsql:5
dev-qt/qtxml:5
<net-libs/libtorrent-rasterbar-2:=
>=sys-libs/zlib-1.2.11
dbus? ( dev-qt/qtdbus:5 )
gui? (
dev-libs/geoip
dev-qt/qtgui:5
dev-qt/qtsvg:5
dev-qt/qtwidgets:5
)"
DEPEND="
${RDEPEND}
dev-libs/boost"
BDEPEND="dev-qt/linguist-tools:5
virtual/pkgconfig"
DOCS=( AUTHORS Changelog CONTRIBUTING.md README.md )
src_prepare() {
MULTIBUILD_VARIANTS=()
use gui && MULTIBUILD_VARIANTS+=( gui )
use webui && MULTIBUILD_VARIANTS+=( nogui )
cmake_src_prepare
}
src_configure() {
multibuild_src_configure() {
local mycmakeargs=(
# musl lacks execinfo.h
-DSTACKTRACE=$(usex !elibc_musl)
# More verbose build logs are preferable for bug reports
-DVERBOSE_CONFIGURE=ON
# Not yet in ::gentoo
-DQT6=OFF
-DWEBUI=$(usex webui)
)
if [[ ${MULTIBUILD_VARIANT} == gui ]]; then
# We do this in multibuild, see bug #839531 for why.
# Fedora has to do the same thing.
mycmakeargs+=(
-DGUI=ON
-DDBUS=$(usex dbus)
-DSYSTEMD=OFF
)
else
mycmakeargs+=(
-DGUI=OFF
-DDBUS=OFF
# The systemd service calls qbittorrent-nox, which is only
# installed when GUI=OFF.
-DSYSTEMD=ON
-DSYSTEMD_SERVICES_INSTALL_DIR="$(systemd_get_systemunitdir)"
)
fi
cmake_src_configure
}
multibuild_foreach_variant multibuild_src_configure
}
src_compile() {
multibuild_foreach_variant cmake_src_compile
}
src_install() {
multibuild_foreach_variant cmake_src_install
einstalldocs
}