dev-util/azuredatastudio: drop old 1.50.0-r1

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

dev-util/azuredatastudio/Manifest

@@ -1,3 +1,2 @@
-DIST azuredatastudio-1.50.0-amd64.deb 142500668 BLAKE2B b6d1a957857be1584ae2a9f64d2f58952d79f44ec49db70fe51f28da5292334d97130b8c9ae779e6baf90eff98bd6e531719bd90b5e81db333d4f8cf6af2386c SHA512 4d9d33e6ad31e668e56f170d8fea9e3de0422b5f6a397820094c8c522f4970c3ec55388a29cc110584cf4e1e9f3e59356eae4db2a05fad9284ffec35426c37d2
 DIST azuredatastudio-1.51.1-amd64.deb 142493364 BLAKE2B 151d9bc60b0104c4c593105bea8c384c73d3e56e1999f2cddec48bf4a8f3313dffb6235f86d352fcb277a097c7339a30eaa3bbdc6ceaea9a8d8003ae167a4a90 SHA512 2a0fb6f501f41edfc480fc6821a6aa81a6f1f20d6793f27d62831be86cd300b84ae78690fdde15f24e629e748f04bbfaa998fe9970ca5ce8f171cbcded43c75d
 DIST azuredatastudio-1.52.0-amd64.deb 142489084 BLAKE2B c58b5dec7cdf125a65f6b395681a6f3ba7e68e7ea6c6e010d2ca68a9b2087d951440236c8143ecc3c0cd8ace94de18bc2db065b279a89d9a0d4034ef500bf94d SHA512 90ecabda64ffd29f4fe0724fd935a663cbaa3662dc6a292fcd313467d73dce03b218e4aae46252874c9f652d1cb74cbaad10fea6402991638908695e9d7ab937

dev-util/azuredatastudio/azuredatastudio-1.50.0-r1.ebuild

@@ -1,112 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit unpacker xdg
-
-DESCRIPTION="Data management and development tool from Microsoft"
-HOMEPAGE="https://learn.microsoft.com/sql/azure-data-studio/
-	https://github.com/microsoft/azuredatastudio/"
-SRC_URI="
-	amd64? (
-		https://azuredatastudio-update.azurewebsites.net/${PV}/linux-deb-x64/stable
-			-> ${P}-amd64.deb
-	)
-"
-S="${WORKDIR}"
-
-LICENSE="Apache-2.0 BSD BSD-1 BSD-2 BSD-4 CC-BY-4.0 ISC LGPL-2.1+ MIT MPL-2.0 openssl PYTHON TextMate-bundle Unlicense UoI-NCSA W3C"
-SLOT="0"
-KEYWORDS="-* ~amd64"
-IUSE="kerberos"
-RESTRICT="bindist"
-
-# This is based on VSCode/VSCodium, so just copy their "RDEPEND".
-RDEPEND="
-	>=app-accessibility/at-spi2-core-2.46.0:2
-	app-crypt/libsecret[crypt]
-	app-misc/ca-certificates
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/nspr
-	dev-libs/nss
-	dev-util/lttng-ust:0/2.12
-	media-libs/alsa-lib
-	|| (
-		media-libs/libcanberra-gtk3
-		media-libs/libcanberra[gtk3(-)]
-	)
-	media-libs/libglvnd
-	media-libs/mesa
-	net-misc/curl
-	net-print/cups
-	sys-apps/dbus
-	sys-libs/zlib
-	sys-process/lsof
-	x11-libs/cairo
-	x11-libs/gtk+:3
-	x11-libs/libdrm
-	x11-libs/libnotify
-	x11-libs/libX11
-	x11-libs/libxcb
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libxkbcommon
-	x11-libs/libxkbfile
-	x11-libs/libXrandr
-	x11-libs/libXScrnSaver
-	x11-libs/pango
-	x11-misc/xdg-utils
-	kerberos? ( app-crypt/mit-krb5 )
-"
-DEPEND="
-	dev-libs/openssl-compat:1.0.0
-"
-BDEPEND="
-	dev-util/patchelf
-"
-
-QA_PREBUILT="*"
-
-src_unpack() {
-	unpack_deb "${A}"
-}
-
-src_prepare() {
-	default
-
-	cd "${S}/usr/share" || die
-
-	mv appdata metainfo || die
-	mv zsh/vendor-completions zsh/site-functions || die
-
-	cd "${PN}/resources/app" || die
-
-	rm -r ./ThirdPartyNotices.txt || die
-
-	# Disable update server.
-	sed -e "/updateUrl/d" -i ./product.json || die
-
-	# Kerberos libs, same issue as VSCode/VSCodium.
-	if ! use kerberos ; then
-		rm -r node_modules.asar.unpacked/kerberos || die
-	fi
-
-	# Patch "System.Security.Cryptography.Native.OpenSsl.so": *.so.10 -> *.so.1.0.0
-	local mssql_ext_version="5.0.20241115.1"
-	local mssql_ext_lib="libSystem.Security.Cryptography.Native.OpenSsl.so"
-	cd "extensions/mssql/sqltoolsservice/Linux/${mssql_ext_version}" || die
-	patchelf --add-needed libcrypto.so.1.0.0 "${mssql_ext_lib}" || die
-	patchelf --add-needed libssl.so.1.0.0 "${mssql_ext_lib}" || die
-	patchelf --remove-needed libcrypto.so.10 "${mssql_ext_lib}" || die
-	patchelf --remove-needed libssl.so.10 "${mssql_ext_lib}" || die
-}
-
-src_install() {
-	cp -r . "${ED}" || die
-
-	dosym -r "/usr/share/${PN}/${PN}" "/usr/bin/${PN}"
-}