net-libs/ngtcp2: add 0.8.1

Signed-off-by: Craig Andrews <candrews@gentoo.org>

net-libs/ngtcp2/Manifest

@@ -1,2 +1,3 @@
 DIST ngtcp2-0.7.0.tar.xz 573964 BLAKE2B 178d51fd41486620c1546b94ca5c6ac1072e7185d864251ce83d3ef7fc7b53e41f283937dd9c7b7771de7dbec099c8a308086c93929878035db7962efd821d70 SHA512 21b4506936e3dffaa06499d3b5f782212e369326f5d71cda65d76c92b0f5518937c83d791e8e5ffcd7ca8efbeeb33ed88c0c592571bf9ff4e32c53b261f6a548
 DIST ngtcp2-0.8.0.tar.xz 581752 BLAKE2B 0bd124c840d56cf8324a2d3de9748e3426944c1ac9436438ced807cda269e4e199d81fc1a9a8c4f7e6a0eb93d474006875c99eafda94d42dc518ea1f6ff00662 SHA512 d8ba29d55c1ad01c04e0d62fca4c1ed97e9e0bfd5dcb889dc1cb2b0a1188554ceb9bf2f92ece15eabfffb34eb992f5ac924f14077aba0de2e11246947b16d518
+DIST ngtcp2-0.8.1.tar.xz 578944 BLAKE2B d53af801b1d3646f8360070753bad903a8857f5533d5ac8957d35801f4e8bcf7b07902cfba2190f0037635cd3e1ec56967b90df7185b5e32bd9a0cd4f6709972 SHA512 dae2975076a7f060d3b09b1fea9be116b534323d63c35a47dd0db0f8f9932c0d9655e95c0b14a58d8808f4caa6823fe25e340ac9564ea8d02fe008b981df4f0e

net-libs/ngtcp2/ngtcp2-0.8.1.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/ngtcp2/ngtcp2.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/ngtcp2/ngtcp2/releases/download/v${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~hppa"
+fi
+
+DESCRIPTION="Implementation of the IETF QUIC Protocol"
+HOMEPAGE="https://github.com/ngtcp2/ngtcp2/"
+
+LICENSE="MIT"
+SLOT="0/0"
+IUSE="+gnutls openssl +ssl test"
+REQUIRED_USE="ssl? ( || ( gnutls openssl ) )"
+
+BDEPEND="virtual/pkgconfig"
+RDEPEND="
+	ssl? (
+		gnutls? ( >=net-libs/gnutls-3.7.2:0= )
+		openssl? (
+			>=dev-libs/openssl-1.1.1:0=
+		)
+	)"
+DEPEND="${RDEPEND}
+	test? ( >=dev-util/cunit-2.1[${MULTILIB_USEDEP}] )"
+RESTRICT="!test? ( test )"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DENABLE_GNUTLS=$(usex gnutls)
+		-DENABLE_OPENSSL=$(usex openssl)
+		-DENABLE_BORINGSSL=OFF
+		-DENABLE_PICOTLS=OFF
+		-DENABLE_WOLFSSL=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_Libev=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Libnghttp3=ON
+	)
+	cmake_src_configure
+}
+
+multilib_src_test() {
+	cmake_build check
+}