dev-python/openapi-core: Bump to 0.14.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/openapi-core/Manifest

@@ -1 +1,2 @@
 DIST openapi-core-0.14.2.gh.tar.gz 57519 BLAKE2B 06dfd284612ca11a271f075444db9b859ca5416e31594680d6b32abec1fe917105f213209d1bfcb9664b265ea3d62839579134e8e104754075cd692d1ba7a99a SHA512 19a2508d56053214993abed7d173d17b55a80dac6421681d7c64082f910bf9cb03c99d4006a2cd883d51d54f11a18f90188f141a78b9d69a9a031c284a14f8f1
+DIST openapi-core-0.14.5.gh.tar.gz 57645 BLAKE2B c5c9c308b93a37e32708677cc7c7a2ccb9ec3f018390e56a251224b6b8776943ccd0ddfb560cdc3f1182cb32a9b2817878a0d4dda3906c179db9841853caf7ac SHA512 69d9fb2cc21dfdb939beae45b1c681faf9f8e3366b36e5907b00be65ac669ec40e3ae3fe910fb2c4f6c70d1412e6a67e4e4e47e3cf2c424716da4c813223295e

dev-python/openapi-core/openapi-core-0.14.5.ebuild

@@ -0,0 +1,71 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Client-side and server-side support for the OpenAPI Specification v3"
+HOMEPAGE="
+	https://github.com/p1c2u/openapi-core/
+	https://pypi.org/project/openapi-core/
+"
+SRC_URI="
+	https://github.com/p1c2u/openapi-core/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/isodate[${PYTHON_USEDEP}]
+	dev-python/dictpath[${PYTHON_USEDEP}]
+	<dev-python/openapi-schema-validator-0.3[${PYTHON_USEDEP}]
+	<dev-python/openapi-spec-validator-0.5[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/lazy-object-proxy[${PYTHON_USEDEP}]
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/parse[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/strict-rfc3339[${PYTHON_USEDEP}]
+		dev-python/webob[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# falcon is not packaged
+	tests/integration/contrib/falcon
+
+	# TODO: these tests fail to collect
+	tests/integration/validation/test_security_override.py
+	tests/integration/validation/test_read_only_write_only.py
+
+	# unhappy about modern django
+	tests/integration/contrib/test_django.py
+	tests/integration/contrib/django
+)
+
+EPYTEST_DESELECT=(
+	# too new pytest?
+	tests/unit/unmarshalling/test_unmarshal.py::TestSchemaUnmarshallerCall::test_string_format_invalid_value
+)
+
+src_prepare() {
+	sed -i -e '/addopts/d' setup.cfg || die
+	distutils-r1_src_prepare
+}