sys-fs/lxcfs: add 5.0.3

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

sys-fs/lxcfs/Manifest

@@ -1,2 +1,4 @@
 DIST lxcfs-5.0.2.tar.gz 103236 BLAKE2B 5fc8dc437e97a79c78320f8d8111746b171b086beb176a6ada30b8c23164ae4e58ad42806bc0ea73bbbb15d94816bd9b3d5500f9e2a306e2458d23fb111bf68f SHA512 df51e7154060dd7efe992eb2bc40c5a52dce8c52063477110ed414ecc3f430f18d5023a29be6866560fc87b060c2158cc1e947f030c509188320d417eb23d407
 DIST lxcfs-5.0.2.tar.gz.asc 833 BLAKE2B a411c6cb4f3382469ea80a974166c98b57ae4b92712bf55507720fc78ec73ef6acbd47f6b3410294b209f77f1f3a17dc4b9fb4dda00bb7323ef32c7185ba4c2e SHA512 f9d54e26d406ebca97c82298361318f13e74fd55285c2b6563ae6c71af63d9b8325ac06b9de8103a95a19c5d965c2d907c313ac151210a162998f8a37ea99676
+DIST lxcfs-5.0.3.tar.gz 103697 BLAKE2B bdea820f1a5b799309b3d5c8ea439477e6eeda2d9600a348a92b203f2f8a6e0e686d0bf56d8f6b5bbfeb4837dd5737626d7d0610157211f0f189711e9e45a048 SHA512 967e60bd7ea545f1fcdd805adc0083e39684013c18f42a51753b5be8cdabfb86a652d02471a1f71c7b4fa756da09b72d324b724d68091d539edd10ea63add1fd
+DIST lxcfs-5.0.3.tar.gz.asc 833 BLAKE2B 2dc139639431d9430149369b0a28b6debef0de9f5f69854070d8f2e47718bcc130a869683dfa2b0002c6a54978b0550303adbd5a7fa5ef565eb6bc6bbfcde9e0 SHA512 0207c110553b9d62cf88ec70ed4472b9696d74b277af1e53df6d1145228b76d06695fd28bf20c8428bee5b6ff617c617fbf063c1c8ff0bcc44be2e3439c76a64

sys-fs/lxcfs/lxcfs-5.0.3.ebuild

@@ -0,0 +1,79 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake meson python-any-r1 systemd verify-sig
+
+DESCRIPTION="FUSE filesystem for LXC"
+HOMEPAGE="https://linuxcontainers.org/lxcfs/introduction/ https://github.com/lxc/lxcfs/"
+SRC_URI="https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz
+	verify-sig? ( https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz.asc )"
+
+LICENSE="Apache-2.0 LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="doc test"
+
+DEPEND="sys-fs/fuse:3"
+RDEPEND="${DEPEND}"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep '
+		dev-python/jinja[${PYTHON_USEDEP}]
+	')
+	doc? ( sys-apps/help2man )
+	verify-sig? ( sec-keys/openpgp-keys-linuxcontainers )"
+
+# Needs some black magic to work inside container/chroot.
+RESTRICT="test"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/linuxcontainers.asc
+
+python_check_deps() {
+	python_has_version -b "dev-python/jinja[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Fix python shebangs for python-exec[-native-symlinks], #851480
+	local shebangs=($(grep -rl "#!/usr/bin/env python3" || die))
+	python_fix_shebang -q ${shebangs[*]}
+}
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir "${EPREFIX}/var"
+
+		$(meson_use doc docs)
+		$(meson_use test tests)
+
+		-Dfuse-version=3
+		-Dinit-script=""
+		-Dwith-init-script=""
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}"/tests || die "failed to change into tests/ directory."
+	./main.sh || die
+}
+
+src_install() {
+	meson_src_install
+
+	newconfd "${FILESDIR}"/lxcfs-5.0.2.confd lxcfs
+	newinitd "${FILESDIR}"/lxcfs-5.0.2.initd lxcfs
+
+	# Provide our own service file (copy of upstream) due to paths being different from upstream,
+	# #728470
+	systemd_newunit "${FILESDIR}"/lxcfs-5.0.2.service lxcfs.service
+}