dev-libs/xapian: add 1.4.27

Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/xapian/Manifest

@@ -1,2 +1,3 @@
 DIST xapian-core-1.4.25.tar.xz 3205904 BLAKE2B 7b03a8fabc3c688f58b3451541dedb664de0a02d7c46a4e8eac080c004232575c00428110eaab0ea463df5c3f43f2b4cebfbe6754f897e55f113683c1db43b2b SHA512 e8069f2cb75554978716a99580fb57fc73bbdd607c82394f53d07205d8c78fb59265004be0c676a6806bb2840a3933499dfc867e36a28855278569a0676d469d
 DIST xapian-core-1.4.26.tar.xz 3246304 BLAKE2B f68b25741de821ef6de2ae5127f09f69a68c435dd224b796d92fc18769db3e3307a0a3aadc98cf26adc966eb063fdbd3ee612ec725020cfc79bdfa041675794b SHA512 ecd94d410dc94b6510c6729f276606987f9dd955cfb0520e62d46fa71645f5b140d474cda0d77078e64ee7cf9c0cd00f3aefe0e1b087739582e64bbcb9fabd4b
+DIST xapian-core-1.4.27.tar.xz 3246624 BLAKE2B 4a61490ebb53738660ef7ff9ecd60e2b53474309d63fe9b9702323a6eba6c9d96d79048f67e8356a2a7c0436ab6ff38792bf9d9776b60f820eaddc77ca5b0f32 SHA512 5a9b75dfc61782012c4c2febd95532e6705f7fa45b0765b64dbc9ee3751c88fb3420f1d7d8fdadee21a59ff4143c5197870a4aa50993490a033fce6925e1e9f1

dev-libs/xapian/xapian-1.4.27.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+MY_P="${PN}-core-${PV}"
+DESCRIPTION="Xapian Probabilistic Information Retrieval library"
+HOMEPAGE="https://xapian.org/"
+SRC_URI="https://oligarchy.co.uk/xapian/${PV}/${MY_P}.tar.xz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0/30" # ABI version of libxapian.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos ~x64-solaris"
+IUSE="cpu_flags_x86_sse cpu_flags_x86_sse2 debug static-libs"
+
+DEPEND="
+	sys-libs/zlib:=
+	!elibc_Darwin? ( !elibc_SunOS? ( sys-apps/util-linux ) )
+	elibc_SunOS? ( sys-libs/libuuid )
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( AUTHORS HACKING PLATFORMS README NEWS )
+
+src_configure() {
+	tc-export_build_env BUILD_CC
+	local -x CC_FOR_BUILD="${BUILD_CC}"
+
+	# skip certain autoconf checks
+	local -x VALGRIND=
+	local -x EATMYDATA=
+
+	local -a myconf=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}/html
+		--disable-werror
+		--enable-backend-chert
+		--enable-backend-glass
+		--enable-backend-inmemory
+		--enable-backend-remote
+		--program-suffix=
+		$(use_enable debug assertions)
+		$(use_enable debug log)
+		$(use_enable static-libs static)
+	)
+
+	if use cpu_flags_x86_sse2; then
+		myconf+=( --enable-sse=sse2 )
+	elif use cpu_flags_x86_sse; then
+		myconf+=( --enable-sse=sse )
+	else
+		myconf+=( --disable-sse )
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	emake -Onone check
+}
+
+src_install() {
+	default
+	find "${ED}" -name "*.la" -type f -delete || die
+}