media-radio/xlog: Version bump

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>

media-radio/xlog/Manifest

@@ -1 +1,2 @@
 DIST xlog-2.0.20.tar.gz 11437051 BLAKE2B a6d6618b62d1f5591cf44efe4ce2e3ba8a1f27bc2fe218f0b65d05f26bb2f8abeea69d3ec2c2009f50209257769647bc6fe9307999f5fede5b72cb0ca9259b16 SHA512 50feaede582ea505021c5530efa702915f2ec6f64e4677055657adbaefca92b3b45b6c6fe5af8d65ed2ae38d0d0e4cda6782fa7781516b5263f738c90fb17c89
+DIST xlog-2.0.22.tar.gz 11407849 BLAKE2B 85d2e904d33ef39883cb8ac086eed4dc7e65503cdccb95e8d33f169d12de4f1ed556a28ac2f40e0044e937185bf4d93fe55608088d6e95744617c9c3a051fb55 SHA512 a261f8e28b75aed9380c29b3da69c7615b0d32346eaf84a0ace5cf77c53407372c4985c599078dba5ed92f77bd8052a74c7dca40028b99bca49cc3164d4ec490

media-radio/xlog/xlog-2.0.22.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools toolchain-funcs xdg-utils
+MY_P=${P/_}
+
+DESCRIPTION="An amateur radio logging program"
+HOMEPAGE="https://www.nongnu.org/xlog"
+SRC_URI="https://download.savannah.gnu.org/releases/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="media-libs/hamlib:=
+	dev-libs/glib:2
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}
+	media-libs/libpng:0
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS data/doc/THANKS NEWS README )
+
+src_prepare() {
+	eapply_user
+	eapply -p0 "${FILESDIR}/${PN}-2.0.7-desktop.patch"
+
+	# Drop -Werror
+	sed -i -e "s:-Werror::g" configure.ac || die
+	# fix underlinking
+	sed -i -e "s:HAMLIB_LIBS@:HAMLIB_LIBS@ -lm:g" src/Makefile.am || die
+	eautoconf
+
+	# Fix broken png files<<
+	einfo "Fixing broken png files."
+	pushd "${S}"/data/doc/manual/output/html
+	for png in xlog-clock.png xlog-dropdown.png xlog-editbox.png; do
+		pngfix -q --out=out.png ${png}
+		mv -f out.png "${png}" || die
+	done
+	popd
+	einfo "done ..."
+
+}
+
+src_configure() {
+	# mime-update causes file collisions if enabled
+	econf --disable-mime-update
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	# build system makes it complicate to inhibit updating desktop 
+	# database, so just remove the offending file
+	rm  "${D}"/usr/share/applications/mimeinfo.cache || die
+	docompress -x /usr/share/doc/${PF}/{KEYS,ChangeLog,TODO,BUGS}
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}