net-misc/gnome-remote-desktop: add 48.2

Signed-off-by: Lukas Schmelting <lschmelting@posteo.com>
Part-of: https://github.com/gentoo/gentoo/pull/43867
Closes: https://github.com/gentoo/gentoo/pull/43867
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

net-misc/gnome-remote-desktop/Manifest

@@ -1,2 +1,3 @@
 DIST gnome-remote-desktop-47.3.tar.xz 287080 BLAKE2B 8bcaf7fa28a2c2ba8082d7c8515fad90db7a339458854da0c0c7ff605f10d0c6f8e1eb0caad6732aff4d2caa9c59fd2dae03dad5481198b92a10c95012ca0f62 SHA512 6a2da7fd3c09d47594eee53146fcc9c467844ce4d0282b4fb88f265016e3fd11f7ee5629cc70164427c024ad91b07021d5a5b9f771e983accc6019c17a0c5f7f
 DIST gnome-remote-desktop-48.1.tar.xz 341944 BLAKE2B e56567d9c9b6856b5c078e54bd2ee186fd7f9aba35a13bb0f621357f32468ad8154277ec4e3b8f85e1557e88a1ea115177292f2bec91164034a063ae18f615ae SHA512 48cd8320df76fbe2a4bf664ab3ed58ef0517b2f70765e4c00828313403a96da476e07e270d9b4633b3d12ea27f34b09ed07d9e8983032c3ed9a631a4574f4edd
+DIST gnome-remote-desktop-48.2.tar.xz 343308 BLAKE2B bf36d9f60fd4f4ffccd2118d1beeb8511147983ab2bd338a4008da0eb113a97930bbe4b58ac681e7f059f10e633c3687119c5999e6704f79732870ccb6456cc5 SHA512 345e74971eaa319af543b47f9353a643d901f0e5aaa8f60a85df21f624d7d413bc34bfaa8ee4c92b4934f8ccedd940658e0fff8f6f616c30262143def9610e3a

net-misc/gnome-remote-desktop/gnome-remote-desktop-48.2.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd tmpfiles xdg
+
+DESCRIPTION="Remote desktop server which allows you to connect to your machine remotely"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong"
+IUSE="doc +rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	x11-libs/libdrm
+	>=media-libs/libepoxy-1.4
+	>=dev-libs/glib-2.75:2
+	>=dev-libs/libei-1.2.0
+	x11-libs/libnotify
+	app-crypt/libsecret
+	>=media-video/pipewire-1.2.0:=
+	app-crypt/tpm2-tss:=
+	rdp? (
+		>=media-libs/nv-codec-headers-11.1.5.0
+		>=net-misc/freerdp-3.1.0:=[server]
+		>=sys-fs/fuse-3.9.1:3=
+		media-libs/libva
+		>=sys-auth/polkit-122
+		>=dev-util/vulkan-headers-1.2.0
+		media-libs/shaderc
+		dev-util/spirv-tools
+		>=x11-libs/libxkbcommon-1.0.0
+		media-libs/fdk-aac:=
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	acct-user/gnome-remote-desktop
+	acct-group/gnome-remote-desktop
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	dev-libs/glib
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+	doc? (
+		app-text/asciidoc
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc man)
+		$(meson_use rdp)
+		$(meson_use vnc)
+		$(meson_use systemd)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+		-Dtests=false  # Tests run xvfb-run directly
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	tmpfiles_process "${PN}-tmpfiles.conf"
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}