xfce-extra/xfce4-pulseaudio-plugin: Bump to 0.3.5

xfce-extra/xfce4-pulseaudio-plugin/Manifest

@@ -1 +1,2 @@
 DIST xfce4-pulseaudio-plugin-0.3.4.tar.bz2 400380 BLAKE2B b8cd4df84f3119d90a7671d8217eaeb83025206d9bfdc5aaae2281cd7c9b13ab03fa8a99ff1eb352f2fa01e889bcd3a505b558ce9884c46b1136bc75a6fb22e7 SHA512 2dfa6a4567caeb2f336b1d9e32cedb5f03e363253549810e768bb51746cd1db362ebd0990098e461a71b8206d81ff877291860a3568a288fe2010498ad486c78
+DIST xfce4-pulseaudio-plugin-0.3.5.tar.bz2 390084 BLAKE2B a43ac67d83cfa113a3429c2fd0e2de1879f9fb9856e136606140ce08d0e70b44ec2cd17a588240edab5609ff8735ee05f7da2314f925205c4aff1b8f574eb767 SHA512 6cfef82b7ca0b2301638c2756f71f7ac03d83c92f3dc40fd24896d1e7879dbab2bd828a66dab1c659a5d93dc63bf505d9ef75094c2588cafd85ba66d202434a5

xfce-extra/xfce4-pulseaudio-plugin/xfce4-pulseaudio-plugin-0.3.5.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils
+
+DESCRIPTION="A panel plug-in for PulseAudio volume control"
+HOMEPAGE="https://git.xfce.org/panel-plugins/xfce4-pulseaudio-plugin/"
+SRC_URI="mirror://xfce/src/panel-plugins/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="debug keybinder libnotify wnck"
+
+RDEPEND=">=dev-libs/glib-2.42.0:=
+	media-sound/pulseaudio:=
+	>=x11-libs/gtk+-3.20.0:3=
+	>=xfce-base/libxfce4ui-4.11.0:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.9.0:=
+	>=xfce-base/xfce4-panel-4.11.0:=
+	>=xfce-base/xfconf-4.6.0:=
+	keybinder? ( dev-libs/keybinder:3= )
+	libnotify? ( x11-libs/libnotify:= )
+	wnck? ( x11-libs/libwnck:3= )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		$(use_enable keybinder)
+		$(use_enable libnotify)
+		$(use_enable wnck)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+
+	if ! has_version media-sound/pavucontrol; then
+		elog "For the 'audio mixer...' shortcut to work, you need to install"
+		elog "an external mixer application. Please either install:"
+		elog
+		elog "	media-sound/pavucontrol"
+		elog
+		elog "or specify another application to use in the 'Properties' dialog."
+	fi
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}