www-client/falkon: drop 22.12.3

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

www-client/falkon/Manifest

@@ -1,3 +1,2 @@
-DIST falkon-22.12.3.tar.xz 2547936 BLAKE2B ec5d800ed89cef7fdf5a37a7ef426c8c05b922a23f993312467a5bd9c0946664877b46fea5d937b4c9c61b670791efa23c7239fa152a9eaed54f391af65185fe SHA512 fad6fb5ff3ea29648708451aecc7c22e2e3768a723b8a02c51a2b375342668eb21b7b4e26bb6da4f2be6f225292aa0e8aecd406a795d96cac655cdb692445a05
 DIST falkon-23.04.2.tar.xz 2553276 BLAKE2B beaf9a124414890ba283689f943cd5cb0f120b079e47dce6783f9264d368e31947eb32ca6137b64c7454dd863481cfc928edf01e617ac0c8270d4050d2f50b78 SHA512 6d13a1bdef02bb438c2355ea113514b15b47ff21904f857899e33e4c34e1b00116b712bdeb4ed56ba8a0d7bc426607650bbfec52f48ef2bfd85664634d6cf87c
 DIST falkon-23.04.3.tar.xz 2553088 BLAKE2B e6dafe1f22f47c031b2c856aa5ba9a23eb74295c5cf891282ec51894c520383bca94ff42ef94c3396075b734da53adc5a289e4c8a94203b8daf6d6f8e847e527 SHA512 2d77e6f7383b3bf23aa979d57d2ba3a58516f18e3a72bf8a78695b36273ff00877e0109bba0dfa2b09215433457d12f919568cecacd9b96be888b585bf513f83

www-client/falkon/falkon-22.12.3.ebuild

@@ -1,92 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_TEST="true"
-KFMIN=5.101.0
-QTMIN=5.15.5
-PYTHON_COMPAT=( python3_{9..11} )
-VIRTUALX_REQUIRED="test"
-inherit ecm gear.kde.org python-single-r1
-
-DESCRIPTION="Cross-platform web browser using QtWebEngine"
-HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="amd64 arm64 ~ppc64 ~x86"
-IUSE="dbus kde python +X"
-
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-RESTRICT="test" # bug 653046
-
-COMMON_DEPEND="
-	dev-libs/openssl:0=
-	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtnetwork-${QTMIN}:5[ssl]
-	>=dev-qt/qtprintsupport-${QTMIN}:5
-	>=dev-qt/qtsql-${QTMIN}:5[sqlite]
-	>=dev-qt/qtwebchannel-${QTMIN}:5
-	>=dev-qt/qtwebengine-${QTMIN}:5=[widgets]
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=kde-frameworks/karchive-${KFMIN}:5
-	virtual/libintl
-	dbus? ( >=dev-qt/qtdbus-${QTMIN}:5 )
-	kde? (
-		>=kde-frameworks/kcoreaddons-${KFMIN}:5
-		>=kde-frameworks/kcrash-${KFMIN}:5
-		>=kde-frameworks/kio-${KFMIN}:5
-		>=kde-frameworks/kwallet-${KFMIN}:5
-		>=kde-frameworks/purpose-${KFMIN}:5
-	)
-	python? (
-		${PYTHON_DEPS}
-		$(python_gen_cond_dep "
-			>=dev-python/pyside2-${QTMIN}[designer,gui,webengine,widgets,\${PYTHON_USEDEP}] \
-			>=dev-python/shiboken2-${QTMIN}[\${PYTHON_USEDEP}]
-		")
-	)
-	X? (
-		>=dev-qt/qtx11extras-${QTMIN}:5
-		x11-libs/libxcb:=
-		x11-libs/xcb-util
-	)
-"
-DEPEND="${COMMON_DEPEND}
-	>=dev-qt/qtconcurrent-${QTMIN}:5
-"
-if [[ ${KDE_BUILD_TYPE} != live ]]; then
-	DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:5"
-fi
-RDEPEND="${COMMON_DEPEND}
-	>=dev-qt/qtsvg-${QTMIN}:5
-"
-BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
-
-PATCHES=( "${FILESDIR}/${PN}-22.04.3-python3.patch" )
-
-pkg_setup() {
-	use python && python-single-r1_pkg_setup
-	ecm_pkg_setup
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_KEYRING=OFF
-		-DDISABLE_DBUS=$(usex !dbus)
-		$(cmake_use_find_package kde KF5Wallet)
-		$(cmake_use_find_package kde KF5KIO)
-		$(cmake_use_find_package python PySide2)
-		$(cmake_use_find_package python Shiboken2)
-		$(cmake_use_find_package python Python3)
-		-DNO_X11=$(usex !X)
-	)
-	use python && mycmakeargs+=(
-		-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
-		-DPython3_INCLUDE_DIR=$(python_get_includedir)
-		-DPython3_LIBRARY=$(python_get_library_path)
-	)
-	ecm_src_configure
-}