gnome-extra/gnome-shell-extension-gsconnect: add 66

Signed-off-by: Pacho Ramos <pacho@gentoo.org>
This commit is contained in:
Pacho Ramos
2025-06-20 17:22:33 +02:00
parent 69b45be42f
commit 3c0aafc6fa
2 changed files with 78 additions and 0 deletions
@@ -1,2 +1,3 @@
DIST gnome-shell-extension-gsconnect-58.tar.gz 899868 BLAKE2B c39e6d82792b9e612d68fc98460b801b51ed8087a94d8eee949ff99a15f058d08842e4b4a3f22050c61ee0d71f1e58aa2574efd9fe685e267afb90492793bce1 SHA512 bc69455271afd51ccb861c66edd21b37bac449e003c560707ab30e2e062ca89f9caa60d697543d81c1c387b54a1f34912be522067b14b953a79a2e089a2612f4
DIST gnome-shell-extension-gsconnect-62.tar.gz 903446 BLAKE2B e33fddd6b8cabb702fdae466be3e3e970c45a57faacf3bdccbc56a8d0a7f077cf0aafd977a9e8868c961c6b2228e38ae9ddc96cfe8315f39b62d90245e20f2ee SHA512 452b9441e1cfe1d804c0ffd7a83d971be5cf287a779821be3391f5eefb753ff53cfceb21e32e509f06672e4863bb4b53345414f5556ef80a7480e0be431d07af
DIST gnome-shell-extension-gsconnect-66.tar.gz 904279 BLAKE2B f0eef3817c8d263ef258435da0a5e951a490d139be1e0d9172505d8fbb17fa350910cb71ac0ba15e36eb6f90c0073e584acb41a452c6adb3243d1c7329d79eba SHA512 6180ee259751121f88c5aa24c7a7f9c99963e2145200cfb3cd9ad5de68f8d5033e5d1c38263a901ea44bca41a7db6edcde2161905256625c6bb469fc614b8896
@@ -0,0 +1,77 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome2-utils meson readme.gentoo-r1 virtualx xdg
DESCRIPTION="KDE Connect implementation for GNOME"
HOMEPAGE="https://github.com/GSConnect/gnome-shell-extension-gsconnect"
SRC_URI="https://github.com/GSConnect/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE="nautilus"
# Upstream broke them and now they need to be run after pkg is installed or
# a container needs to be used:
# https://github.com/GSConnect/gnome-shell-extension-gsconnect/issues/1786
RESTRICT="test"
COMMON_DEPEND="dev-libs/glib:2"
RDEPEND="${COMMON_DEPEND}
app-eselect/eselect-gnome-shell-extensions
>=dev-libs/gjs-1.68
>=gnome-base/gnome-shell-46
gnome-base/gvfs
gnome-extra/evolution-data-server
|| ( media-libs/libcanberra media-libs/gsound )
nautilus? (
dev-python/nautilus-python
gnome-base/nautilus[introspection] )
"
DEPEND="${COMMON_DEPEND}"
BDEPEND="
virtual/pkgconfig
"
DISABLE_AUTOFORMATTING="yes"
DOC_CONTENTS="For knowing more about how to do the setup, please visit:
https://github.com/GSConnect/gnome-shell-extension-gsconnect/wiki/Installation"
src_configure() {
# nemo support relies on nemo-python from https://github.com/linuxmint/nemo-extensions
# https://bugs.gentoo.org/694388
meson_src_configure \
-Dinstalled_tests=false \
-Dnemo=false \
$(meson_use nautilus)
}
src_test() {
virtx meson_src_test
}
src_install() {
meson_src_install
readme.gentoo_create_doc
}
pkg_preinst() {
gnome2_schemas_savelist
xdg_pkg_preinst
}
pkg_postinst() {
gnome2_schemas_update
xdg_pkg_postinst
ebegin "Updating list of installed extensions"
eselect gnome-shell-extensions update
eend $?
readme.gentoo_print_elog
}
pkg_postrm() {
gnome2_schemas_update
xdg_pkg_postrm
}