mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 18:58:08 -07:00
app-i18n/ibus: version bump
Package-Manager: Portage-2.3.19, Repoman-2.3.6
This commit is contained in:
Yixun Lan
@@ -1,3 +1,4 @@
|
||||
DIST ibus-1.5.12.tar.gz 2190284 BLAKE2B 57ac7f9e8e8f0419bad1bf3aa629282ef3c0188d29e98bc872e594955f69e0863020d600c674cabed56db156a85210b5b3c1fe137b135395a27d2535e4938164 SHA512 a443bf0d1b71a52c18e7d13a0c69f38c48f6924cfb1669912880b87be1bf41bcb7d8d6252aafd6799e43d41c081fd94cf334fd836a0505c93a4e5c5b68241c81
|
||||
DIST ibus-1.5.15.tar.gz 2259352 BLAKE2B 52a820b55573f034f60dc705e0c513515c0f128f861d2dd9a22be9bfafdd10f116a159b8d9a21a64f7b66225e7191a08b9c5ff873bbe29421c53fec2bee08b71 SHA512 4e588acf2ca0172b365630dcfe2d9062e7583e50a44d435ec05c8e3976c6caf54c4708733f1f7dce5ef7724254469ee5c7ab3b086f0cbea18775c894863b0c3e
|
||||
DIST ibus-1.5.16.tar.gz 2375719 BLAKE2B cf4cbd4556e43403c73da3cd2cb9f6da8e0baf5f90b3bc74f6d12c1bad057198ed828053dcbb3ddfd28c37d9011b6166e834385720aa827a68f594dbd4cf9298 SHA512 494ead69cf9c0111fd25fd1de27e796d89db4f08443afa1ec469f638469b25d8b19a59ea7ab0db0f3a130b9a89b3f2819667099ba38fc973d6efc61b367ce237
|
||||
DIST ibus-1.5.17.tar.gz 2522960 BLAKE2B a0d19eaae809549d678b42394e76107b8869232c90932bfaa5072621598e83db0569084e931c51c15b7179d9d8e0a2ce144b726229dae81a009665a5de87afc4 SHA512 8a7e4fabbcb2096e647b1fb7487c92882bd320a4d777f2765817378abec2e60cafd63364c881fefc2805ff2baa6b28b15ee0710587662a3e65eeb60ead19496c
|
||||
|
||||
182
app-i18n/ibus/ibus-1.5.17.ebuild
Normal file
182
app-i18n/ibus/ibus-1.5.17.ebuild
Normal file
@@ -0,0 +1,182 @@
|
||||
# Copyright 1999-2017 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="6"
|
||||
PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
|
||||
VALA_USE_DEPEND="vapigen"
|
||||
|
||||
inherit autotools bash-completion-r1 gnome2-utils ltprune python-r1 vala virtualx
|
||||
|
||||
DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
|
||||
HOMEPAGE="https://github.com/ibus/ibus/wiki"
|
||||
SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.gz"
|
||||
|
||||
LICENSE="LGPL-2.1"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
|
||||
IUSE="+X +emoji gconf +gtk +gtk2 +introspection kde +libnotify nls +python test vala wayland"
|
||||
REQUIRED_USE="emoji? ( gtk )
|
||||
gtk2? ( gtk )
|
||||
kde? ( gtk )
|
||||
libnotify? ( gtk )
|
||||
python? (
|
||||
${PYTHON_REQUIRED_USE}
|
||||
gtk
|
||||
introspection
|
||||
)
|
||||
test? ( gtk )
|
||||
vala? ( introspection )"
|
||||
|
||||
CDEPEND="app-text/iso-codes
|
||||
dev-libs/glib:2
|
||||
gnome-base/dconf
|
||||
gnome-base/librsvg:2
|
||||
sys-apps/dbus[X?]
|
||||
X? (
|
||||
x11-libs/libX11
|
||||
!gtk? ( x11-libs/gtk+:2 )
|
||||
)
|
||||
gconf? ( gnome-base/gconf:2 )
|
||||
gtk? (
|
||||
x11-libs/gtk+:3
|
||||
x11-libs/libX11
|
||||
x11-libs/libXi
|
||||
gtk2? ( x11-libs/gtk+:2 )
|
||||
)
|
||||
introspection? ( dev-libs/gobject-introspection )
|
||||
kde? ( dev-qt/qtgui:5 )
|
||||
libnotify? ( x11-libs/libnotify )
|
||||
nls? ( virtual/libintl )
|
||||
python? (
|
||||
${PYTHON_DEPS}
|
||||
dev-python/pygobject:3[${PYTHON_USEDEP}]
|
||||
)
|
||||
wayland? (
|
||||
dev-libs/wayland
|
||||
x11-libs/libxkbcommon
|
||||
)"
|
||||
RDEPEND="${CDEPEND}
|
||||
python? (
|
||||
gtk? (
|
||||
x11-libs/gtk+:3[introspection]
|
||||
)
|
||||
)"
|
||||
DEPEND="${CDEPEND}
|
||||
$(vala_depend)
|
||||
dev-util/intltool
|
||||
virtual/pkgconfig
|
||||
emoji? (
|
||||
app-i18n/unicode-cldr
|
||||
app-i18n/unicode-emoji
|
||||
)
|
||||
nls? ( sys-devel/gettext )"
|
||||
|
||||
src_prepare() {
|
||||
vala_src_prepare --ignore-use
|
||||
if ! use emoji; then
|
||||
touch \
|
||||
tools/main.vala \
|
||||
ui/gtk3/panel.vala
|
||||
fi
|
||||
if ! use kde; then
|
||||
touch ui/gtk3/panel.vala
|
||||
fi
|
||||
if ! use libnotify; then
|
||||
touch ui/gtk3/panel.vala
|
||||
fi
|
||||
# for multiple Python implementations
|
||||
sed -i "s/^\(PYGOBJECT_DIR =\).*/\1/" bindings/Makefile.am
|
||||
# fix for parallel install
|
||||
sed -i \
|
||||
-e "/^py2_compile/,/^$/d" \
|
||||
-e "/^install-data-hook/,/^$/d" \
|
||||
bindings/pygobject/Makefile.am
|
||||
# require user interaction
|
||||
sed -i "/^TESTS += ibus-compose/d" src/tests/Makefile.am
|
||||
|
||||
sed -i "/^bash_completion/d" tools/Makefile.am
|
||||
|
||||
default
|
||||
eautoreconf
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local unicodedir="${EPREFIX}"/usr/share/unicode
|
||||
local python_conf=()
|
||||
if use python; then
|
||||
python_setup
|
||||
python_conf+=(
|
||||
$(use_enable gtk setup)
|
||||
--with-python=${EPYTHON}
|
||||
)
|
||||
else
|
||||
python_conf+=( --disable-setup )
|
||||
fi
|
||||
|
||||
econf \
|
||||
$(use_enable X xim) \
|
||||
$(use_enable emoji emoji-dict) \
|
||||
$(use_with emoji unicode-emoji-dir "${unicodedir}"/emoji) \
|
||||
$(use_with emoji emoji-annotation-dir "${unicodedir}"/cldr/common/annotations) \
|
||||
$(use_enable gconf) \
|
||||
$(use_enable gtk gtk3) \
|
||||
$(use_enable gtk ui) \
|
||||
$(use_enable gtk2) \
|
||||
$(use_enable introspection) \
|
||||
$(use_enable kde appindicator) \
|
||||
$(use_enable libnotify) \
|
||||
$(use_enable nls) \
|
||||
$(use_enable test tests) \
|
||||
$(use_enable vala) \
|
||||
$(use_enable wayland) \
|
||||
"${python_conf[@]}"
|
||||
}
|
||||
|
||||
src_test() {
|
||||
unset DBUS_SESSION_BUS_ADDRESS
|
||||
virtx emake -j1 check
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
prune_libtool_files --modules
|
||||
|
||||
if use python; then
|
||||
python_install() {
|
||||
emake -C bindings/pygobject \
|
||||
pyoverridesdir="$(${EPYTHON} -c 'import gi; print(gi._overridesdir)')" \
|
||||
DESTDIR="${D}" \
|
||||
install
|
||||
}
|
||||
python_foreach_impl python_install
|
||||
fi
|
||||
|
||||
keepdir /usr/share/ibus/engine
|
||||
|
||||
newbashcomp tools/${PN}.bash ${PN}
|
||||
|
||||
insinto /etc/X11/xinit/xinput.d
|
||||
newins xinput-${PN} ${PN}.conf
|
||||
}
|
||||
|
||||
pkg_preinst() {
|
||||
use gconf && gnome2_gconf_savelist
|
||||
gnome2_icon_savelist
|
||||
gnome2_schemas_savelist
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
use gconf && gnome2_gconf_install
|
||||
use gtk && gnome2_query_immodules_gtk3
|
||||
use gtk2 && gnome2_query_immodules_gtk2
|
||||
gnome2_icon_cache_update
|
||||
gnome2_schemas_update
|
||||
dconf update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
use gtk && gnome2_query_immodules_gtk3
|
||||
use gtk2 && gnome2_query_immodules_gtk2
|
||||
gnome2_icon_cache_update
|
||||
gnome2_schemas_update
|
||||
}
|
||||
Reference in New Issue
Block a user