dev-python/zstandard: Bump to 0.20.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/zstandard/Manifest

@@ -1 +1,2 @@
 DIST python-zstandard-0.19.0.gh.tar.gz 683942 BLAKE2B 5b28fb6360147f87fb658d28652e5e43b0e41ff3cc31e46d91b1dcdd5334869f9a10a598f3d1d15a8c0f02afc59d009a8088ba3e81066f1a5f1ad9c05ebd4a1d SHA512 56e7b43161940f182ff5a0745bb6bdb2710c9a61140c4a84b690e0abd18c8b862211ab2b1ba36cfd99fe75bb0ae00af7de798b010b2bd4c5a44d691d4fa0c63d
+DIST python-zstandard-0.20.0.gh.tar.gz 712241 BLAKE2B 6ec393a440eb2a0527e655ee1aec16a47120578bbbb69d2f208b4367be199041887bf02d8feeb74f87992d0ab2b5e668cf8b3d8cd8967bd6dc47d4e052781ebc SHA512 bdbbd829e431a9b1ad1247b83e2e6102314a257a32c92a5c666c5ac050eb115bccd9d358240ac9ab41e975ade13bbbc155c66cb8fb583d2ee8dbd28ae323e4f8

dev-python/zstandard/zstandard-0.20.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=python-zstandard-${PV}
+DESCRIPTION="Zstandard Bindings for Python"
+HOMEPAGE="
+	https://github.com/indygreg/python-zstandard/
+	https://pypi.org/project/zstandard/
+"
+SRC_URI="
+	https://github.com/indygreg/python-zstandard/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+DEPEND="
+	app-arch/zstd:=
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		>=dev-python/cffi-1.14.0-r2:=[${PYTHON_USEDEP}]
+	' 'python*')
+"
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# the C backend is repeatedly broken, so force CFFI instead
+	sed -e '/PYTHON_ZSTANDARD_IMPORT_POLICY/s:default:cffi:' \
+		-i zstandard/__init__.py || die
+	# unreliable, fails on x86
+	sed -e 's:test_estimated_compression_context_size:_&:' \
+		-i tests/test_data_structures.py || die
+	# unbundle zstd
+	: > zstd/zstdlib.c || die
+	# it does random preprocessing on that, so we can't use #include
+	cp "${ESYSROOT}/usr/include/zstd.h" zstd/zstd.h || die
+	sed -i -e '/include_dirs/a    libraries=["zstd"],' make_cffi.py || die
+
+	distutils-r1_src_prepare
+
+	DISTUTILS_ARGS=(
+		--no-c-backend
+	)
+}
+
+src_test() {
+	rm -r zstandard || die
+	distutils-r1_src_test
+}