net-vpn/openconnect: bump to 8.02

Drop java support due to lagging eclasses.

Package-Manager: Portage-2.3.56_p3, Repoman-2.3.12_p50
Signed-off-by: Mike Gilbert <floppym@gentoo.org>
This commit is contained in:
Mike Gilbert
2019-01-18 12:11:06 -05:00
parent 6d2e606555
commit 3b5beea6e4
3 changed files with 168 additions and 16 deletions
+2
View File
@@ -1,2 +1,4 @@
DIST openconnect-7.08.tar.gz 1686133 BLAKE2B 265c43982b475ef1e49d7bf16e782c82b9ac48fbfbe61b5b8fe250505391edea8e5050e8cc3dc9b3cadb349f3842e13c05e431172e8c7488d9052ad15c93e87e SHA512 22f9b0bd4bd17e2ab91ff42b2464c89abba035fe705c037ba4d1042ace460c8738e20481783a1edc3b7dd6503fe9fcc7fdd188552811fb1525310e25a4c2f400
DIST openconnect-8.02.tar.gz 1876135 BLAKE2B aef1f17702ddbbd392c3203f4235a6e24ca5ecbfe144652675ac8b98c0cbb85bf8cc5563295150cf385d3c0bc5a9b3ad84228706baa17f56dd62b798cbdd05d1 SHA512 690a51198aeaf4bb1cd0901b0799ac991712a29aa899fe735a7b5201683cd627556eebeefba01d0c752ba44ba0a6c5ee1c3647d692383f3f4b335e79c5337cbc
DIST vpnc-scripts-20180227.tar.gz 21241 BLAKE2B 2ba4c76121ba9c5d307233d6f8c91db03c8da4882b8f6dfeed335f7fcc30438df8fe0657a1177e7e551566b597e195cf41bb6e27e13b757a0c931e8574de9a5e SHA512 9a508426e9307213078ce57b59d25168647fa5d2e823b1085e93401259b0a52269e948c8292e4055babf3e8b3c087a23475b5caa2a43c11feb2df8b0d8843972
DIST vpnc-scripts-20190117.tar.gz 21412 BLAKE2B 47adc50fe8940e6f5253321d2ef91abeb03e131dc0c1ba02f33f90c9a1ef75c0e838c0215c7ac419134c620b83a449e225d6ba5d77bb98d8f461406cb39eed9f SHA512 d01bb52532bd96f1bbf9735b8d5530c762c80205e53057f619db6090556887da1c91fe111da9937b452910f493e73dad26fcd20d3bd97248099d90ffa3060cde
+156
View File
@@ -0,0 +1,156 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="xml"
inherit linux-info python-any-r1 readme.gentoo-r1
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="https://gitlab.com/openconnect/openconnect.git"
inherit git-r3 autotools
else
ARCHIVE_URI="ftp://ftp.infradead.org/pub/${PN}/${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
fi
VPNC_VER=20190117
SRC_URI="${ARCHIVE_URI}
ftp://ftp.infradead.org/pub/vpnc-scripts/vpnc-scripts-${VPNC_VER}.tar.gz"
DESCRIPTION="Free client for Cisco AnyConnect SSL VPN software"
HOMEPAGE="http://www.infradead.org/openconnect.html"
LICENSE="LGPL-2.1 GPL-2"
SLOT="0/5"
IUSE="doc +gnutls gssapi libproxy libressl lz4 nls smartcard static-libs stoken"
DEPEND="
dev-libs/libxml2
sys-libs/zlib
!gnutls? (
!libressl? ( >=dev-libs/openssl-1.0.1h:0=[static-libs?] )
libressl? ( dev-libs/libressl:0=[static-libs?] )
)
gnutls? (
app-misc/ca-certificates
dev-libs/nettle
>=net-libs/gnutls-3:0=[static-libs?]
)
gssapi? ( virtual/krb5 )
libproxy? ( net-libs/libproxy )
lz4? ( app-arch/lz4:= )
nls? ( virtual/libintl )
smartcard? ( sys-apps/pcsc-lite:0= )
stoken? ( app-crypt/stoken )"
RDEPEND="${DEPEND}
sys-apps/iproute2
!<sys-apps/openrc-0.13"
BDEPEND="
virtual/pkgconfig
doc? ( ${PYTHON_DEPS} sys-apps/groff )
nls? ( sys-devel/gettext )"
CONFIG_CHECK="~TUN"
pkg_pretend() {
check_extra_config
}
pkg_setup() {
:
}
src_unpack() {
if [[ ${PV} == 9999 ]]; then
git-r3_src_unpack
fi
default
}
src_prepare() {
default
if [[ ${PV} == 9999 ]]; then
eautoreconf
fi
}
src_configure() {
if use doc; then
python_setup
else
export PYTHON=/bin/false
fi
local myconf=(
--with-vpnc-script="${EPREFIX}/etc/openconnect/openconnect.sh"
--without-openssl-version-check
$(use_enable static-libs static)
$(use_enable nls)
$(use_with !gnutls openssl)
$(use_with gnutls)
$(use_with libproxy)
$(use_with lz4)
$(use_with gssapi)
$(use_with smartcard libpcsclite)
$(use_with stoken)
--without-java
)
econf "${myconf[@]}"
}
DOC_CONTENTS="The init script for openconnect supports multiple vpn tunnels.
You need to create a symbolic link to /etc/init.d/openconnect in /etc/init.d
instead of calling it directly:
ln -s /etc/init.d/openconnect /etc/init.d/openconnect.vpn0
You can then start the vpn tunnel like this:
/etc/init.d/openconnect.vpn0 start
If you would like to run preup, postup, predown, and/or postdown scripts,
You need to create a directory in /etc/openconnect with the name of the vpn:
mkdir /etc/openconnect/vpn0
Then add executable shell files:
mkdir /etc/openconnect/vpn0
cd /etc/openconnect/vpn0
echo '#!/bin/sh' > preup.sh
cp preup.sh predown.sh
cp preup.sh postup.sh
cp preup.sh postdown.sh
chmod 755 /etc/openconnect/vpn0/*
"
src_install() {
default
newinitd "${FILESDIR}"/openconnect.init.in-r4 openconnect
dodir /etc/openconnect
insinto /etc/openconnect
newconfd "${FILESDIR}"/openconnect.conf.in openconnect
exeinto /etc/openconnect
newexe "${WORKDIR}"/vpnc-scripts-${VPNC_VER}/vpnc-script openconnect.sh
insinto /etc/logrotate.d
newins "${FILESDIR}"/openconnect.logrotate openconnect
keepdir /var/log/openconnect
find "${ED}" -name '*.la' -delete || die
readme.gentoo_create_doc
}
pkg_postinst() {
readme.gentoo_print_elog
if [[ -z ${REPLACING_VERSIONS} ]]; then
elog
elog "You may want to consider installing the following optional packages."
optfeature "resolvconf support" virtual/resolvconf
fi
}
+10 -16
View File
@@ -1,21 +1,21 @@
# Copyright 1999-2018 Gentoo Authors
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
EAPI=7
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="xml"
inherit eutils java-pkg-opt-2 linux-info python-any-r1 readme.gentoo-r1
inherit linux-info python-any-r1 readme.gentoo-r1
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="git://git.infradead.org/users/dwmw2/${PN}.git"
EGIT_REPO_URI="https://gitlab.com/openconnect/openconnect.git"
inherit git-r3 autotools
else
ARCHIVE_URI="ftp://ftp.infradead.org/pub/${PN}/${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
fi
VPNC_VER=20180227
VPNC_VER=20190117
SRC_URI="${ARCHIVE_URI}
ftp://ftp.infradead.org/pub/vpnc-scripts/vpnc-scripts-${VPNC_VER}.tar.gz"
@@ -24,7 +24,7 @@ HOMEPAGE="http://www.infradead.org/openconnect.html"
LICENSE="LGPL-2.1 GPL-2"
SLOT="0/5"
IUSE="doc +gnutls gssapi java libproxy libressl lz4 nls smartcard static-libs stoken"
IUSE="doc +gnutls gssapi libproxy libressl lz4 nls smartcard static-libs stoken"
DEPEND="
dev-libs/libxml2
@@ -47,10 +47,9 @@ DEPEND="
RDEPEND="${DEPEND}
sys-apps/iproute2
!<sys-apps/openrc-0.13"
DEPEND="${DEPEND}
BDEPEND="
virtual/pkgconfig
doc? ( ${PYTHON_DEPS} sys-apps/groff )
java? ( >=virtual/jdk-1.6 )
nls? ( sys-devel/gettext )"
CONFIG_CHECK="~TUN"
@@ -60,7 +59,7 @@ pkg_pretend() {
}
pkg_setup() {
java-pkg-opt-2_pkg_setup
:
}
src_unpack() {
@@ -78,11 +77,6 @@ src_prepare() {
}
src_configure() {
if [[ ${LINGUAS+set} == set ]]; then
strip-linguas -u po
echo "${LINGUAS}" > po/LINGUAS || die
fi
if use doc; then
python_setup
else
@@ -101,7 +95,7 @@ src_configure() {
$(use_with gssapi)
$(use_with smartcard libpcsclite)
$(use_with stoken)
$(use_with java)
--without-java
)
econf "${myconf[@]}"
@@ -147,7 +141,7 @@ src_install() {
newins "${FILESDIR}"/openconnect.logrotate openconnect
keepdir /var/log/openconnect
prune_libtool_files
find "${ED}" -name '*.la' -delete || die
readme.gentoo_create_doc
}