x11-themes/fluent-icon-theme: bump to 2022.02.04

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Maciej Barć <xgqt@gentoo.org>

x11-themes/fluent-icon-theme/Manifest

@@ -1 +1,2 @@
 DIST fluent-icon-theme-2021.12.20.tar.gz 33924235 BLAKE2B 17f051f086858ceb9969a8cacf6bbd2a9efd2e19d98872866ec5d9ea40e0389f3f9ad451dd6ed449716108eee20ad34fff1b121b497b4323314868bb1fb4429e SHA512 fc5e131c90f9444c92d0305489350f590f29dd78f03dd090959db00a1415a0bd35998e25ed93213c176536fa31e780942593b5d5470e4aac6fe98eb066463fa8
+DIST fluent-icon-theme-2022.02.04.tar.gz 6742454 BLAKE2B 4795639edb540a2ab6e91f14e60e692e8d5826de6ab91d7a2db9a8386105887eff24d080541425b39ffddae4430d2967b168289c9e6444fe38a0e2135348314a SHA512 2da9e9ff1b75284228dd3d32009c302326504107d0e384977161e28cf95e4b0cb143cff94841712a549ea3f0e1cafe393392ec89f9827c12e64dde4bc8194ddf

x11-themes/fluent-icon-theme/fluent-icon-theme-2022.02.04.ebuild

@@ -0,0 +1,56 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# ie. 2021.12.20 -> 2021-12-20
+MY_PV="${PV//./-}"
+MY_PN="${PN^}"
+
+inherit xdg
+
+DESCRIPTION="Fluent icon theme for Linux desktops"
+HOMEPAGE="https://github.com/vinceliuice/Fluent-icon-theme"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/vinceliuice/${MY_PN}.git"
+else
+	SRC_URI="https://github.com/vinceliuice/${MY_PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${MY_PN}-${MY_PV}"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+black +hardlink round"
+RESTRICT="binchecks strip test"
+
+BDEPEND="sys-apps/util-linux[hardlink(-)?]"
+
+src_prepare() {
+	default
+
+	sed -i '/gtk-update-icon-cache/d' install.sh || die
+}
+
+src_install() {
+	dodir /usr/share/icons
+	local myinstallopts=(
+		--all
+		--dest "${ED}/usr/share/icons"
+		$(usev black '--black')
+		$(usev round '--round')
+	)
+	bash ./install.sh "${myinstallopts[@]}" || die "install script failed"
+
+	if use hardlink; then
+		einfo "Linking duplicate icons... (may take a long time)"
+		hardlink -pot "${ED}/usr/share/icons" || die "hardlink failed"
+	fi
+
+	# installs broken symlink (by design, but we remove it due to QA warnings)
+	find "${ED}" -xtype l -delete || die "removing broken symlinks failed"
+
+	einstalldocs
+}