mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-09 06:37:10 -08:00
dev-util/cppcheck: version bump to 1.87
Closes: https://bugs.gentoo.org/683026 Package-Manager: Portage-2.3.66, Repoman-2.3.12 Signed-off-by: Matthias Maier <tamiko@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST cppcheck-1.86.tar.gz 2184186 BLAKE2B 8b488ec72d0998d6b037de2b1204373c8b3de475ad165bf108bb331399356cb0d1e20a7bc6f368f1a038ec886ad7a84ad694172d0a96a203a6877f3838c21001 SHA512 59cec55b8408e8f2e2e7172bce69350c248bc3185a0938b523c44a58f98b344e11aef957ec1b7a7b2bc7a876660b2683e51f54b76f0b550f9549497c29453655
|
||||
DIST cppcheck-1.87.tar.gz 2243258 BLAKE2B ffe42bfb2e896163678c5bb24e46ae2391ba8254cbe7c1c19c3c1b16cd38adf9c773de6aaefe70af08b9c1dca8b0b0b5e9939323368a2f81491fd6981ff18139 SHA512 b0149002b40260c1488904929296403722a66b84263b41d0097c3caed28265332766c114f0d1f378ea6c7e73ab973ea71ab89c6744f6cc818f22de08933e6766
|
||||
|
||||
@@ -0,0 +1,113 @@
|
||||
# Copyright 1999-2019 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
PYTHON_COMPAT=( python{2_7,3_5,3_6} )
|
||||
inherit distutils-r1 qmake-utils toolchain-funcs
|
||||
|
||||
DESCRIPTION="Static analyzer of C/C++ code"
|
||||
HOMEPAGE="https://github.com/danmar/cppcheck"
|
||||
SRC_URI="${HOMEPAGE}/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-3+"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~sparc ~x86"
|
||||
IUSE="htmlreport pcre qt5"
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/tinyxml2:=
|
||||
htmlreport? ( dev-python/pygments[${PYTHON_USEDEP}] )
|
||||
pcre? ( dev-libs/libpcre )
|
||||
qt5? (
|
||||
dev-qt/qtcore:5
|
||||
dev-qt/qtgui:5
|
||||
dev-qt/qtprintsupport:5
|
||||
)
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
app-text/docbook-xsl-stylesheets
|
||||
dev-libs/libxslt
|
||||
virtual/pkgconfig
|
||||
"
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-1.75-tinyxml2.patch
|
||||
"${FILESDIR}"/${PN}-1.85-ldflags.patch
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
rm -r externals/tinyxml || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
tc-export CXX PKG_CONFIG
|
||||
export LIBS="$(${PKG_CONFIG} --libs tinyxml2)"
|
||||
|
||||
emake dmake
|
||||
./dmake || die
|
||||
|
||||
if use pcre ; then
|
||||
sed -e '/HAVE_RULES=/s:=no:=yes:' \
|
||||
-i Makefile || die
|
||||
fi
|
||||
|
||||
if use qt5 ; then
|
||||
pushd gui || die
|
||||
eqmake5
|
||||
popd || die
|
||||
fi
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
emake ${PN} man \
|
||||
CFGDIR="${EROOT}/usr/share/${PN}/cfg" \
|
||||
DB2MAN="${EROOT}/usr/share/sgml/docbook/xsl-stylesheets/manpages/docbook.xsl"
|
||||
|
||||
if use qt5 ; then
|
||||
pushd gui || die
|
||||
emake
|
||||
popd || die
|
||||
fi
|
||||
|
||||
if use htmlreport ; then
|
||||
pushd htmlreport || die
|
||||
distutils-r1_src_compile
|
||||
popd || die
|
||||
fi
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# safe final version
|
||||
mv -v ${PN}{,.final} || die
|
||||
mv -v lib/library.o{,.final} || die
|
||||
mv -v cli/cppcheckexecutor.o{,.final} || die
|
||||
#trigger recompile with CFGDIR inside ${S}
|
||||
emake check CFGDIR="${S}/cfg"
|
||||
# restore
|
||||
mv -v ${PN}{.final,} || die
|
||||
mv -v lib/library.o{.final,} || die
|
||||
mv -v cli/cppcheckexecutor.o{.final,} || die
|
||||
}
|
||||
|
||||
src_install() {
|
||||
# it's not autotools-based, so "${ED}" here, not "${D}", bug 531760
|
||||
emake install DESTDIR="${ED}"
|
||||
|
||||
insinto "/usr/share/${PN}/cfg"
|
||||
doins cfg/*.cfg
|
||||
if use qt5 ; then
|
||||
dobin gui/${PN}-gui
|
||||
dodoc gui/{projectfile.txt,gui.${PN}}
|
||||
fi
|
||||
if use htmlreport ; then
|
||||
pushd htmlreport || die
|
||||
distutils-r1_src_install
|
||||
popd || die
|
||||
find "${D}" -name "*.egg-info" -delete
|
||||
else
|
||||
rm "${ED}/usr/bin/cppcheck-htmlreport" || die
|
||||
fi
|
||||
doman ${PN}.1
|
||||
dodoc -r tools/triage
|
||||
}
|
||||
Reference in New Issue
Block a user