app-misc/dvtm: add patch to avoid file collisions with sys-libs/ncurses

Bug: https://bugs.gentoo.org/show_bug.cgi?id=648472
Package-Manager: Portage-2.3.24, Repoman-2.3.6

app-misc/dvtm/dvtm-0.15-r3.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="Dynamic virtual terminal manager"
+HOMEPAGE="http://www.brain-dump.org/projects/dvtm/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://repo.or.cz/dvtm.git"
+else
+	SRC_URI="http://www.brain-dump.org/projects/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND=">=sys-libs/ncurses-6.1:0=[unicode]"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.15-gentoo.patch
+	"${FILESDIR}"/${PN}-0.15-stop-installing-terminfo.patch
+)
+
+src_prepare() {
+	default
+
+	restore_config config.h
+}
+
+src_compile() {
+	tc-export PKG_CONFIG
+	local msg=""
+	use savedconfig && msg=", please check the configfile"
+	emake CC=$(tc-getCC) ${PN} || die "emake failed${msg}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" STRIP=true install
+
+	insinto /usr/share/${PN}
+	newins config.h ${PF}.config.h
+
+	dodoc README.md
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	elog "This ebuild has support for user defined configs"
+	elog "Please read this ebuild for more details and re-emerge as needed"
+	elog "if you want to add or remove functionality for ${PN}"
+}

app-misc/dvtm/dvtm-9999.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -19,13 +19,14 @@ fi
 LICENSE="MIT"
 SLOT="0"
 
-RDEPEND="sys-libs/ncurses:0=[unicode]"
+RDEPEND=">=sys-libs/ncurses-6.1:0=[unicode]"
 DEPEND="
 	${RDEPEND}
 	virtual/pkgconfig
 "
 PATCHES=(
 	"${FILESDIR}"/${PN}-9999-gentoo.patch
+	"${FILESDIR}"/${PN}-0.15-stop-installing-terminfo.patch
 )
 
 src_prepare() {

app-misc/dvtm/files/dvtm-0.15-stop-installing-terminfo.patch

@@ -0,0 +1,12 @@
+diff -ur a/Makefile b/Makefile
+--- a/Makefile	2016-01-09 12:40:56.000000000 +0100
++++ b/Makefile	2018-02-23 00:45:06.436287174 +0100
+@@ -55,8 +55,6 @@
+ 	@mkdir -p ${DESTDIR}${MANPREFIX}/man1
+ 	@sed "s/VERSION/${VERSION}/g" < dvtm.1 > ${DESTDIR}${MANPREFIX}/man1/dvtm.1
+ 	@chmod 644 ${DESTDIR}${MANPREFIX}/man1/dvtm.1
+-	@echo installing terminfo description
+-	@TERMINFO=${TERMINFO} tic -s dvtm.info
+ 
+ uninstall:
+ 	@echo removing executable file from ${DESTDIR}${PREFIX}/bin