net-irc/weechat: version bump

This commit is contained in:
Tim Harder
2015-08-24 23:00:20 -04:00
parent bf3396e858
commit 3a37b840a9
2 changed files with 138 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST weechat-1.1.1.tar.bz2 2305377 SHA256 810bf0584fd5888246797fc7f1bbc4facb064a4d1c5d91627a9c8c01cbce97b5 SHA512 710cb8badeb2734cbe6430e1c5f7fc91d8ec5c9ef85d2c6cc2206ffdf915fab083027a04d25ba23a17515e767d3b482f85b3b3e8fc445cbf1d05db941ca13dfd WHIRLPOOL d445db9a42e6ac8a58bf17a6a905bc769ea3da005d29f4c8dd703c859ae475dea0302ba471662ae52ff7c4961f35b09942757ccf657d1d419edc50416dde6002
DIST weechat-1.2.tar.bz2 2367277 SHA256 7c4501401f3794d551331b3cede354895962858acc50437567ffd40fa7af684d SHA512 dd806c1e63e5abab8fcc2f84a615eae8769fc9271f89abb19fae9ef4489e86e132a8d6a4843714a3c772c064c9060e4b63f7433fe6beddd3e675ba08a744a1f9 WHIRLPOOL 8d9d5db2f3628e41f7b186ae80189113645f64dff407b5b64f602deefcf821b2457225d57d2cb1dee6b4c014704013c48fbc26423f6a39b762a0c55439bfb908
DIST weechat-1.3.tar.bz2 2402422 SHA256 703dd771f74a2391bab656992712331d9151a227ac3210393a4ecf6458605148 SHA512 82159f1c630bf389e7a3b8baf29b67c50711e1a767040440c71bfd7d3cd0c3005b7423e6dd53c2437512cc68953f540039971a4e6f6d7a4cdb4a4e74e4c3985b WHIRLPOOL 325b0feec0571d07494b2b5c863999d4f0bfa8f9698144624e5b8ec4c3c3180a1c3bc252647f3ba52f4cc46de788a450a122f2f3ac028ca333cb0c124fb70d8c
+137
View File
@@ -0,0 +1,137 @@
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
inherit eutils python-single-r1 multilib cmake-utils
if [[ ${PV} == "9999" ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/weechat/weechat.git"
else
SRC_URI="https://weechat.org/files/src/${P}.tar.bz2"
KEYWORDS="~amd64 ~x86"
fi
DESCRIPTION="Portable and multi-interface IRC client"
HOMEPAGE="http://weechat.org/"
LICENSE="GPL-3"
SLOT="0"
NETWORKS="+irc"
PLUGINS="+alias +charset +exec +fifo +logger +relay +scripts +spell +trigger +xfer"
#INTERFACES="+ncurses gtk"
# dev-lang/v8 was dropped from Gentoo so we can't enable javascript support
SCRIPT_LANGS="guile lua +perl +python ruby tcl"
LANGS=" cs de es fr hu it ja pl pt_BR ru tr"
IUSE="doc nls +ssl test ${LANGS// / linguas_} ${SCRIPT_LANGS} ${PLUGINS} ${INTERFACES} ${NETWORKS}"
#REQUIRED_USE=" || ( ncurses gtk )"
RDEPEND="
dev-libs/libgcrypt:0=
net-misc/curl[ssl]
sys-libs/ncurses
sys-libs/zlib
charset? ( virtual/libiconv )
guile? ( dev-scheme/guile:12 )
lua? ( dev-lang/lua:0[deprecated] )
nls? ( virtual/libintl )
perl? ( dev-lang/perl )
python? ( ${PYTHON_DEPS} )
ruby? ( || ( dev-lang/ruby:2.2 dev-lang/ruby:2.1 dev-lang/ruby:2.0 ) )
ssl? ( net-libs/gnutls )
spell? ( app-text/aspell )
tcl? ( >=dev-lang/tcl-8.4.15:0= )
"
# ncurses? ( sys-libs/ncurses )
# gtk? ( x11-libs/gtk+:2 )
DEPEND="${RDEPEND}
doc? (
app-text/asciidoc
dev-util/source-highlight
)
nls? ( >=sys-devel/gettext-0.15 )
test? ( dev-util/cpputest )
"
DOCS="AUTHORS.asciidoc ChangeLog.asciidoc ReleaseNotes.asciidoc README.asciidoc"
# tests need to be fixed to not use system plugins if weechat is already installed
RESTRICT="test"
PATCHES=( "${FILESDIR}"/${PN}-1.2-tinfo.patch )
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
local i
epatch "${PATCHES[@]}"
# fix libdir placement
sed -i \
-e "s:lib/:$(get_libdir)/:g" \
-e "s:lib\":$(get_libdir)\":g" \
CMakeLists.txt || die "sed failed"
# install only required translations
for i in ${LANGS} ; do
if ! use linguas_${i} ; then
sed -i \
-e "/${i}.po/d" \
po/CMakeLists.txt || die
fi
done
# install only required documentation ; en always
for i in `grep ADD_SUBDIRECTORY doc/CMakeLists.txt \
| sed -e 's/.*ADD_SUBDIRECTORY( \(..\) ).*/\1/' -e '/en/d'`; do
if ! use linguas_${i} ; then
sed -i \
-e '/ADD_SUBDIRECTORY( '${i}' )/d' \
doc/CMakeLists.txt || die
fi
done
}
src_configure() {
# $(cmake-utils_use_enable gtk)
# $(cmake-utils_use_enable ncurses)
local mycmakeargs=(
"-DENABLE_NCURSES=ON"
"-DENABLE_LARGEFILE=ON"
"-DENABLE_DEMO=OFF"
"-DENABLE_GTK=OFF"
"-DENABLE_JAVASCRIPT=OFF"
"-DPYTHON_EXECUTABLE=${PYTHON}"
$(cmake-utils_use_enable alias)
$(cmake-utils_use_enable doc)
$(cmake-utils_use_enable charset)
$(cmake-utils_use_enable exec)
$(cmake-utils_use_enable fifo)
$(cmake-utils_use_enable guile)
$(cmake-utils_use_enable irc)
$(cmake-utils_use_enable logger)
$(cmake-utils_use_enable lua)
$(cmake-utils_use_enable nls)
$(cmake-utils_use_enable perl)
$(cmake-utils_use_enable python)
$(cmake-utils_use_enable relay)
$(cmake-utils_use_enable ruby)
$(cmake-utils_use_enable scripts)
$(cmake-utils_use_enable scripts script)
$(cmake-utils_use_enable spell ASPELL)
$(cmake-utils_use_enable ssl GNUTLS)
$(cmake-utils_use_enable tcl)
$(cmake-utils_use_enable test TESTS)
$(cmake-utils_use_enable trigger)
$(cmake-utils_use_enable xfer)
)
[[ ${EPYTHON} == python3* ]] && mycmakeargs+=( $(cmake-utils_use_enable python PYTHON3) )
cmake-utils_src_configure
}