net-misc/mptcpd: add 0.13

Signed-off-by: Craig Andrews <candrews@gentoo.org>

net-misc/mptcpd/Manifest

@@ -1 +1,2 @@
 DIST mptcpd-0.12.tar.gz 690687 BLAKE2B 35c0b66268a04312f1d174348c40abc81d95f190860672740f4dd9ab472f1ecb4a6604b65a4ecf5084c9b98c1c1d50b3b0a7d5a714fa7e5568200a90909eb088 SHA512 313ce6f3905192fc614d419d498bfd814632730a50e3119039f076b4cec32360424f237a18cfec8c80a52ea6555a6e21949669ccb85e3178bd83748a2de66f73
+DIST mptcpd-0.13.tar.gz 688567 BLAKE2B e9783820b5e7908e5dcfa755ddf8eca3f16ae1f5adf44f8562c887ca1656a784bf69e02469bd7748a4f54665d45b27cba049b3643474fe7b737de5d09d4e2bc6 SHA512 5dd53c9e1c92a3242ad84d93642116e77acb24c997219c98fe30a4c6d80b283de8878bcc84a6ac4eaf51ff6dd32cff5ed2a40a869c8304faa835f3b300dbca37

net-misc/mptcpd/mptcpd-0.13.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools linux-info systemd
+
+DESCRIPTION="Daemon that performs multipath TCP path management related operations."
+HOMEPAGE="https://github.com/intel/mptcpd/"
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+IUSE="debug doc"
+
+RDEPEND="
+	>=dev-libs/ell-0.45.0
+	elibc_musl? ( sys-libs/argp-standalone )
+	"
+DEPEND="
+	${RDEPEND}
+	>=sys-kernel/linux-headers-5.6
+	"
+BDEPEND="
+	doc? (
+		app-text/doxygen
+		virtual/pandoc
+	)
+	virtual/pkgconfig
+	"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/intel/mptcpd.git"
+else
+	SRC_URI="https://github.com/intel/mptcpd/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+CONFIG_CHECK="MPTCP"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9-no-werror.patch
+)
+
+src_prepare() {
+	default
+
+	# For Werror patch
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-kernel=upstream
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+		$(use_enable debug)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake
+	use doc && emake doxygen-doc
+}
+
+src_test() {
+	emake check
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}