dev-python/aiohttp: Bump to 3.11.0_beta0

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2024-10-29 07:51:29 +01:00
parent 5a4a5cd478
commit 39becb4c56
2 changed files with 129 additions and 0 deletions
+1
View File
@@ -3,3 +3,4 @@ DIST aiohttp-3.10.5.tar.gz 7524360 BLAKE2B 57ca70d1a075ae7f9ba9b86a19be52e05e885
DIST aiohttp-3.10.6.tar.gz 7538429 BLAKE2B 55df48ae6321aa9d18ecf02ea16a34a328ad36ec87b0af77291c89684cd8de1fe35617187a700229c056f062ea50e8bd2249c2adb4e39a0899cab6fcd5521ac4 SHA512 9f5a989db03a1c9ae7a67c2888259466a4e9d3926f6e7bd8c31bb7981b7378dd8712a839e9c746e3502cbcdaef03b5c9dfe5fd65d0fde0af938bfbf4c7341327
DIST aiohttp-3.10.8.tar.gz 7540022 BLAKE2B 8407815a0f65035032c9c59174642784a9ad5845d6655c32f29369d3a7ffdd63d52310ec61ed3a106122a4aeb22ed0db5264a353b7e483bb63021cdd9526b5b6 SHA512 f19a58e698908faf164592037d57f1d133e064616b5552df26639a9a7248e90a960cb1b070dbbb90c058579cbdcc4edb72b2846bd20ab2867b4b0c670ddd177f
DIST aiohttp-3.10.9.tar.gz 7541983 BLAKE2B 3bcfcd09c537fbd2a976f95b5c8387280ec0256bbc231b2bc5a07a1524e6926bfdebd182b1365d950b5a1465f44c4db004a645af7490c57cd4637978595fa6d4 SHA512 0b52ba3ff2c78113117f56818ab177791f2764b2e5ce6531ce5b0481ab9d22b4fe621d70c1c2067eab8cfdd423a2cf0fdaefd8b13231aecf0491326bdf12d1a0
DIST aiohttp-3.11.0b0.tar.gz 7587019 BLAKE2B 7391adbb55819deaf4a70f6b8a6a55bb5ded9a0b932ed5597585f3c1ae669575ecd4050df8757f7ada42cedb1301027f4aa1b6c027d6f7140bb5612d4268b926 SHA512 9754c51e63b20ff4df28d04897e630165bb0da6bc2924cd43a610d5679b3a87f82d9c0eebc0c2d6eb82c82c37b4908e7ff73ed801df7956846ac1a260219e61d
@@ -0,0 +1,128 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..13} pypy3 )
inherit distutils-r1 pypi
DESCRIPTION="HTTP client/server for asyncio"
HOMEPAGE="
https://github.com/aio-libs/aiohttp/
https://pypi.org/project/aiohttp/
"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="+native-extensions test-rust"
RDEPEND="
>=dev-python/aiodns-3.2.0[${PYTHON_USEDEP}]
>=dev-python/aiohappyeyeballs-2.3.0[${PYTHON_USEDEP}]
>=dev-python/aiosignal-1.1.2[${PYTHON_USEDEP}]
>=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
dev-python/brotlicffi[${PYTHON_USEDEP}]
>=dev-python/frozenlist-1.1.1[${PYTHON_USEDEP}]
>=dev-python/multidict-4.5.0[${PYTHON_USEDEP}]
>=dev-python/propcache-0.2.0[${PYTHON_USEDEP}]
>=dev-python/yarl-1.17.0[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
<dev-python/async-timeout-5[${PYTHON_USEDEP}]
>=dev-python/async-timeout-4.0[${PYTHON_USEDEP}]
' 3.10)
"
BDEPEND="
native-extensions? (
dev-python/cython[${PYTHON_USEDEP}]
)
test? (
dev-python/freezegun[${PYTHON_USEDEP}]
www-servers/gunicorn[${PYTHON_USEDEP}]
dev-python/pytest-mock[${PYTHON_USEDEP}]
dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
dev-python/re-assert[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
dev-python/time-machine[${PYTHON_USEDEP}]
' 'python3*')
test-rust? (
dev-python/trustme[${PYTHON_USEDEP}]
)
)
"
DOCS=( CHANGES.rst CONTRIBUTORS.txt README.rst )
EPYTEST_XDIST=1
distutils_enable_tests pytest
src_prepare() {
# increase the timeout a little
sed -e '/abs=/s/0.001/0.01/' -i tests/test_helpers.py || die
# xfail_strict fails on py3.10
sed -i -e '/--cov/d' -e '/xfail_strict/d' setup.cfg || die
sed -i -e 's:-Werror::' Makefile || die
distutils-r1_src_prepare
}
python_configure() {
if [[ ! -d tools && ${EPYTHON} != pypy3 ]] && use native-extensions
then
# workaround missing files
mkdir tools || die
> requirements/cython.txt || die
> tools/gen.py || die
chmod +x tools/gen.py || die
# force rehashing first
emake requirements/.hash/cython.txt.hash
> .update-pip || die
> .install-cython || die
emake cythonize
fi
}
python_compile() {
# implicitly disabled for pypy3
if ! use native-extensions; then
local -x AIOHTTP_NO_EXTENSIONS=1
fi
distutils-r1_python_compile
}
python_test() {
local EPYTEST_IGNORE=(
# proxy is not packaged
tests/test_proxy_functional.py
# python_on_whales is not packaged
tests/autobahn/test_autobahn.py
# benchmarks
tests/test_benchmarks_client_request.py
tests/test_benchmarks_cookiejar.py
tests/test_benchmarks_http_websocket.py
)
local EPYTEST_DESELECT=(
# Internet
tests/test_client_session.py::test_client_session_timeout_zero
# broken by irrelevant deprecation warnings
tests/test_circular_imports.py::test_no_warnings
)
# upstream unconditionally blocks building C extensions
# on PyPy3 but the test suite needs an explicit switch
if [[ ${EPYTHON} == pypy3 ]] || ! use native-extensions; then
local -x AIOHTTP_NO_EXTENSIONS=1
fi
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x PYTEST_PLUGINS=pytest_mock,xdist.plugin
rm -rf aiohttp || die
epytest -m "not internal and not dev_mode" \
-p rerunfailures --reruns=5
}