net-irc/limnoria: add 20260508

Closes: https://bugs.gentoo.org/974031
Signed-off-by: Sam James <sam@gentoo.org>

net-irc/limnoria/Manifest

@@ -1 +1,2 @@
 DIST limnoria-20241222.tar.gz 1182856 BLAKE2B 5f9c98ea71224940398dbd1387a9d6e90d9115e7716d0bab39f3396b78551e88955f82a6a1b2562be9339b096026dab880b98043fb60aa396ebf99d54970c9c3 SHA512 48eb38489edd769eee083a31345500b8614386a383f069d2d6b291e2180bc3238fbb2dad34d31a61d825db57f5464bd41cf4485a75bc24dc21ef839152eaba00
+DIST limnoria-20260508.tar.gz 1150680 BLAKE2B 733f8e68b4f42d878f86f3e61cc6e30a5bdb3a6a2254b956116574c5d1e77e58de3cdcc9f689c6e6f8999dba0be999805da656a08f9463d771d7136f0c402549 SHA512 2785b9deb42d6a046f03f5105790e401fb5f787367ebbd6e2e68c144cb87103224cab8e8c18154ba11553728f4f70af9a8d677d54793d6cce70930e4f871e445

net-irc/limnoria/limnoria-20260508.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+inherit distutils-r1
+
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
+MY_PN="Limnoria"
+MY_P="${MY_PN}-${MY_PV}"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/ProgVal/${MY_PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/ProgVal/${MY_PN}/archive/master-${MY_PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${MY_PN}-master-${MY_PV}"
+	KEYWORDS="~amd64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Python based extensible IRC infobot and channel bot"
+HOMEPAGE="https://docs.limnoria.net"
+LICENSE="BSD GPL-2 GPL-2+"
+SLOT="0"
+IUSE="crypt ssl"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/feedparser[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/pysocks[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	crypt? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
+	ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# replace "installed on ${timestamp}" with real version
+	echo "version='${MY_PV//-/.}'" > "${S}"/src/version.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	PLUGINS_DIR="${BUILD_DIR}/build/lib/supybot/plugins"
+	# intermittent failure due to issues loading libsandbox.so from LD_PRELOAD
+	# runs successfully when running the tests on the installed system
+	EXCLUDE_PLUGINS=(
+		--exclude="${PLUGINS_DIR}/Unix"
+		--exclude="${PLUGINS_DIR}/Aka"
+		--exclude="${PLUGINS_DIR}/Misc"
+	)
+
+	"${EPYTHON}" "${BUILD_DIR}/install/usr/bin/supybot-test" \
+		--plugins-dir="${PLUGINS_DIR}" --no-network \
+		--disable-multiprocessing "${EXCLUDE_PLUGINS[@]}" \
+		"${S}/test" \
+		|| die "Tests failed under ${EPYTHON}"
+}
+
+pkg_postinst() {
+	elog "Complete user documentation is available at https://limnoria-doc.readthedocs.io/"
+	elog ""
+	elog "Use supybot-wizard to create a configuration file."
+	elog "Run supybot </path/to/config> to use the bot."
+}

net-irc/limnoria/limnoria-99999999.ebuild

@@ -1,10 +1,10 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{11..13} )
+PYTHON_COMPAT=( python3_{11..14} )
 inherit distutils-r1
 
 MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"