xfce-extra/xfce4-sensors-plugin: Bump to 1.4.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-extra/xfce4-sensors-plugin/Manifest

@@ -1 +1,2 @@
 DIST xfce4-sensors-plugin-1.4.2.tar.bz2 508525 BLAKE2B 619bfbc8d4453697cee2c5d5a669edee1a455e899a50229c77bf1b41661e06d7811a09e446e84e5cf62b9c24d7244f3eec74eb14fe7ccc4bcf49a25b14df9d18 SHA512 0b036ca6b040f1f97576917c944e19b9b5803c4e98f1d21435c0a5598701c9bff053e014f03edd09dbb9232e5c932c014719999a0e972e5e3db8330665c0217c
+DIST xfce4-sensors-plugin-1.4.3.tar.bz2 508993 BLAKE2B 4e857c2b31b6dc1d9e1f5adeb0b34c1f68c0e3386c7211533c5ffdfddddfc307fd16b0a55b6f8697aab87c62e143f3e8795c1a7ba36c3cfd18e92b56e316c7f0 SHA512 2cb91afaf740db5bbbb8451cfa0540ee979671e6a1a640ad61dfeb41328c057bc16fa668e9d536595ef460bfbd41617e8b3d27f63e02324e9764543fa6a0b2b5

xfce-extra/xfce4-sensors-plugin/xfce4-sensors-plugin-1.4.3.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="A panel plug-in for acpi, lm-sensors and hddtemp sensors"
+HOMEPAGE="https://goodies.xfce.org/projects/panel-plugins/xfce4-sensors-plugin"
+SRC_URI="https://archive.xfce.org/src/panel-plugins/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="+acpi hddtemp libnotify lm-sensors video_cards_nvidia"
+
+REQUIRED_USE="|| ( hddtemp lm-sensors acpi )"
+
+RDEPEND=">=x11-libs/gtk+-3.20:3=
+	>=xfce-base/libxfce4ui-4.14:=
+	>=xfce-base/libxfce4util-4.14:=
+	>=xfce-base/xfce4-panel-4.12:=
+	hddtemp? (
+		app-admin/hddtemp
+		|| (
+			net-analyzer/openbsd-netcat
+			net-analyzer/netcat
+		)
+	)
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	lm-sensors? ( >=sys-apps/lm-sensors-3.1.0:= )
+	video_cards_nvidia? ( x11-drivers/nvidia-drivers[tools,static-libs] )"
+DEPEND=${RDEPEND}
+
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		--libexecdir="${EPREFIX}"/usr/$(get_libdir)
+		$(use_enable lm-sensors libsensors)
+		$(use_enable hddtemp)
+		$(use_enable hddtemp netcat)
+		$(use_enable acpi procacpi)
+		$(use_enable acpi sysfsacpi)
+		$(use_enable video_cards_nvidia xnvctrl)
+		$(use_enable libnotify notification)
+		--disable-pathchecks
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}