dev-python/virtualenvwrapper: Bump to 6.1.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/virtualenvwrapper/Manifest

@@ -1 +1,2 @@
 DIST virtualenvwrapper-6.1.0.tar.gz 95880 BLAKE2B 86d37682148ee132f9be5c4554de3c770c0f1c3055441bbce080d94da6fa83fc138a15c4c7edbb525e0c303c3c2ba5c1b1ee23260ea5bafaab157b3699b39b87 SHA512 78e09956132862fbf1caf53cb6c9375aa3718685f72d8f3fb61e402e6b26e8568d5b3a3ed18142b14f3b2691f89e6f912782e813d8139dc71ceb7e47bde8d0b0
+DIST virtualenvwrapper-6.1.1.tar.gz 95964 BLAKE2B 722fee78cdadbde77e03b22458f1591e9540ef12cd7deb14ecfa8abf1b030d16f8548b31297832eaf843d5b1db8453c239ff42162d66a74490339ab77e8ccc37 SHA512 1d2095c79f3679a4068418fe6e740771334bf0be44961dc5a50ac4848c83b5af046fc6125497177b864603efc4f2a0aacc912185129b8eb510dc4dcdef661853

dev-python/virtualenvwrapper/virtualenvwrapper-6.1.1.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Set of extensions to Ian Bicking's virtualenv tool"
+HOMEPAGE="
+	https://github.com/python-virtualenvwrapper/virtualenvwrapper/
+	https://pypi.org/project/virtualenvwrapper/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/stevedore[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+		dev-python/virtualenv-clone[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	')
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			dev-python/pip[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/virtualenvwrapper-6.0.0-remove-use-of-which.patch"
+	"${FILESDIR}/virtualenvwrapper-4.8.4_p20230121-override-default-python-executable.patch"
+)
+
+src_prepare() {
+	default
+
+	# specify default python interpeter to align with PYTHON_SINGLE_TARGET
+	sed -i -e "s:@@GENTOO_PYTHON_EXECUTABLE@@:${PYTHON}:" virtualenvwrapper.sh || die
+
+	# remove tests which require an internet connection
+	rm tests/test_mkvirtualenv_install.sh || die
+	rm tests/test_mkvirtualenv_requirements.sh || die
+
+	# remove tests which require functional git repos with remotes
+	sed -i -e '/test_wipeenv_\(pip_e\|develop\) () {/,/}/ d' tests/test_wipeenv.sh || die
+}
+
+python_test() {
+	# tests have unusual expectations
+	local -x HOME="${HOME%/}"
+	local -x USER="${USER}"
+
+	cp -a "${BUILD_DIR}"/{install/usr,test} || die
+	local -x VIRTUAL_ENV="${BUILD_DIR}/test"
+
+	bash ./tests/run_tests "${VIRTUAL_ENV}" || die "Tests failed under ${EPYTHON}"
+}