gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-23 16:49:10 -07:00
Code Issues Projects Releases Wiki Activity

app-backup/dar: Removed old.

Browse Source 
Package-Manager: Portage-2.3.8, Repoman-2.3.3
This commit is contained in:
Lars Wendler
2017-09-02 22:35:31 +02:00
parent b0d76be4ad
commit 3870d79add
2 changed files with 0 additions and 97 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
app-backup/dar/Manifest
View File

@@ -1,5 +1,4 @@
DIST dar-2.4.20.tar.gz 1804634 SHA256 f0f66108692de8b27e76b1832d9013d9d1dbf45d2aaaaf5c222dde3c6f1b308d SHA512 1ed2e43df05082c01f6a53aa8c1c7328cb27fc3d84115d3f4a07de943fc814b614155f673464cd1a455e3b8c21e30f95da03ed9f72883b58ae005e3696de8143 WHIRLPOOL b3ce8c59efe2f9f988133613b73fe1ec14af39746e7c5fff0c83fa2146218fad3e912f586e9b677af809696105fa9d72dc35122ec3b3ca3ad63b2cdd75fce954
DIST dar-2.4.24.tar.gz 1820097 SHA256 cb9f0935f4aa1c10daaceef3fbcf165ca73524fd6ce50948cb91e926080825f0 SHA512 3e5fbaaac7ab8e25776d20c11accba94c30abcbc898e7700e9faa98dee94995e742a9481740f2d286149a198ce661d876d2737fed85f1a2555073436175c5f10 WHIRLPOOL 659ac04d22c4781595863b22372755a357f060ab7325623d54e7d258aa36701111c026a884775444c2cea232fc3a0410d6c85c06a5f56a14cc39022c72237fe6
DIST dar-2.5.10.tar.gz 1888334 SHA256 771c8462b9e65bf646699a14a4e156c75b5bda4301ebf6f5e03bd82c2486a4d8 SHA512 90727f206634fc7d8ab7ca1faf588cfdb504d7474096b2965fde18a0a3cc54f603f0df3ddd1b00d331951d5d4688a1adb861eec71034e92aa1428e5ba9e665f1 WHIRLPOOL cdfaf5ee6535083e49aef2992010b960650b9804426cc6a52cf0839225d54e7537b8e356acfb398210b480eebf73551875f01ae016d04221c2ac18cc65ee4f05
DIST dar-2.5.11.tar.gz 1891928 SHA256 ad9d4b32b7a1240d9ae74155ff0aab3848065bee65ce01a022a234c02be73989 SHA512 36b90218a34ac7f41ce9ca0a2167cfb2fd243b23b8e84350153e8804f0faabf87291b4e4b061533bcb0ca079f087c074eeaa12a54ee8084dd386a072ac503847 WHIRLPOOL 4e52c72a98d56b402cb546b96c5d09233910558322dca9344242ab5829f1c39e68fca31221db4f90dc6d20c216199ebce1329fd9dc214d548a78457178ab4cf5
DIST dar-2.5.12.tar.gz 1893694 SHA256 19bd60000a681a20386ee079b9a6ea05028020053eaeddbff175a8d22563fba2 SHA512 58eafe69c730d8f3974a1b1e8f7ca67feee82babde9ba9577ef29c422861db2b29afa835c9b55160e5d226efb634b539a580845e429d08fd84beeb6f0d39be7e WHIRLPOOL d16a861c4f5e88ac93854085e9b62cc357643ba1cab0d3f822a699fa192574cbf45c8254308cddfc928839169e096fa55f229a33ab9735d7f582f5ca346c280f

96
app-backup/dar/dar-2.5.10.ebuild
View File

@@ -1,96 +0,0 @@
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit flag-o-matic
DESCRIPTION="A full featured backup tool, aimed for disks"
HOMEPAGE="http://dar.linux.free.fr/"
SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
IUSE="dar32 dar64 doc gcrypt gpg lzo nls static static-libs xattr"
RESTRICT="test" # need to be run as root
RDEPEND=">=sys-libs/zlib-1.2.3:=
!static? (
app-arch/bzip2:=
app-arch/xz-utils:=
sys-libs/libcap
gcrypt? ( dev-libs/libgcrypt:0= )
gpg? ( app-crypt/gpgme )
lzo? ( dev-libs/lzo:= )
xattr? ( sys-apps/attr:= )
)"
DEPEND="${RDEPEND}
static? (
app-arch/bzip2[static-libs]
app-arch/xz-utils[static-libs]
sys-libs/libcap[static-libs]
sys-libs/zlib[static-libs]
gcrypt? ( dev-libs/libgcrypt:0=[static-libs] )
gpg? (
app-crypt/gpgme[static-libs]
dev-libs/libassuan[static-libs]
dev-libs/libgpg-error[static-libs]
)
lzo? ( dev-libs/lzo[static-libs] )
xattr? ( sys-apps/attr[static-libs] )
)
nls? (
sys-devel/gettext
virtual/libintl
)
doc? ( app-doc/doxygen )"
REQUIRED_USE="?? ( dar32 dar64 )
gpg? ( gcrypt )"
#PATCHES=(
#)
src_configure() {
local myconf=( --disable-upx )
# Bug 103741
filter-flags -fomit-frame-pointer
# configure.ac is totally funked up regarding the AC_ARG_ENABLE
# logic.
# For example "--enable-dar-static" causes configure to DISABLE
# static builds of dar.
# Do _not_ use $(use_enable) until you have verified that the
# logic has been fixed by upstream.
use xattr || myconf+=( --disable-ea-support )
use dar32 && myconf+=( --enable-mode=32 )
use dar64 && myconf+=( --enable-mode=64 )
use doc || myconf+=( --disable-build-html )
# use examples && myconf+=( --enable-examples )
use gcrypt || myconf+=( --disable-libgcrypt-linking )
use gpg || myconf+=( --disable-gpgme-linking )
use lzo || myconf+=( --disable-liblzo2-linking )
use nls || myconf+=( --disable-nls )
if ! use static ; then
myconf+=( --disable-dar-static )
if ! use static-libs ; then
myconf+=( --disable-static )
fi
fi
econf ${myconf[@]}
}
src_install() {
emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
local DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
einstalldocs
if ! use static-libs ; then
prune_libtool_files --all
fi
}