dev-python/towncrier: Bump to 25.8.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/towncrier/Manifest

@@ -1 +1,2 @@
 DIST towncrier-24.8.0.gh.tar.gz 74612 BLAKE2B 257ce077a212648177514f87f15274415a343fd16105dd2d94935b86ff53552b47554584efcc73810ac5ccc0f67196845838ee83b6f43580dd9d9a4eee782da7 SHA512 6e4db4713aa35d7daee2296433ee1c1093ef6a56831128f3b068ea5c7be167c9ba83a97e1ea17e94bd3ef80ec1c715c0a57484f4159538de6105052830798698
+DIST towncrier-25.8.0.gh.tar.gz 80858 BLAKE2B bfeacc0f4d105a3bedee7b9a6e49ca8db9e07a68e17cdcae17b5638e2d00791c32e3b0d8359aa0f08194a0d3237e0cb8b9e11a6adc5f62bf34aef0eba2952409 SHA512 203fc93796e19f2c9c51e8de803df0da54d6f8762ba7cf11f6d50d12fdb922223ae430e5c911e8ffbedcb77287fce93314fe2888dd0b2622c65f25a4dc274be1

dev-python/towncrier/towncrier-25.8.0.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="Building newsfiles for your project"
+HOMEPAGE="
+	https://github.com/twisted/towncrier/
+	https://pypi.org/project/towncrier/
+"
+SRC_URI="
+	https://github.com/twisted/${PN}/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/click-default-group[${PYTHON_USEDEP}]
+	dev-python/incremental[${PYTHON_USEDEP}]
+	dev-python/jinja2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/incremental[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-vcs/git
+		>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	# unbundle click-default-group, sigh
+	rm src/towncrier/click_default_group.py || die
+	sed -i -e '/click_default_group/s:[.]::' src/towncrier/_shell.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	"${EPYTHON}" -m twisted.trial towncrier ||
+		die "tests failed with ${EPYTHON}"
+}