dev-python/sigstore: Bump to 4.0.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/sigstore/Manifest

@@ -1 +1,2 @@
 DIST sigstore-python-3.6.5.gh.tar.gz 281176 BLAKE2B 23d4ccffaa2e779fdb65406f452d0c559a2c0699560d996f3b71d326d38da38bc6a264c3d4195b866d9764289a986de7f732afc64f33995f98557e759baf0c79 SHA512 a4fd2cfe1619db363b33ea03e940ae6d3b97bb838501d704926cf32b63f7c2ce75ace9915ec466ab4a9714c9a2b45578aa3006b9c19ca022c588d50bb53ae5bb
+DIST sigstore-python-4.0.0.gh.tar.gz 299794 BLAKE2B ba6da6348436e9cdf43251556f7557015c5023ab80c90d801fd6ecc6f110a479d61e4edfa5f49a3a2a3204c411bc756a8c7a074798264c8f4a6036761804b052 SHA512 32fb6ce24635a0cedfea48d87f59c48d4794fd49399ca9fe1c10f945179888cd238dddb8be8ec5830b39e5d5faea0c5e8adec59c6710356ccd14067b817c0709

dev-python/sigstore/sigstore-4.0.0.ebuild

@@ -0,0 +1,62 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P=sigstore-python-${PV}
+DESCRIPTION="A tool for signing Python package distributions"
+HOMEPAGE="
+	https://github.com/sigstore/sigstore-python/
+	https://pypi.org/project/sigstore/
+"
+# no tests in sdist, as of 3.3.0
+SRC_URI="
+	https://github.com/sigstore/sigstore-python/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/cryptography-42[${PYTHON_USEDEP}]
+	>=dev-python/id-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-4.2[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-23.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.6[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-2[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.1[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	~dev-python/rfc3161-client-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/rfc8785-0.1.2[${PYTHON_USEDEP}]
+	>=dev-python/rich-13[${PYTHON_USEDEP}]
+	~dev-python/sigstore-models-0.0.5[${PYTHON_USEDEP}]
+	~dev-python/sigstore-rekor-types-0.0.18[${PYTHON_USEDEP}]
+	>=dev-python/tuf-6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pretend[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps
+	sed -r -i -e 's:~=:>=:' -e 's:, ?< ?[0-9.]*::' pyproject.toml || die
+}
+
+python_test() {
+	epytest test/unit --skip-online
+}