kde-apps/dolphin-plugins-mercurial: 22.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/dolphin-plugins-mercurial/Manifest

@@ -1 +1,2 @@
 DIST dolphin-plugins-22.08.3.tar.xz 260088 BLAKE2B 2927d42a603776cc3b600606ff2f27a77c8bbbe6b089d3e691571c7594d0e4d53023064afbf07e02f546073823a873fd45f200ea13b9e2765b61046602d8239b SHA512 2201858d9d349c28cced78dcfd9a31c3fde05b3ab107a28615af4cc5c32d4315074881f78dfb255638a13269de16ab68b7c53b68d013cf46ded091f8b059173e
+DIST dolphin-plugins-22.12.0.tar.xz 268876 BLAKE2B 8a21afe22227fdea29a63b09a6adcb5e6f263f9a0b11adad7466c72c3c145c4ce906b4acf77ced9c6a51d68d19f991e0c2933029d5848e10afa1eb7a3cd8da3a SHA512 be257382b493c2f318cfba7c594a1ef89c358ba5ccb3ff7478313040923f319106a1f94fcf9699695d3d17b59031bcdc88352fc6c58f779475b41a5080dc2126

kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-22.12.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="hg"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.99.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for Mercurial integration"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	dev-vcs/mercurial
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_qt_module DBus
+	ecm_punt_kf_module Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+	# delete non-${PN} translations
+	find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}