dev-qt/qtconnectivity: add 6.9.2

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

dev-qt/qtconnectivity/Manifest

@@ -1 +1,2 @@
 DIST qtconnectivity-everywhere-src-6.9.1.tar.xz 1072040 BLAKE2B d9b78cf12f75be6c08de122669ec97c3f5e8ccde9f9be468305b9809604d587126df3abcadf10e717f49e7ab45a63b8490d1657a887965fe8c41ce6110438de0 SHA512 5591a7b4140e9580186b20bf8b3c75f07f8d22f48910ca017f8ab7609a4438297bdb0e9f04cc31ebc238bfd58d85b6e980938e2014b4106f48034fda6294df96
+DIST qtconnectivity-everywhere-src-6.9.2.tar.xz 1057556 BLAKE2B f5bac3ea5601f3ac6f55c7c177d44a53a8885a9e2c1b2326ba886ef2e5a914de22d8903ae4b4fc4647f1d3f1a731b9a6ae2026bdc7d219daa2eef49cdb3b3a47 SHA512 94df6d32404121f6d3763fc32f83430e135f4be9198ac03008c9743f82f3c8c8008b3563d87c823f723a830bb76021d1c30b7804b60bb5ad533291c0605c86dc

dev-qt/qtconnectivity/qtconnectivity-6.9.2.ebuild

@@ -0,0 +1,85 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Bluetooth and NFC support library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+IUSE="+bluetooth neard nfc smartcard"
+REQUIRED_USE="
+	|| ( bluetooth nfc )
+	nfc? ( ?? ( neard smartcard ) )
+"
+
+DEPEND="
+	~dev-qt/qtbase-${PV}:6
+	bluetooth? (
+		~dev-qt/qtbase-${PV}:6[dbus,network]
+		net-wireless/bluez:=
+	)
+	nfc? (
+		neard? ( ~dev-qt/qtbase-${PV}:6[dbus] )
+		smartcard? ( sys-apps/pcsc-lite )
+	)
+"
+RDEPEND="
+	${DEPEND}
+	nfc? (
+		neard? ( net-wireless/neard )
+	)
+"
+
+CMAKE_SKIP_TESTS=(
+	# most hardware tests are auto-skipped, but some still misbehave
+	# if bluez/hardware is available (generally tests here may not be
+	# very relevant without hardware, lists may need to be extended)
+	tst_qbluetoothdevicediscoveryagent #936485
+	tst_qbluetoothlocaldevice
+	tst_qbluetoothserver
+	tst_qbluetoothservicediscoveryagent
+	tst_qbluetoothserviceinfo
+	tst_qlowenergycontroller
+)
+
+src_prepare() {
+	qt6-build_src_prepare
+
+	use bluetooth ||
+		sed -i '/add_subdirectory(bluetooth)/d' src/CMakeLists.txt || die
+	use nfc ||
+		sed -i '/add_subdirectory(nfc)/d' src/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(usev nfc "
+			$(qt_feature neard)
+			$(qt_feature smartcard pcsclite)
+		")
+	)
+
+	qt6-build_src_configure
+}
+
+src_install() {
+	qt6-build_src_install
+
+	# broken (unnecessary) symlink due to add_app() being used over add_tool()
+	use !bluetooth || rm -- "${ED}"/usr/bin/sdpscanner6 || die
+
+	if use test; then
+		local delete=( # sigh
+			"${D}${QT6_BINDIR}"/bluetoothtestdevice
+			"${D}${QT6_BINDIR}"/bttestui
+			"${D}${QT6_BINDIR}"/qlecontroller-server
+		)
+		# using -f given not tracking which tests may be skipped or not
+		rm -f -- "${delete[@]}" || die
+	fi
+}