media-gfx/ahoviewer: bump to 2.0.0-beta

- add 'plugins' USE flag to build plugin support - in future, it'll pull
   external plugins from https://github.com/ahodesuka/ahoviewer-plugins,
 - GTK-3 support,
 - switch to meson build system.

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

media-gfx/ahoviewer/Manifest

@@ -1 +1,2 @@
 DIST ahoviewer-1.6.5.tar.gz 227653 BLAKE2B 691a9eaa62b55d91b2d215d41ce402c39ca7490a44506a489061aaadd97fac2ac84aa1b28a7d1b4c097d69153ffe146fac105e9b086adc6b66b9f459e6b98eb5 SHA512 30309cff22008d444eec113bd5d79bdc0e9ff1bbc1b117bd3ecefabfdef79773fd17347766115bb0a192db76dbb24f30c853b27123f0a333c8625b94dc2a8775
+DIST ahoviewer-2.0.0_beta.tar.gz 488564 BLAKE2B 325d9689e13fc2847d00be3e77eb5cd8234c98d0c516d3427d4275beaf6cc08ba8a054dfa047ec5e00e4693f8b14f730694358dc22a15e8d503bf67f232c1772 SHA512 6a38da0810c93886233a41d1fdc3f9779158c54b328c13cb2eea9e921057913fd3bb48370b95526f2bc8635ca4ba0967e7edeb95052ea689b05fb8555d826cf0

media-gfx/ahoviewer/ahoviewer-2.0.0_beta.ebuild

@@ -0,0 +1,86 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg
+
+MY_PV="$(ver_rs 3 -)"
+
+DESCRIPTION="A GTK image viewer, manga reader, and booru browser"
+HOMEPAGE="https://github.com/ahodesuka/ahoviewer"
+SRC_URI="https://github.com/ahodesuka/ahoviewer/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome-keyring gnutls +gstreamer plugins +rar +ssl +zip"
+
+DEPEND="dev-cpp/glibmm:=
+	dev-cpp/gtkmm:3.0=
+	dev-libs/libconfig:=[cxx]
+	dev-libs/libsigc++:2=
+	dev-libs/libxml2:2=
+	media-libs/libnsgif
+	net-misc/curl
+	x11-libs/gtk+:3
+	gnome-keyring? ( app-crypt/libsecret )
+	gstreamer? (
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gstreamer:1.0
+	)
+	plugins? ( dev-libs/libpeas )
+	rar? ( app-arch/unrar:= )
+	ssl? (
+		gnutls? (
+			dev-libs/libgcrypt:=
+			net-libs/gnutls:=
+			net-misc/curl[curl_ssl_gnutls]
+		)
+		!gnutls? (
+			dev-libs/openssl:=
+			net-misc/curl[curl_ssl_openssl]
+		)
+	)
+	zip? ( dev-libs/libzip )
+"
+RDEPEND="${DEPEND}
+	gstreamer? (
+		media-libs/gst-plugins-base:1.0[X]
+		media-libs/gst-plugins-good:1.0
+		|| (
+			media-plugins/gst-plugins-vpx
+			media-plugins/gst-plugins-libav
+		)
+	)"
+
+# In future (-beta), pull https://github.com/ahodesuka/ahoviewer-plugins
+# directly via SRC_URI="plugins? ( )", or add as a separate package. It
+# depends on how the plugins are handled.
+#PDEPEND="plugins? ( x11-misc/ahoviewer-plugins )"
+
+S="${WORKDIR}/ahoviewer-${MY_PV}"
+
+src_prepare() {
+	default
+
+	# Hopefully related to beta/git, incomplete release.
+	cat <<- EOF > src/version.h || die
+		#ifndef _VERSION_H_
+		#define AHOVIEWER_VERSION "${MY_PV}"
+		extern const char *const ahoviewer_version;
+		#endif // _VERSION_H_
+	EOF
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature gnome-keyring libsecret)
+		$(meson_feature gstreamer)
+		$(meson_feature plugins libpeas)
+		$(meson_feature rar libunrar)
+		$(meson_feature zip libzip)
+	)
+
+	meson_src_configure
+}

media-gfx/ahoviewer/metadata.xml

@@ -5,6 +5,7 @@
     <email>juippis@gentoo.org</email>
   </maintainer>
   <use>
+    <flag name="plugins">Build plugin support for now, in future pull additional plugins</flag>
     <flag name="rar">Rar archive support</flag>
     <flag name="zip">Zip archive support</flag>
   </use>