x11-wm/icewm: Bump to version 1.9.0

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
This commit is contained in:
Lars Wendler
2020-10-29 21:44:07 +01:00
parent 9bf0896d92
commit 36d18a0bfc
2 changed files with 138 additions and 0 deletions
+1
View File
@@ -1,3 +1,4 @@
DIST icewm-1.7.0.tar.lz 1668130 BLAKE2B 90739f862cf320c43dc2ddbd1a5ecdf2918e6525e45d5732b19adaaeef0f104d9a66d29acab776658f869d7149954d4b531a07e2595a4c80b4dc50dc679473f0 SHA512 1b0faed0e9ead837dcb0d3ce91ad5248d7fca5ad48455c838700c66482a3373bb4e552dbc252b93b0a5613d53e2663cea756e64b3f3fb073d9ba2797e2b69601
DIST icewm-1.8.2.tar.lz 1686746 BLAKE2B a2dcf77284f5dc2f908ec949c6e1ea792292648fbd5cb8167216ee994706b1a208ca6fe29831f6bf98d2ec02e5e5120eca8f3a93a20a4a75d80d839210d829bd SHA512 3454b9547b7f4857957133cda4436814149bea99886cd4564f947391a1f42d474d56c7cd3208ff2471262c57f623de1ec22e30f0d9b14874f29ac3a4855b9a45
DIST icewm-1.8.3.tar.lz 1686603 BLAKE2B 214cb3c7816ba8d94fa56fb9d4a6c630f49f23f69f99ff1ba7aff38aba6f6b7fbd623a284d4873616486d266a7ec412ba9cf4b29479c5c29f1f7ff27e15d1f48 SHA512 697395ff995b57e043774bae2cce667935879c4deab17d9a9059c1e152a90704ad3af618a2c945ac5afd561754895d4e9805f4fea77d5f1e06cf99a7dfd4c062
DIST icewm-1.9.0.tar.lz 1695327 BLAKE2B 233c2fb2f9be4be757055a5655f32a9c34f3551dd1807568e00b84ac8e60422c2f25d03d6ca206e9134b4db0605a0ea5a8b4bad1cd507220d2b5520583a66e96 SHA512 781d1ef230fda0b6b52ce6383126e7f953ac043fd85d14de718d42f1271c063d9861fbfd4dd6e81f9b6f33058c59026766ebc3f2fce84ca79c89ddb562c26fde
+137
View File
@@ -0,0 +1,137 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools unpacker
DESCRIPTION="Ice Window Manager with Themes"
HOMEPAGE="https://ice-wm.org/ https://github.com/ice-wm/icewm"
LICENSE="GPL-2"
SRC_URI="https://github.com/ice-wm/icewm/releases/download/${PV}/${P}.tar.lz"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="+alsa ao bidi debug +gdk-pixbuf nls truetype uclibc xinerama"
# Tests broken in all versions, patches welcome, bug #323907, #389533
RESTRICT="test"
REQUIRED_USE="|| ( alsa ao )"
#fix for icewm preversion package names
S="${WORKDIR}/${P/_}"
# These are the core dependencies of icewm.
# Look into configure.ac and search for PKG_CHECK_MODULES([CORE]
CORE_DEPEND="
media-libs/fontconfig
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXrender
"
RDEPEND="
${CORE_DEPEND}
x11-libs/libICE
x11-libs/libSM
x11-libs/libXft
x11-libs/libXpm
x11-libs/libXrandr
alsa? (
media-libs/alsa-lib
media-libs/libsndfile[alsa]
)
ao? (
media-libs/libao
media-libs/libsndfile
)
bidi? ( dev-libs/fribidi )
gdk-pixbuf? (
x11-libs/gdk-pixbuf:2[X]
)
!gdk-pixbuf? (
media-libs/libpng:0=
virtual/jpeg
)
xinerama? ( x11-libs/libXinerama )
"
DEPEND="
${RDEPEND}
$(unpacker_src_uri_depends)
dev-libs/glib:2
gnome-base/librsvg
x11-base/xorg-proto
gdk-pixbuf? ( gnome-base/librsvg:2 )
"
BDEPEND="
app-text/asciidoc
virtual/pkgconfig
nls? ( >=sys-devel/gettext-0.19.6 )
"
src_prepare() {
# Fix bug #486710 - TODO: Still needed?
#use uclibc && PATCHES+=( "${FILESDIR}/${PN}-1.3.8-uclibc.patch" )
default
eautoreconf
}
src_configure() {
local icesound
if use alsa && use ao ; then
icesound="alsa,ao"
elif use alsa ; then
icesound="alsa"
elif use ao ; then
icesound="ao"
fi
local myconf=(
--enable-logevents
--enable-xrandr
--with-cfgdir=/etc/icewm
--with-docdir=/usr/share/doc/${PF}/html
--with-icesound="${icesound}"
--with-libdir=/usr/share/icewm
$(use_enable bidi fribidi)
$(use_enable debug)
$(use_enable gdk-pixbuf)
$(use_enable nls i18n)
$(use_enable nls)
$(use_enable xinerama)
)
if use truetype ; then
myconf+=(
--enable-shape
)
else
myconf+=(
--disable-xfreetype
--enable-corefonts
)
fi
econf "${myconf[@]}"
sed -i "s:/icewm-\$(VERSION)::" src/Makefile || die
sed -i "s:ungif:gif:" src/Makefile || die "libungif fix failed"
}
src_install() {
local DOCS=( AUTHORS ChangeLog NEWS README.md TODO VERSION )
default
docinto html
dodoc doc/icewm.html
dodoc man/*.html
exeinto /etc/X11/Sessions
doexe "${FILESDIR}/icewm"
}